PureBoard

Verfasst: **01.01.2010 15:55**

Also ich steh hier wieder vor einem Problem, bei meinem Code wird der ButtonGadget nicht angezeigt
Ich habe auch noch ein ExplorerListGadget und einen ExplorerTreeGadget, wenn ich beide ausblende bzw. einfach lösche, wird der Button normal angezeigt

hier mein Source:

Code: Alles auswählen

;-Window
Enumeration
	#WINDOW_0
EndEnumeration

;-Buttons
Enumeration
	#BUTTON_0
EndEnumeration

;-Explorer
Enumeration
	#EXPLORER_0
	#EXPLORER_1
EndEnumeration

If OpenWindow(#WINDOW_0,100,100,430,250,"New window",#PB_Window_SystemMenu)
	ButtonGadget(#BUTTON_0,10,10,100,20,"Button 1")
	ExplorerTreeGadget(#EXPLORER_0,10,40,200,200,"C:\",#PB_Explorer_NoFiles)
	ExplorerListGadget(#EXPLORER_1,220,40,200,200,"C:\",#PB_Explorer_NoFolders)
	
	For i = 3 To 1 Step -1
		RemoveGadgetColumn(#EXPLORER_1,i)
	Next
	
	Repeat
		Select WaitWindowEvent()
			Case #PB_Event_CloseWindow
				Select EventWindow()
					Case #WINDOW_0
						End
				EndSelect
			Case #PB_Event_Gadget
				Select EventGadget()
					Case #BUTTON_0
						Debug "Hello world"
					Case #EXPLORER_0
						Select EventType()
							Case #PB_EventType_LeftClick
								SetGadgetText(#EXPLORER_1,GetGadgetText(#EXPLORER_0))
						EndSelect
					Case #EXPLORER_1
						Select EventType()
							Case #PB_EventType_LeftClick
								Debug GetGadgetItemText(#EXPLORER_1,GetGadgetState(#EXPLORER_1))
						EndSelect
				EndSelect
		EndSelect
	ForEver
EndIf

Verfasst: **01.01.2010 15:58**

Code: Alles auswählen

;-Window
Enumeration
   #WINDOW_0
EndEnumeration

;-Gadgets
Enumeration
   #BUTTON_0
   #EXPLORER_0
   #EXPLORER_1   
EndEnumeration

; ;-Explorer
; Enumeration
;    #EXPLORER_0
;    #EXPLORER_1
; EndEnumeration

If OpenWindow(#WINDOW_0,100,100,430,250,"New window",#PB_Window_SystemMenu)
   ButtonGadget(#BUTTON_0,10,10,100,20,"Button 1")
   ExplorerTreeGadget(#EXPLORER_0,10,40,200,200,"C:\",#PB_Explorer_NoFiles)
   ExplorerListGadget(#EXPLORER_1,220,40,200,200,"C:\",#PB_Explorer_NoFolders)
   
   For i = 3 To 1 Step -1
      RemoveGadgetColumn(#EXPLORER_1,i)
   Next
   
   Repeat
      Select WaitWindowEvent()
         Case #PB_Event_CloseWindow
            Select EventWindow()
               Case #WINDOW_0
                  End
            EndSelect
         Case #PB_Event_Gadget
            Select EventGadget()
               Case #BUTTON_0
                  Debug "Hello world"
               Case #EXPLORER_0
                  Select EventType()
                     Case #PB_EventType_LeftClick
                        SetGadgetText(#EXPLORER_1,GetGadgetText(#EXPLORER_0))
                  EndSelect
               Case #EXPLORER_1
                  Select EventType()
                     Case #PB_EventType_LeftClick
                        Debug GetGadgetItemText(#EXPLORER_1,GetGadgetState(#EXPLORER_1))
                  EndSelect
            EndSelect
      EndSelect
   ForEver
EndIf

Gadgets müssen eindeutig sein

Verfasst: **01.01.2010 16:01**

ach verdammt, hätte ich eigentlich auch drauf kommen müssen ( - .-)

danke dir nochmal (^. ^ )

PureBoard

Button wird nicht angezeigt

Button wird nicht angezeigt

Re: Button wird nicht angezeigt

Re: Button wird nicht angezeigt