PureBoard

Code: Alles auswählen

;XIncludeFile "E:\pbi\drawTextLF.pbi"
;{ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~\ E:\pbi\drawTextLF.pbi
        ; drawTextLF.pbi
        ; [..just a LineFeed-able drawText ]
        
        Global drawTextLF_EndX.l  ; use these variables after a call of drawTextLF() to retrieve the pixel
        Global drawTextLF_EndY.l  ; position where drawTextLF() finished (the upper right corner of end of text)
        
        Global drawTextLF_MaxX.l ; right side of last drawn text area (x + length in pixel of the longest line)
        
        ; parameters:
        ; x / y           : starting position
        ; text            : text to be drawn on current drawing-output.
        ; color           : textcolor
        ; xWrapTo         : x-position of further drawing after linefeed occurrence (default value is your passed 'x'-parameter)
        ; lineSeperator$  : the string that is used in 'text' as line seperator (default value is '#LF$')
        Procedure drawTextLF(x.l, y.l, text.s, color.l, xWrapTo.l=-1, lineSeperator$=#LF$)
          Static yPitch.l
          Static xPitch.l
          Static line.s
          Static i.l
          Static n.l
          drawTextLF_MaxX = 0
          If xWrapTo=-1
            xWrapTo=x
          EndIf
          yPitch=TextHeight("X")
          n=CountString(text,lineSeperator$)
          For i=0 To n
            line=StringField(text,i+1,lineSeperator$)
            xPitch=DrawText( x, y+i*yPitch, line, color)
            If xPitch>drawTextLF_MaxX
              drawTextLF_MaxX = xPitch
            EndIf
            If i=0
              x=xWrapTo
            EndIf
          Next
          drawTextLF_EndX = xPitch
          drawTextLF_EndY = y+(i-1)*yPitch
        EndProcedure
        
        
        
        ; [...]
;}
;  ________________________________/ [end] E:\pbi\drawTextLF.pbi



InitSprite()
InitMouse()
InitKeyboard()
ww=800
wh=600
hWin=OpenWindow(0, 50,100,ww,wh, "")
OpenWindowedScreen( hWin, 0,0,ww,wh, 0,0,0)

Define text.s
text=" jsfjssfj"+#LF$
text+" dfhhfghg h"+#LF$
text+"gfsj gj j"+#LF$
text+"fg sjfgj gsj "+#LF$
text+"     ------------"+#LF$
text+".,,.hlk.+123"

Repeat
  event=WaitWindowEvent(30)
  ExamineKeyboard()
  ExamineMouse()
  x=MouseX()
  y=MouseY()
  StartDrawing(ScreenOutput())
    DrawingMode(#PB_2DDrawing_Transparent | #PB_2DDrawing_Outlined)
    drawTextLF( x,y, text, $00ff00)
    Box( x,y, drawTextLF_MaxX - x, TextHeight(text)*(1+CountString(text,#LF$)), $ff2222)
  StopDrawing()
  FlipBuffers()
  ClearScreen($333333)
Until event=#PB_Event_CloseWindow Or KeyboardPushed(#PB_Key_Escape)