PureBoard

Code: Alles auswählen

; http://msdn.microsoft.com/en-us/library/bb773836%28v=VS.85%29.aspx

EnableExplicit

Prototype SHMessageBoxCheck(hWnd, Text.s, Caption.s, uType, iDefault, RegVal.s)
Procedure MessageRequesterCheck(Titel.s, Text.s, RegVal.s, Flags = 0)
  Protected hDLL = OpenLibrary(#PB_Any, "Shlwapi.dll")
  Protected SHMessageBoxCheck.SHMessageBoxCheck
  Protected result
 
  CompilerIf #PB_Compiler_Unicode
    SHMessageBoxCheck = GetFunctionEntry(hDLL, 191)
  CompilerElse
    SHMessageBoxCheck = GetFunctionEntry(hDLL, 185)
  CompilerEndIf
  If SHMessageBoxCheck
    result = SHMessageBoxCheck(0, Text, Titel, Flags, #PB_Ignore, RegVal)
  Else
    result = MessageRequester(Text, Titel, Flags)
  EndIf
  CloseLibrary(hDLL)
  ProcedureReturn result
EndProcedure


Select MessageRequesterCheck("Fehler:", "Du bist zu blöd zum Mäuse melken", "{9937FEAC-4F3B-44F0-9D96-20D8F1784479}", #MB_YESNO | #MB_ICONERROR)
  Case #PB_MessageRequester_Yes
    Debug "Siehst es ja wenigstens ein"
  Case #PB_MessageRequester_No
    Debug "Na dann melk mal"
  Case #PB_Ignore
    Debug "Ach, haste mich abgeschaltet ;)"
EndSelect

Code: Alles auswählen

CompilerIf Defined(GUID, #PB_Structure) = #False
Structure GUID
  Data1.l
  Data2.w
  Data3.w
  Data4.b[8]
EndStructure
CompilerEndIf

CompilerIf #PB_Compiler_OS = #PB_OS_Linux
; requires uuid-dev
ImportC "-luuid"
  uuid_generate(*out.GUID)
  uuid_unparse_upper(*uu.GUID, *out)
EndImport
CompilerEndIf

Procedure.s MakeGUID()
  Protected guid.GUID, result.s
  
  CompilerSelect #PB_Compiler_OS
    CompilerCase #PB_OS_Linux
      result = Space(36)
      uuid_generate(@guid)
      uuid_unparse_upper(@guid, @result)
      result = "{" + PeekS(@result, -1, #PB_Ascii) + "}"        
    CompilerCase #PB_OS_Windows
      Protected lpsz.s{76}
      If CoCreateGuid_(@guid) = #S_OK
        result = PeekS(@lpsz, StringFromGUID2_(guid, @lpsz, 76), #PB_Unicode)
      EndIf      
    CompilerDefault
    
  CompilerEndSelect
  
  ProcedureReturn result
EndProcedure

Debug MakeGUID()

Code: Alles auswählen

Procedure.s ExpandEnvironmentString(String.s)
	Protected ExpandString.s, Length.i
	Length = ExpandEnvironmentStrings_(@String, #Null, #Null)
	ExpandString = Space(Length)
	ExpandEnvironmentStrings_(@String, @ExpandString, Length)
	ProcedureReturn ExpandString
EndProcedure

Debug ExpandEnvironmentString("%ProgramFiles%")
Debug ExpandEnvironmentString("%HomeDrive%%HomePath%")
Debug ExpandEnvironmentString("%AppData%\Meine Firma")