PureBoard

Code: Alles auswählen

ThorSpIm (Thorium Sprite Image) format structure

------
header
------
8 byte signature = ThorSpIm
1 byte format version = 1
2 byte width
2 byte height
----------
image data
----------
32bit per pixel (BGRA)

Code: Alles auswählen

;ThReCo (Thorium Ressource Container) format structure
;------
;header
;------
;6 byte signature = ThReCo
;1 byte format version = 1
;1 byte used compressions (flags)
;1 byte flags
;2 byte alignment
;1 byte compression of directory
;2 byte compressed size of directory    (4 byte on huge file)
;2 byte uncompressed size of directory  (4 byte on huge file)
;4 byte offset of directory             (8 byte on huge file)
;---------
;directory
;---------
;2 byte count of ressources             (4 byte on huge file)
;x byte ressource entries
;---------------
;ressource entry
;---------------
;1 byte lengh descriptor for ressource name
;x byte ressource name
;2 byte version of ressource
;1 byte compression
;1 byte count of language entries
;x byte language entries
;--------------
;language entry
;--------------
;1 byte language
;4 byte compressed size of ressource    (8 byte on huge file)
;4 byte uncompressed size of ressource  (8 byte on huge file)
;4 byte offset of ressource             (8 byte on huge file)
;
;------------
;header flags
;------------
;bit0 = ressource versioning
;bit1 = multilingual
;bit2 = big file (file > 2GB)
;bit3 = huge file (file > 4GB)
;bit4 = unused
;bit5 = unused
;bit6 = unused
;bit7 = unused
;
;-----------------------
;compression enumaration
;-----------------------
;00 = none (uncompressed)
;01 = JCalG1
;02 = bzip2 (not used at the moment)
;03 = BriefLZ (not used at the moment)
;04 = zlib (not used at the moment)
;
;-----------------
;compression flags
;-----------------
;bit0 = JCalG1
;bit1 = bzip2 (not used at the moment)
;bit2 = BriefLZ (not used at the moment)
;bit3 = zlib (not used at the moment)
;bit4 = unused
;bit5 = unused
;bit6 = unused
;bit7 = unused

Code: Alles auswählen

#Tsi_Signature = $6D497053726F6854

Procedure GfxCatchTsi(TsiAddr.i)

  Define.i X, Y , Sprite, Buffer, Pitch, PixelFormat, SourceAddr, SourceLineLen
  Define *SourcePixel.Long
  Define *DestPixel.Long
  Define *Header.TsiHeader
  
  *Header = TsiAddr
  
  ;check if file is a ThorSpIm
  If *Header\Signature <> #Tsi_Signature
    ProcedureReturn 0
  EndIf
  
  ;check the format version of the ThorSpIm
  If *Header\FormatVersion <> 1
    ProcedureReturn 0
  EndIf
  
  ;create empty sprite
  Sprite = CreateSprite(#PB_Any, *Header\Width, *Header\Height, #PB_Sprite_Texture | #PB_Sprite_AlphaBlending)
  
  ;if sprite can not be created, exit procedure
  If Sprite = 0
    ProcedureReturn 0
  EndIf
  
  ;copy the image data to the sprite
  
  StartDrawing(SpriteOutput(Sprite))
  
  Buffer = DrawingBuffer()
  Pitch = DrawingBufferPitch()
  PixelFormat = DrawingBufferPixelFormat()
  
  SourceAddr = TsiAddr + SizeOf(TsiHeader)
  SourceLineLen = *Header\Width * 4
  
  Select PixelFormat
  
    Case #PB_PixelFormat_32Bits_BGR
      ;BGRA format, no conversion needed
    
      If Pitch = SourceLineLen
        ;image data can be copied as hole
        CopyMemory(SourceAddr, Buffer, SourceLineLen * *Header\Height)
      Else
        ;image data have to be copied line by line
        For Y = 0 To *Header\Height - 1
          CopyMemory(SourceAddr + (SourceLineLen * Y), Buffer + (Pitch * Y), SourceLineLen)
        Next
      EndIf
    
    Case #PB_PixelFormat_32Bits_RGB
      ;RGBA format, pixels need to be converted
      
      *SourcePixel = SourceAddr
      For Y = 0 To *Header\Height - 1
        *DestPixel = Buffer + (Pitch * Y)
        For X = 0 To *Header\Width - 1
          *DestPixel\l = ABGR2ARGB(*SourcePixel\l)
          *SourcePixel + 4
          *DestPixel + 4
        Next
      Next
      
    Default
      ;not supported pixel format, exit procedure
    
      FreeSprite(Sprite)
      ProcedureReturn 0
  
  EndSelect
  
  StopDrawing()

  ProcedureReturn Sprite

EndProcedure