PureBoard

Das deutsche PureBasic-Forum
https://www.purebasic.fr/german/

Erstellen eines Date-Requesters

https://www.purebasic.fr/german/viewtopic.php?t=13431

Seite 1 von 1

Erstellen eines Date-Requesters

Verfasst: 27.06.2007 11:52
von Kurzer
Hall ozusammen,
ich hab grad mal wieder "Schaltschwierigkeiten".

Ich möchte mir einen Datums-Auswahlrequester bauen, der aus einem kleinen Fenster, einem Datumsgadget und einem OK Button besteht.

Code: Alles auswählen

  If OpenWindow(#Window_Input, 100, 100, 150, 40, "Eingabe",  #PB_Window_SystemMenu | #PB_Window_TitleBar | #PB_Window_WindowCentered )
    If CreateGadgetList(WindowID(#Window_Input))
      DateGadget(#Date_Input, 10, 10, 90, 20, "%mm/%dd/%yyyy", Date())
      ButtonGadget(#Button_Input_Ok, 110, 10, 30, 20, "OK")
    EndIf
  EndIf
Nun hat mein eigentliches Programm, in dem ich diesen Requester brauche, schon einen recht heftigen Eventloop.

Wie realisiere ich so einen selbstgebauten Requester, ohne daß ich die Eventabfrage in meinen großen Eventloop einflechten muß?
OpenWindow, CloseWindow Proceduren kann ich ja unterbringen, aber um den OK Button abzufragen, muß ich auf die Events reagieren.

Eigentlich schwebt mir ein modaler Dialog vor ala:
Datum = EigenerDatumsRequester (x, y, breite, hoehe, Defaultdatum)

Aber wie mache ich das mit dem Eventloop ohne meinen Haupteventloop nutzen zu müssen.
Ich hätte alles, was zu dem EingabeRequester gehört gern irgendwo gekapselt (eigenes Include oder so...).

Markus

Verfasst: 27.06.2007 11:59
von Kurzer
Okay, sorry... Blick ins Codearchiv hat geholfen...

(Blöd, wenn man unter Zeitdruck was machen muß und an einer Stelle plötzlich nicht weiterkommt... da kommt dann nen bisserl Panik auf)

Markus

Verfasst: 27.06.2007 12:16
von ts-soft
Jetzt wo ich mich mit Beispiel abgequält habe :cry:
Mußte trotzdem gucken :wink:

Code: Alles auswählen

Procedure DateRequester(MainID.l)
  Protected win.l, date.l, btn.l, result.l
  win = OpenWindow(#PB_Any, 100, 100, 150, 40, "Eingabe",  #PB_Window_SystemMenu | #PB_Window_TitleBar | #PB_Window_WindowCentered , WindowID(MainID))
  If win And CreateGadgetList(WindowID(win))
    date = DateGadget(#PB_Any, 10, 10, 90, 20, "%mm/%dd/%yyyy", Date())
    btn = ButtonGadget(#PB_Any, 110, 10, 30, 20, "OK")
    
    DisableWindow(MainID, #True)
    Repeat
      Select WaitWindowEvent()
        Case #PB_Event_CloseWindow
          If EventWindow() = win
            Break
          EndIf
        Case #PB_Event_Gadget
          If EventGadget() = btn
            Break
          EndIf
      EndSelect
    ForEver
    result = GetGadgetState(date)
    CloseWindow(win)
    DisableWindow(MainID, #False)
    ProcedureReturn result
  EndIf
EndProcedure

If OpenWindow(0, #PB_Ignore, #PB_Ignore, 640, 480, "Main")
  Debug DateRequester(0)
EndIf

Verfasst: 27.06.2007 12:32
von Kurzer
Man bist Du fix. :allright: Danke!

Soll auch nicht vergeblich gewesen sein, daher werde ich Dein Beispiel als Vorlage nutzen. ;)

Verfasst: 27.06.2007 13:37
von Kaeru Gaman
@ts
ich würde das aber ggf durch nen cancel button ergänzen.
auch beim schließen über CloseWindow sollte der wert im date-gadget nicht übernommen werden...

Verfasst: 27.06.2007 13:50
von ts-soft
Kaeru Gaman hat geschrieben:@ts
ich würde das aber ggf durch nen cancel button ergänzen.
auch beim schließen über CloseWindow sollte der wert im date-gadget nicht übernommen werden...
Bissel kann er auch selber korrigieren :mrgreen: , hab ja nur seine Styles
übernommen, besser wäre es so:

Code: Alles auswählen

Procedure DateRequester(MainID.l)
  Protected win.l, date.l, btn.l, result.l

  win = OpenWindow(#PB_Any, 100, 100, 150, 40, "Eingabe",  #PB_Window_SystemMenu | #PB_Window_WindowCentered , WindowID(MainID))

  If win And CreateGadgetList(WindowID(win))

    SetWindowLong_(WindowID(win), #GWL_EXSTYLE, GetWindowLong_(WindowID(win), #GWL_EXSTYLE) | #WS_EX_TOOLWINDOW)
    SetWindowPos_(WindowID(win), 0, 0, 0, 0, 0, #SWP_FRAMECHANGED | #SWP_NOMOVE | #SWP_NOSIZE)

    AddKeyboardShortcut(win, #PB_Shortcut_Escape, 100)

    date = DateGadget(#PB_Any, 10, 10, 90, 20, "%mm/%dd/%yyyy", Date())
    btn = ButtonGadget(#PB_Any, 110, 10, 30, 20, "OK")

    DisableWindow(MainID, #True)

    Repeat

      Select WaitWindowEvent()

        Case #PB_Event_CloseWindow
          If EventWindow() = win
            CloseWindow(win)
            DisableWindow(MainID, #False)
            ProcedureReturn #False
          EndIf
        Case #PB_Event_Menu
          If EventMenu() = 100
            CloseWindow(win)
            DisableWindow(MainID, #False)
            ProcedureReturn #False
          EndIf
        Case #PB_Event_Gadget
          If EventGadget() = btn
            result = GetGadgetState(date)
            CloseWindow(win)
            DisableWindow(MainID, #False)
            ProcedureReturn result
          EndIf

      EndSelect

    ForEver

  EndIf
EndProcedure

If OpenWindow(0, #PB_Ignore, #PB_Ignore, 640, 480, "Main")
  Debug DateRequester(0)
EndIf
Wobei ich es auch nicht window-centered machen würde

Verfasst: 27.06.2007 14:03
von Kurzer
Anpassungen machen ist klar... ich brauchte nur einen Wink in die richtige Richtung.

Ich setze den Requester jetzt so ein:

Code: Alles auswählen

Procedure.l InputDate(CallerWindowID.l, X.l, Y.l, Title$, DefaultDate.l)
  Protected Window.l, Date.l, Button.l, Result.l, Ok.b = #False
  
  Window = OpenWindow(#PB_Any, X, Y, 150, 40, Title$,  #PB_Window_SystemMenu | #PB_Window_TitleBar, WindowID(CallerWindowID))

  If Window And CreateGadgetList(WindowID(Window))
    Date = DateGadget(#PB_Any, 10, 10, 90, 20, "%mm/%dd/%yyyy", DefaultDate)
    Button = ButtonGadget(#PB_Any, 110, 10, 30, 20, "OK")
   
    DisableWindow(CallerWindowID, #True)

    Repeat
      Select WaitWindowEvent()
        Case #PB_Event_CloseWindow
          If EventWindow() = Window : Break : EndIf
        Case #PB_Event_Gadget 
          If EventGadget() = Button : Ok = #True : Break : EndIf
      EndSelect
    ForEver
    
    Result = GetGadgetState(Date)
    CloseWindow(Window)
    DisableWindow(CallerWindowID, #False)
    If Ok = #True : ProcedureReturn Result : EndIf
  EndIf

EndProcedure

Verfasst: 27.06.2007 16:39
von Kurzer
/:-> Noch'n Gedicht:

Warum gibt es in dieser Version des DatumsrRequesters Probleme mit der Abfrage, wenn zuvor im DateGadget die Cursortasten benutzt worden sind...

Code: Alles auswählen

Procedure.l InputDate(CallerWindowID.l, CallerItemID.l, X.l, Y.l, Title$, DefaultDate.l)
  Protected Event.l, EventwParam.l, EventWindow.l, EventGadget.l, Window.l, Date.l, Button.l, Result.l = -1
  
  Window = OpenWindow(#PB_Any, X, Y, 150, 40, Title$,  #PB_Window_SystemMenu | #PB_Window_TitleBar, WindowID(CallerWindowID))

  If Window And CreateGadgetList(WindowID(Window))
    Date = DateGadget(#PB_Any, 10, 10, 90, 20, "%mm/%dd/%yyyy", DefaultDate)
    Button = ButtonGadget(#PB_Any, 110, 10, 30, 20, "OK")
   
    DisableWindow(CallerWindowID, #True)
    SetActiveGadget(Date)

    Repeat
      Event       = WaitWindowEvent()
      EventWindow = EventWindow()
      EventwParam = EventwParam()
      EventGadget = EventGadget()

      If EventWindow = Window                  ; ############################
        Select Event
          Case #PB_Event_CloseWindow
            Result = 0
          Case #WM_KEYUP
            If EventwParam = #VK_ESCAPE : Result = 0 : EndIf
            If EventwParam = #VK_RETURN : Result = GetGadgetState(Date) : EndIf
            Debug EventwParam
          Case #PB_Event_Gadget
            If EventGadget = Button : Result = GetGadgetState(Date) : EndIf
        EndSelect
      EndIf                                    ; ############################
    Until Result > -1
    
    CloseWindow(Window)
    DisableWindow(CallerWindowID, #False)
    SetActiveGadget(CallerItemID)

    ProcedureReturn Result
  EndIf

EndProcedure
... und in dieser Version nicht?

Code: Alles auswählen

Procedure.l InputDate(CallerWindowID.l, CallerItemID.l, X.l, Y.l, Title$, DefaultDate.l)
  Protected Event.l, EventwParam.l, EventWindow.l, EventGadget.l, Window.l, Date.l, Button.l, Result.l = -1
  
  Window = OpenWindow(#PB_Any, X, Y, 150, 40, Title$,  #PB_Window_SystemMenu | #PB_Window_TitleBar, WindowID(CallerWindowID))

  If Window And CreateGadgetList(WindowID(Window))
    Date = DateGadget(#PB_Any, 10, 10, 90, 20, "%mm/%dd/%yyyy", DefaultDate)
    Button = ButtonGadget(#PB_Any, 110, 10, 30, 20, "OK")
   
    DisableWindow(CallerWindowID, #True)
    SetActiveGadget(Date)

    Repeat
      Event       = WaitWindowEvent()
      EventWindow = EventWindow()
      EventwParam = EventwParam()
      EventGadget = EventGadget()

      Select Event
        Case #PB_Event_CloseWindow
          If EventWindow = Window : Result = 0 : EndIf        ; ##########################
        Case #WM_KEYUP
          If EventwParam = #VK_ESCAPE : Result = 0 : EndIf
          If EventwParam = #VK_RETURN : Result = GetGadgetState(Date) : EndIf
          Debug EventwParam
        Case #PB_Event_Gadget
          If EventGadget = Button : Result = GetGadgetState(Date) : EndIf
      EndSelect
    Until Result > -1
    
    CloseWindow(Window)
    DisableWindow(CallerWindowID, #False)
    SetActiveGadget(CallerItemID)

    ProcedureReturn Result
  EndIf

EndProcedure
Die Unterschiede sind mit # markiert.

In der ersten Version (mit dem "WindowID-If" drumherum) reagieren ESC und RETURN nicht mehr, wenn ich mittels Cursor im DatumsGadget rumgekurft bin.

Verfasst: 27.06.2007 16:49
von ts-soft
Du solltest besser immer das Fenster unterscheiden, auch wenn das andere
deaktiviert ist, ich weiß nicht ob alle API events deaktiviert sind.

Also immer erst prüfen, ob Dein Requester gemeint ist, auch für alle #WM_
ereignisse.

Ausserdem solltest Du shortcuts nehmen für Escape und Return. Für Escape
ist es in meinem Beispiel schon eingebaut.

Verfasst: 27.06.2007 16:59
von Kurzer
ts-soft hat geschrieben:Du solltest besser immer das Fenster unterscheiden, auch wenn das andere
deaktiviert ist, ich weiß nicht ob alle API events deaktiviert sind.

Also immer erst prüfen, ob Dein Requester gemeint ist, auch für alle #WM_
ereignisse.
Witzigerweise gibts die Probleme ja in der Version, die nur die Events des Requesters-Fensters abfragt:

If EventWindow = Window
... Eventbearbeitung
EndIf

Aber evtl. relativiert sich das bei der Benutzung von Shortcuts.

edit: [kurze Zeit später...] Supi, so gehts jetzt einwandfrei!

Code: Alles auswählen

Procedure.l InputDate(CallerWindowID.l, CallerItemID.l, X.l, Y.l, Title$, DefaultDate.l)
  Protected Event.l, EventWindow.l, EventGadget.l, EventMenu.l, Window.l, Date.l, Button.l, Result.l = -1
  
  Window = OpenWindow(#PB_Any, X, Y, 150, 40, Title$,  #PB_Window_SystemMenu | #PB_Window_TitleBar, WindowID(CallerWindowID))
  AddKeyboardShortcut(Window, #PB_Shortcut_Escape, #VK_ESCAPE) 
  AddKeyboardShortcut(Window, #PB_Shortcut_Return, #VK_RETURN) 
  
  If Window And CreateGadgetList(WindowID(Window))
    Date = DateGadget(#PB_Any, 10, 10, 90, 20, "%mm/%dd/%yyyy", DefaultDate)
    Button = ButtonGadget(#PB_Any, 110, 10, 30, 20, "OK")
   
    DisableWindow(CallerWindowID, #True)
    SetActiveGadget(Date)

    Repeat
      Event       = WaitWindowEvent()
      EventWindow = EventWindow()
      EventGadget = EventGadget()
      EventMenu   = EventMenu()

      If EventWindow = Window
        Select Event
          Case #PB_Event_CloseWindow
             Result = 0
          Case #PB_Event_Menu
            If EventMenu = #VK_RETURN : Result = GetGadgetState(Date) : EndIf
            If EventMenu = #VK_ESCAPE : Result = 0 : EndIf
          Case #PB_Event_Gadget
            If EventGadget = Button : Result = GetGadgetState(Date) : EndIf
        EndSelect
      EndIf
    Until Result > -1
    
    CloseWindow(Window)
    DisableWindow(CallerWindowID, #False)
    SetActiveGadget(CallerItemID)

    ProcedureReturn Result
  EndIf

EndProcedure
Alle Zeiten sind UTC+02:00
Seite 1 von 1

Powered by phpBB® Forum Software © phpBB Limited

Deutsche Übersetzung durch phpBB.de