Interface mit Daten (Beispiel für PB4)

[mk-soft]

@Leonhard

schönes Beispiel. Habe es etwas geändert. Finde es mit DataSection übersichtlicher.
[Edit] Geht naturlich nur mit PB4

Code: Alles auswählen

Interface IMsgBox ; Interface
  SetTitle(Titel.s)
  SetText(text.s)
  SetFlags(flags.l)
  Show()
  Free()
EndInterface

Structure MsgBox_M ; Interface-Daten (*this)
  *VT.l
  Titel.s
  text.s
  flags.l
EndStructure

Procedure MsgBox_SetTitle(*this.MsgBox_M, Titel.s)
  *this\Titel = Titel
EndProcedure

Procedure MsgBox_SetText(*this.MsgBox_M, text.s)
  *this\text = text
EndProcedure

Procedure MsgBox_SetFlags(*this.MsgBox_M, flags.l)
  *this\flags = flags
EndProcedure

Procedure MsgBox_Show(*this.MsgBox_M)
  ProcedureReturn MessageRequester(*this\Titel, *this\text, *this\flags)
EndProcedure

Procedure MsgBox_Free(*this.MsgBox_M)
  FreeMemory(*this)
EndProcedure

Procedure New_MsgBox()
  *object.MsgBox_M    = AllocateMemory(SizeOf(MsgBox_M))
  *object\VT = ?vtMsgbox
  ProcedureReturn *object
EndProcedure

box.IMsgBox = New_MsgBox()
If box
  box\SetTitle("OOP_MessageBox")
  box\SetText("Magst Du OOP?")
  box\SetFlags(#PB_MessageRequester_YesNo)
  Select box\Show()
    Case #PB_MessageRequester_Yes
      box\SetText("Oh, das Freut mich!")
    Case #PB_MessageRequester_No
      box\SetText("Das macht mich Traurig")
  EndSelect
  box\SetFlags(#PB_MessageRequester_Ok)
  box\Show()
  box\Free()
EndIf


DataSection
  vtMsgBox:
    Data.l @MsgBox_SetTitle()
    Data.l @MsgBox_SetText()
    Data.l @MsgBox_SetFlags()
    Data.l @MsgBox_Show()
    Data.l @MsgBox_Free()
EndDataSection

FF

P.S. Man braucht weniger programmieren.

[inc.]

Geht der Trend zu OOP? Wird mehr OO oder prozedural programmiert?

Habe auch erst kürzlich damit angefangen.
Suche mal hier im Forum nach Hallodri's OOP Plugin.
Wenn du dies installierst und mal seine Beispiele durchgehst, wirst du vieles direkt auf Anhieb verstehen.
Wenn du es einmal verstanden und genutzt hast, wirst du sicher fix daran gefallen finden. Mich hats sogar a bisserl süchtig gemacht.

[ts-soft]

Das Beispiel von Leonard finde ich auch sehr schön, könnte fast von mir sein

Wurde noch in PB3.94 verfaßt, deshalb noch etwas holprig!

[Leonhard]

Ich hab das Beispiel irgendwo bekommen, wo ich eine Frage zum Thema "Was ist ein Interface und wie benutze ich es?".

@mk-soft

Ich find das mit DataSection auch besser verständlich. Nachteil ist, das man eventuell komunigations-schwierigkeiten bei dem Labels bekommt, wenn man ein Label im Hauptprogramm erstellt. Das will ich vermeiden.

Gibt es eigendlich noch andere Typen, wie man ein Interface mit seinen Procedure-Pointer einschreiben kann?

[Leonhard]

Ich hab das Beispiel irgendwo bekommen, wo ich eine Frage zum Thema "Was ist ein Interface und wie benutze ich es?".

@mk-soft
Ich find das mit DataSection auch besser verständlich. Nachteil ist, das man eventuell komunigations-schwierigkeiten bei dem Labels bekommt, wenn man ein Label im Hauptprogramm erstellt. Das will ich vermeiden.

@all
Gibt es eigendlich noch andere Typen, wie man ein Interface mit seinen Procedure-Pointer einschreiben kann?

[mk-soft]

@Leonhard,

eventuell komunigations-schwierigkeiten

Empfehlen kann ich nur für jedes eigende Objekt eine Datei anzulegen. Die Reihenfolge sollte meiner Meinung immer folgende haben:

- Interfaces deklarieren. Kann auch später sein, aber man sieht im Kopf gleich alle Methoden.
- Structure anlegen. Immer zuerst Pointer auf VTABLE dann die Daten
- Methoden Programmieren
- DataSection die Methoden zuweisen. (Wer es mit DataSection mag)

Gibt es eigendlich noch andere Typen, wie man ein Interface mit seinen Procedure-Pointer einschreiben kann?

Bekanntlicher weise führen 1000 Wege nach Rom. Bei der Programmierung Millionen. Die Regeln für den Aufbau eines Objekt kann man aber nicht umgeben. Der nächste Schritt ist es Objekte zu Programmieren die man in anderen Sprachen einbinden kann.

[ts-soft]

Ich bin inzwischen von den Interfaces ab. Prototypes in der Structure finde ich noch praktischer! Viele wege nach ROM

[ullmann]

Danke für die Antworten, habe im Moment -leider- wenig Zeit, werde mich später damit beschäftigen.

Rainer

[Hellhound66]

@ts-soft:

Prototypes (Hab ich schon seit 3.9x mit Pointern und CallFunctionFast gemacht) haben den Vorteil:

-Sie scheinen einfacher zum deklarieren und zum Erstellen der Klassen sein,

aber sie haben auch die Nachteile:

-du musst von Hand den *this-Pointer übergeben, oder du nutzt das GetThis-Macro, was wiederum dazu führt, dass die Klasse nicht in allen Gebieten funktioniert.
-die Klasse selber wird größer, weil jede definierte Klassenvariable oder dynamische Klasse die VTablegröße an speicher verbraucht, weil die Methoden direkt in der Struktur liegen.
-die ganze Sache so sehr schnell unübersichtlich werden kann.

[ts-soft]

@Hellhound66

Deshalb sollte man alle Möglichkeiten mal erforschen, solange es nichts
natives gibt. Solange ich an keinem wichtigen Projekt sitze, werde ich diverse
Varianten einfach mal testen. Bei richtigen Projekten kann ich es dann
hoffentlich abschätzen, welcher Weg der richtige ist.