PureBoard

Code: Alles auswählen

EnableExplicit
Procedure.i SplitJPEGStream(file.s)
	Protected counter.i
	Protected path.s = GetPathPart(file)
	Protected fileId.i
	Protected Dim bytes.a(4)
	Protected pos.i = 0
	Protected writeFileId.i = 0

	fileId = ReadFile(#PB_Any, file)
	If (Not fileId)
		Debug "Konnte Datei nicht öffnen."
		ProcedureReturn #False
	EndIf
	
	While Not Eof(fileid)
		bytes(pos) = ReadAsciiCharacter(fileId)
		If (bytes(pos) = $D8 And bytes((pos + 3) % 4) = $FF And (counter = 0 Or (bytes((pos + 2) % 4) = $D9 And bytes((pos + 1) % 4) = $FF)))
			If (writeFileId)
				WriteAsciiCharacter(writeFileId, bytes((pos + 2) % 4))
				CloseFile(writeFileId)
			EndIf
			counter + 1
			writeFileId = CreateFile(#PB_Any, path + RSet(Str(counter), 4, "0") + ".jpg")
			If (Not writeFileId)
				Debug "Konnte Datei nicht zum Schreiben öffnen."
				ProcedureReturn #False
			EndIf
		ElseIf (writeFileId)
			WriteAsciiCharacter(writeFileId, bytes((pos + 2) % 4))
		EndIf
		pos = (pos + 1) % 4
	Wend
	
	If (writeFileId)
		WriteAsciiCharacter(writeFileId, bytes((pos + 2) % 4))
		WriteAsciiCharacter(writeFileId, bytes((pos + 3) % 4))
		CloseFile(writeFileId)
	EndIf
	
	CloseFile(fileId)
	
	ProcedureReturn #True
EndProcedure

SplitJPEGStream("/home/nicolas/test.mjpeg")