PureBoard

Code: Alles auswählen

;
**********************************************************************
;
; ListDirectory() - PB-Include
;
; Author: Scarabol
; Version: 4.10
; Datum: 14-02-2008
;
; **********************************************************************
;
; ListDirectory(Directory$, Level, Pattern$)
;
; Beschreibung:
;   Listet alle im Verzeichnis befindlichen Dateien und Unterverzeichnisse auf.
;
; Rückgabewert:
;   Die Funktion gibt einen String zurück.
;   Die Einträge sind durch Chr(10) getrennt.
;

Procedure.s ListDirectory(directory$, level.l=0, pattern$="*.*")
  Protected dir$, d.l, t$
  d = ExamineDirectory(#PB_Any, directory$, pattern$)
  While NextDirectoryEntry(d)
    If DirectoryEntryType(d) = #PB_DirectoryEntry_Directory
      If Not (DirectoryEntryName(d) = "." Or DirectoryEntryName(d) = "..")
        dir$ + directory$+DirectoryEntryName(d)+"\" + Chr(10)
        If level > 0
          t$ = ListDirectory(directory$+DirectoryEntryName(d)+"\", level-1)
          If t$
            dir$ + t$
          EndIf
        EndIf
      EndIf
    ElseIf DirectoryEntryType(d) = #PB_DirectoryEntry_File
      dir$ + DirectoryEntryName(d) + Chr(10)
    EndIf
  Wend
  ProcedureReturn dir$
EndProcedure

; **********************************************************************
;
; ListDirectory() - Example

EnableExplicit

Define d$
Define c.l

d$ = ListDirectory("C:\Windows\")

For c = 1 To CountString(d$, Chr(10))+1
  Debug StringField(d$, c, Chr(10))
Next

;
; **********************************************************************

Code: Alles auswählen

ListDirectory("C:\", 0, "Thumbs.db")