PureBoard

Code: Alles auswählen

;Achtung, die Ausführung dieses Codes führt zu einem sofortigen Weltuntergang
CreateFile(0,"d:\dickefetteIniDatei.ini")
WriteStringFormat(0,#PB_Unicode)
out.s="ClemensVonBrentano@ = Das Märchen von dem Schulmeister Klopfstock und seinen @ Söhnen"
For i=1 To 64001
  
  WriteStringN(0,ReplaceString(out,"@",Str(i)),#PB_Unicode)
Next i

CloseFile(0)
ReadFile(0,"d:\dickefetteIniDatei.ini")
Select ReadStringFormat(0)
Case    #PB_Ascii  : Debug "Kein BOM gefunden. Dies kennzeichnet üblicherweise eine normale Textdatei."
  Case #PB_UTF8   : Debug "UTF-8 BOM gefunden."
  Case #PB_Unicode: Debug "UTF-16 (Little Endian) BOM gefunden."

  Case #PB_UTF16BE: Debug "UTF-16 (Big Endian) BOM gefunden."
  Case #PB_UTF32  : Debug "UTF-32 (Little Endian) BOM gefunden."
  Case #PB_UTF32BE: Debug "UTF-32 (Big Endian) BOM gefunden."
EndSelect
CloseFile(0)

Code: Alles auswählen

; ----------------------------------------------
Procedure StringToField(*string, Array result$(1), separator$)
   ; Trennt einen String in einzelne Teile auf,
   ; und speichert die Teile in ein String-Feld
   ; Der Separator kann auch aus mehreren Bytes bestehen
   
   Protected *c.character = *string    ; Pointer auf ein Zeichen im String
   Protected *s = *c                   ; Pointer auf den Anfang des Teils
   
   Protected *sep.character = @separator$          ; Pointer auf Separator
   Protected SepLenC = Len(separator$)             ; Länge des Sep. in Zeichen
   Protected SepLenB = SepLenC * SizeOf(character) ; Länge des Sep. in Byte
   
   Protected n                         ; zählt die Einträge
   Protected a = ArraySize(result$())  ; Größe des Feldes
   
   
   Repeat
      If *c\c = *sep\c     ; könnte Separator sein
         If SepLenC = 1 Or CompareMemory(*c, *sep, SepLenB) ; Wenn es Separator ist
            ;*c\c = 0       
            
            result$(n) = PeekS(*s, (*c - *s)/SizeOf(character)) ; String bis dahin speichern  
            
            *c + SepLenB   ; Separator überspringen
            *s = *c        ; neuen Stringanfang merken
            
            n + 1          ; Feldindex erhöhen
            If n > a       ; Feld vergrößern, wenn Feld kleiner als der Index ist
               a = a*2 + 1          
               ReDim result$(a)
            EndIf
         Else
            *c + SizeOf(character)
         EndIf
         
      ElseIf *c\c = 0      ; Stringende erreicht
         result$(n) = PeekS(*s)     ; Letzter Eintrag     
         n + 1                      
         
         ReDim result$(n - 1)       ; unnötige Elemente wieder entfernen 
         ProcedureReturn n          ; Rückgabe anzahl der Elemente
         
      Else                 ; Sonst 
         *c + SizeOf(character)     ; weiter zum nächsten Zeichen 
      EndIf
   ForEver
EndProcedure
; ----------------------------------------------

Dim Feld$(0)
Define Text$ = "Ich bin//ein kleiner//Text"

Define Last
Define i

Last = StringToField(@Text$, Feld$(), "//") - 1

For i = 0 To Last
   Debug Feld$(i)
Next i