PureBoard

Code: Alles auswählen

Interface Rechnen
  Plus    (x1,x2)
  Minus   (x1,x2)
EndInterface 


Procedure Rechnen_Plus(*This.Rechnen, x1, x2)  ;<<--- muss hier "This.rechnen" stehen ?
    ProcedureReturn x1+x2
EndProcedure 

Procedure Rechnen_minus(*This.Rechnen, x1, x2)
    ProcedureReturn x1-x2
EndProcedure 


;************************

MyRechnen.Rechnen = Rechnen_CreateObject()         ; <<---Fehler "Not a function, array or macro"

x = Rechnen\Plus(2,2)                ;<<----- wäre das korrekt ?
y = Rechnen\Minus (10,1)

print Str(x)

Code: Alles auswählen

EnableExplicit

Interface Rechnen
  Destroy () ; damit wir den Objektspeicher auch wieder freigeben können!
  Plus    (x1, x2)
  Minus   (x1, x2)
EndInterface

Structure Rechnen_Template
  *vTable
  ; weitere Objectvariablen
EndStructure

Procedure New_RechnenObject() ; Objekt erstellen (Objektspeicher allokieren)
  Protected *this.Rechnen_Template
  
  *this = AllocateMemory(SizeOf(Rechnen_Template))
  If *this
    *this\vTable = ?VTable_RechnenClass
    ; weitere Initialisierungen
    ProcedureReturn *this
  EndIf
EndProcedure

Procedure Rechnen_Destroy(*This.Rechnen_Template)
  FreeMemory(*This)
EndProcedure

Procedure Rechnen_Plus(*This.Rechnen_Template, x1, x2)
    ProcedureReturn x1 + x2
EndProcedure

Procedure Rechnen_Minus(*This.Rechnen_Template, x1, x2)
    ProcedureReturn x1 - x2
EndProcedure

DataSection
  VTable_RechnenClass: ; Methoden, Reihenfolge muß mit Interface übereinstimmen!
  Data.i @Rechnen_Destroy()
  Data.i @Rechnen_Plus()
  Data.i @Rechnen_Minus()
EndDataSection

Define.Rechnen *obj

*obj = New_RechnenObject()
Debug *obj\Plus(20, 10)
Debug *obj\Minus(1000, 100)
*obj\Destroy() : *obj = 0

Code: Alles auswählen

Structure udtRechnen
  *VTable
  cntRef.l
EndStructure

Interface IRechnen Extends IUnknown
  Plus    (x1,x2)
  Minus   (x1,x2)
EndInterface

Procedure.l QueryInterface (*This.udtRechnen, *iid.IID, *Object.Integer)

;Standardzuweisungen auf eigenes Objekt (ggf. noch erweitern mit IID, die erwartet wird)
  If CompareMemory(*iid, ?IID_IUnknown, 16)
    *Object\i = *This
    *This\cntRef + 1
    ProcedureReturn #S_OK
  EndIf

;Unbekanntes Interface
  MessageRequester("Intern" , "QueryInterface hat nach einem nicht impletierten Interface angefragt")
  *Object\i = 0
  ProcedureReturn #E_NOINTERFACE

EndProcedure
Procedure.l AddRef         (*This.udtRechnen)

  *This\cntRef + 1
  ProcedureReturn *This\cntRef

EndProcedure
Procedure.l Release        (*This.udtRechnen)

    *This\cntRef - 1

    If *This\cntRef < 1
      FreeMemory(*This)
      ProcedureReturn 0
    EndIf

    ProcedureReturn *This\cntRef

  EndProcedure
Procedure   Rechnen_Plus   (*This.udtRechnen, x1, x2)  ;<<--- muss hier "This.rechnen" stehen ?

    ProcedureReturn x1+x2

EndProcedure
Procedure   Rechnen_minus  (*This.udtRechnen, x1, x2)

    ProcedureReturn x1-x2

EndProcedure

Procedure Rechnen_New()
  Define *This.udtRechnen

  DataSection

    VTable:
    Data.i @QueryInterface()
    Data.i @AddRef()
    Data.i @Release()
    Data.i @Rechnen_Plus()
    Data.i @Rechnen_minus()

    IID_IUnknown: ; {00000000-0000-0000-C000-000000000046}
    Data.l $00000000
    Data.w $0000,$0000
    Data.b $C0,$00,$00,$00,$00,$00,$00,$46

  EndDataSection

  *This = AllocateMemory(SizeOf(udtRechnen))
  If *This = 0 : MessageRequester ("", "Zu wenig Speicher") : End : EndIf

  *This\VTABLE   = ?VTable
  *This\cntRef + 1

  ProcedureReturn *This

EndProcedure

;************************

Define *Rechnen.IRechnen

;Com-Objekt erstellen
*Rechnen = Rechnen_New()

;Com-Objekt benutzen
Debug *Rechnen\Plus(2,2)
Debug *Rechnen\Minus (10,1)

;Com-Objekt wieder frei geben
*Rechnen\Release()
*Rechnen = 0