PureBoard

Verfasst: **30.09.2010 17:28**

Wie kann zu einen normalen Button diesen kleinen "nach unten"-Pfeil rechts neben dem Text hinzufügen?
Habe nur die Möglichkeit eines SplitButtons gefunden, welche aber erst ab Vista funktioniert. Ist daher für mich ungeeignet.

Mfg
iostream

Verfasst: **30.09.2010 18:44**

nicht schön, aber funktioniert unter allen OS

Code: Alles auswählen

Enumeration
  #myWindow
  #myButton
  #myDropDown
  #myMenu
  #myMenuItem1
  #myMenuItem2
  #myMenuItem3
EndEnumeration

OpenWindow(#myWindow, #PB_Ignore, #PB_Ignore, 100, 100, "")
ButtonGadget(#myButton, 5, 5, 50, 25, "button")
ButtonGadget(#myDropDown, 54, 5, 20, 25, "V")
CreatePopupMenu(#myMenu)
MenuItem(#myMenuItem1, "Open") 
MenuItem(#myMenuItem2, "Save") 
MenuItem(#myMenuItem3, "Quit")

Repeat
  
  WWE = WaitWindowEvent() 
  
  Select WWE
    Case #PB_Event_Gadget
      Select EventGadget()
        Case #myDropDown
          DisplayPopupMenu(#myMenu, WindowID(#myWindow))  
      EndSelect
  EndSelect
    
Until WWE = #PB_Event_CloseWindow

Grüße ... Kiffi

Verfasst: **30.09.2010 23:21**

oder mit nem image:

Code: Alles auswählen

Enumeration
  #myWindow
  #myButton
  #myDropDown
  #myMenu
  #myMenuItem1
  #myMenuItem2
  #myMenuItem3
EndEnumeration

CreateImage(#myDropDown, 16, 16, 32|#PB_Image_Transparent)
If StartDrawing(ImageOutput(#myDropDown))
  DrawingMode(#PB_2DDrawing_AlphaChannel)
  For i = 0 To 5
    Line(i+2, i+6, 10-i*2, 1, RGBA(255,0,0,255))
  Next
  StopDrawing()
EndIf

OpenWindow(#myWindow, #PB_Ignore, #PB_Ignore, 100, 100, "")
ButtonGadget(#myButton, 5, 5, 50, 25, "button")
ButtonImageGadget(#myDropDown, 54, 5, 20, 25, ImageID(#myDropDown))
CreatePopupMenu(#myMenu)
MenuItem(#myMenuItem1, "Open")
MenuItem(#myMenuItem2, "Save")
MenuItem(#myMenuItem3, "Quit")

Repeat
 
  WWE = WaitWindowEvent()
 
  Select WWE
    Case #PB_Event_Gadget
      Select EventGadget()
        Case #myDropDown
          DisplayPopupMenu(#myMenu, WindowID(#myWindow)) 
      EndSelect
  EndSelect
   
Until WWE = #PB_Event_CloseWindow

lg kevin

PureBoard

Dropdown-Pfeil zu Button hinzufügen

Dropdown-Pfeil zu Button hinzufügen

Re: Dropdown-Pfeil zu Button hinzufügen

Re: Dropdown-Pfeil zu Button hinzufügen