PureBoard

Code: Alles auswählen

Procedure ButtonHandler()
  ;Debug "Button click event on gadget #" + EventGadget()
  ; wenn man hier den EventGadget mit EventGadget() ermittelt und mit If... abfragt,
  ; hat man eine Universal-Procedure für alle anfallenden Button-Gadgets
  If EventGadget() = 3 
    
    InitialPath1$ = "C:\my Basic\PureBasic\source.txt"   ; anfänglichen Pfad für die Anzeige festlegen (kann auch leer sein)
    Pattern$ = "executable (*.exe;*.dll)|*.exe;*.dll|Alle Dateien (*.*)|*.*"
    Pattern = 0    ; wir verwenden den ersten von drei möglichen Pattern als Standard
    File1$ = OpenFileRequester("Bitte Datei zum Laden auswählen", InitialPath1$, Pattern$, Pattern)
    SetGadgetText(#Str_Source_DIR, File1$)
      IncludeFile  "CreatePreferencesA.pbi"
  ;  IncludeFile "OpenPreferences.pbi"
    
  ElseIf EventGadget() = 4
    
    InitialPath2$ = "C:\my Basic\PureBasic\target.txt"   ; anfänglichen Pfad für die Anzeige festlegen (kann auch leer sein)
    Pattern$ = "executable (*.exe;*.dll)|*.exe;*.dll|Alle Dateien (*.*)|*.*"
    Pattern = 0    ; wir verwenden den ersten von drei möglichen Pattern als Standard
    File2$ = OpenFileRequester("Bitte Datei zum Laden auswählen", InitialPath2$, Pattern$, Pattern)
    SetGadgetText(#Str_Target_DIR, File2$)
      IncludeFile  "CreatePreferencesB.pbi"
    IncludeFile "OpenPreferences.pbi"
    
        Debug File1$ <- existiert nicht mehr
    
  ElseIf EventGadget() = 5          
    
    InitialPath3$ = "C:\my Basic\PureBasic\my Patch\new\patch.csp"   ; anfänglichen Pfad für die Anzeige festlegen (kann auch leer sein)
    Pattern$ = "executable (*.exe;*.dll)|*.exe;*.dll|Alle Dateien (*.*)|*.*"
    Pattern = 1    ; wir verwenden den ersten von drei möglichen Pattern als Standard
    File3$ = OpenFileRequester("Bitte Datei zum Laden auswählen", InitialPath3$, Pattern$, Pattern)
    SetGadgetText(#Str_Patch_DIR, File3$)
    IncludeFile  "CreatePreferencesC.pbi"
    IncludeFile "OpenPreferences.pbi"
    
    Debug File1$ <- existiert nicht mehr
    Debug File2$ <- existiert nicht mehr
    Debug File3$
    createpatch(File1$,File2$,File3$)
    
    
  EndIf
  IncludeFile "OpenPreferences.pbi"
 ; createpatch(File1$,File2$,File3$)
EndProcedure

Code: Alles auswählen

 File1$ = OpenFileRequester("Bitte Datei zum Laden auswählen", InitialPath1$, Pattern$, Pattern)

Code: Alles auswählen

Define texte$

CreatePreferences("Pfade.pref")
Datei1$ = "C:\Source\meine.exe"
Datei2$ = "C:\Target\meine.exe"
Datei3$ = "C:\patch\mein-patch.ptc"

WritePreferenceString("Datei1", Datei1$) 
WritePreferenceString("Datei2", Datei2$)
WritePreferenceString("Datei3", Datei3$)
ClosePreferences()
If OpenPreferences("Pfade.pref")
   ExaminePreferenceKeys()
   While NextPreferenceKey() 
       texte$ = texte$ + PreferenceKeyName() + " = " + PreferenceKeyValue() + #LF$
   Wend
   texte$ = texte$ +  #LF$
   Debug texte$
   ClosePreferences()
 EndIf

Code: Alles auswählen

Procedure ButtonHandler()
  ;Debug "Button click event on gadget #" + EventGadget()
  ; wenn man hier den EventGadget mit EventGadget() ermittelt und mit If... abfragt,
  ; hat man eine Universal-Procedure für alle anfallenden Button-Gadgets
  If EventGadget() = 3 
  
    Shared File1$
    Shared File2$
    Shared File3$

Code: Alles auswählen

EnableExplicit 

Code: Alles auswählen

Procedure patchit(File1$,File3$)
  Protected ByteOld.b , ByteDiff.b
  Protected PakMD5.s
  Protected PakSize.l, i.l
  Protected *Patch, *DataFile
  
  UseMD5Fingerprint() 
  UseLZMAPacker()
  
  OpenPack(0,File3$)
  *Patch = NextPackEntry(0)
  PakSize = PackEntrySize(0)
  PakMD5 =  PeekS(*Patch,32)
  

Code: Alles auswählen

CompilerIf #PB_Compiler_IsMainFile ; 
  Global Updater$ = "C:\Temp\Test_update.zip"   ; <- is created 
  Global OldFile$ = "C:\Temp\Test1.txt"         ; <- must exist 
  Global NewFile$ = "C:\Temp\Test2.txt"         ; <- must exist 

; ; this creates a Package (ZIP File) with NewFile$ and MD5 Checksum .... 
; Debug CreatePackage(Updater$, OldFile$, NewFile$) 

; ; this updates OldFile$ with NewFile$ from Package .... 
; Debug PatchWithPackage(Updater$, OldFile$) 
  
CompilerEndIf 

Code: Alles auswählen

UseZipPacker()        ; <-- plugin for Packer 
;                     ;     You need one of these: UseZipPacker(), UseLzmaPacker(), UseTarPacker(), UseBriefLZPacker(). 
UseMD5Fingerprint()   ; <-- plugin for Checksum 


#PACKAGE      = 1   
#FILE_Patch   = 1 

#MD5_SIZE = 32  ; size of MD5 is always 32 chars 

; --- Helper: Ask User for Confirmation ---
; 
Procedure Confirm(Message$)
  If MessageRequester("", Message$, #PB_MessageRequester_Info|#PB_MessageRequester_YesNo) = #PB_MessageRequester_Yes 
    ProcedureReturn #True 
  EndIf 
  ProcedureReturn #False 
EndProcedure


; create the file with the new Patch file 
; 
Procedure CreatePackage(Package$, OldFile$, NewFile$)  ; --- 
  Protected checksumOldFile$, checksumNewFile$, packedFile$ 
  Protected result, *fmem, fsize, bytes 

  If FileSize(Package$) > -1  ; existing file 
    If Confirm("Packet-Datei existiert bereits. " + #LF$ + "Überschreiben?") = #False  
      ProcedureReturn #False  ; don't overwrite the existing file 
    EndIf 
  EndIf 

  checksumOldFile$ = FileFingerprint(OldFile$, #PB_Cipher_MD5)  
  checksumNewFile$ = FileFingerprint(NewFile$, #PB_Cipher_MD5) 
  If checksumOldFile$ = checksumNewFile$ 
    ProcedureReturn #False 
  EndIf 
  
  If CreatePack(#PACKAGE, Package$) 
    ; read file to buffer 
    If ReadFile(#FILE_Patch, NewFile$) 
      fsize = Lof(#FILE_Patch) + #MD5_SIZE 
      *fmem = AllocateMemory(fsize) 
      If *fmem 
        bytes = ReadData(#FILE_Patch, *fmem + #MD5_SIZE, fsize - #MD5_SIZE)  ; keep the 32 byte for md5 
        If bytes 
          Debug "Number of bytes read: " + Str(bytes) + "  " + Str(fsize - #MD5_SIZE) 
          PokeS(*fmem, checksumOldFile$, #MD5_SIZE, #PB_String_NoZero|#PB_Ascii)  ; Writes the strings in ascii

          packedFile$ = ReplaceString(NewFile$, #PS$, "?") ; change PathSeparator with some char not allowed in filenames 
          AddPackMemory(#PACKAGE, *fmem, fsize, packedFile$) 
          result = #True 
        EndIf 
        FreeMemory(*fmem) 
      EndIf 
      CloseFile(#FILE_Patch)
    EndIf 
    ClosePack(#PACKAGE) 
  EndIf 
  ProcedureReturn result ; default is #False 
EndProcedure 


; patch the old file with the new file from Package 
; 
Procedure PatchWithPackage(Package$, OldFile$)  ; --- 
  Protected checksumOldFile$, packed$ 
  Protected result, *fmem, fsize 

  If FileSize(OldFile$) = -1  ; not existing old file 
    ; ERROR 
    ProcedureReturn #False 
  EndIf 

  checksumOldFile$ = FileFingerprint(OldFile$, #PB_Cipher_MD5)  

  If OpenPack(#PACKAGE, Package$) 
    If ExaminePack(#PACKAGE) 
      While NextPackEntry(#PACKAGE)  
        fsize = PackEntrySize(#PACKAGE) 
;Debug "Name: " + PackEntryName(#PACKAGE) + ", Size: " + fsize 

        *fmem = AllocateMemory(fsize) ;, #PB_Memory_NoClear)  
        If *fmem 
          If UncompressPackMemory(#PACKAGE, *fmem, fsize) <> -1 
            packed$ = PeekS(*fmem, #MD5_SIZE, #PB_Ascii)            
            If checksumOldFile$ = packed$  ; 
              If CopyFile(OldFile$, OldFile$ + ".bak") 
                If CreateFile(#FILE_Patch, OldFile$) 
                  WriteData(#FILE_Patch, *fmem + #MD5_SIZE, fsize - #MD5_SIZE) 
                  CloseFile(#FILE_Patch)  
                  result = #True  ; 
                EndIf 
              EndIf 
            EndIf 
          EndIf         
          FreeMemory(*fmem) 
        EndIf 
      Wend
    EndIf 
    ClosePack(#PACKAGE) 
  EndIf 
  ProcedureReturn result ; default #False 
EndProcedure 


CompilerIf #PB_Compiler_IsMainFile ; create a file .... 

  Global Updater$ = "C:\Temp\Test_update.zip"   ; <- is created 
  Global OldFile$ = "C:\Temp\Test1.txt"         ; <- must exist 
  Global NewFile$ = "C:\Temp\Test2.txt"         ; <- must exist 

; ; this creates a Package (ZIP File) with NewFile$ and MD5 Checksum .... 
; Debug CreatePackage(Updater$, OldFile$, NewFile$) 

; ; this updates OldFile$ with NewFile$ from Package .... 
; Debug PatchWithPackage(Updater$, OldFile$) 
  
CompilerEndIf