PureBoard

Verfasst: **07.07.2015 12:49**

Nimm integer (.i) und nicht long (.l)!
Spätestens, wenn Du x64 kompiliert und #PB_Any zur Gadgeterstellung nutzt, könnte es sonst zu merkwürdigen Effekten kommen.

Verfasst: **07.07.2015 21:33**

Danke, habe es geändert.

aber ich habe folgendes Problem entdeckt , dass mir auf die Schnelle nicht auffiehl:
Wenn ich längeren Text benutze und einen späteren Abschnitt in BB tags setzen will, werden am letzten Wort Buchstaben weggeschnitten

---------
Beispiel:

... Welt verliebte sich in dieses rehäugige, unerfahrene, immer etwas schüchtern wirkende Mädchen. Gleich für ihre erste Hauptrolle wurde die Schauspielerin 1954 mit einen Oscar ausgezeichnet und war fortan ein Star.

[u]
Doch Hepburn wurde nic[/u] <--- hier wird vom WORT "nicht" das "ht" weggeschnitten.

nur eine bekannte Schauspielerin - ...

------------------------
wie kann ich das lösen?

je länger der Text um so ungenauer wird das korrekte Umschließen.

Verfasst: **07.07.2015 21:50**

udg hat geschrieben:je länger der Text um so ungenauer wird das korrekte Umschließen.

genauer gesagt: Je mehr Zeilenumbrüche, desto ungenauer. Die werden meiner Erfahrung nach mit EM_GETSEL nicht mitgezählt. Diese Zeichen musst Du separat berechnen und auf Dein cende addieren.

Grüße ... Peter

Verfasst: **07.07.2015 21:55**

Code: Alles auswählen

text = Mid(text, cstart + 1, cende - cstart)  ;Text zwischen Anfang und Ende ausschneiden

liegt es an dieser Codezeile?

ich selektiere zb. im weiteren Text nur 3 Wörter. Dort ist doch kein Zeilenumbruch vorhanden und

Code: Alles auswählen

SendMessage_(GadgetID(gID), #EM_GETSEL, @cstart, @cende)  ;Anfang und Ende der Markierung holen

sagt doch dem Programm, dass es nur die Markierung berücksichtigen soll.
Sehe ich was falsch?

Code: Alles auswählen

cende

wenn sich der Text ändert, was die länge angeht, kann ich dann überhaupt einzeln noch was berechnen?

Code: Alles auswählen

cende + 5

zB. geht hier in der Mitte vom text jetzt, dann aber weiter hinten nicht mehr.
Da gibts doch bestimmt eine ordentliche Lösung.

Verfasst: **07.07.2015 22:16**

udg hat geschrieben:Dort ist doch kein Zeilenumbruch vorhanden

aber mit Sicherheit vor der Markierung.

Grüße ... Peter

Verfasst: **07.07.2015 22:34**

Kiffi hat geschrieben:
udg hat geschrieben:Dort ist doch kein Zeilenumbruch vorhanden
aber mit Sicherheit vor der Markierung.

Grüße ... Peter

ja vor der markierung sind 6 Zeilenumbrüche und diese 6 Zeichen werden dann weggelassen.

Worried. Gibt es noch eine andere Methode außer #EM_GETSEL ?

Für mich nur gerade unverständlich warum ich sage: "nehme nur den markierten Text" aber alles davor wird auch mit verarbeitet.

Gruß

Verfasst: **07.07.2015 23:49**

Schau mal hier:

Original-Posting von Christi (ein wenig modifiziert und lauffähig gemacht):

Code: Alles auswählen

OpenWindow(0, 0, 0, 200, 220, "Test", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)

editorid = EditorGadget(0, 0, 0, 200, 200)
ButtonGadget(1, 50, 200, 100, 20, "Klick")

For z = 1 To 10
  AddGadgetItem(0, -1, "zeile " + Space(z) + Str(z))
Next

Repeat
  w_ereignis = WaitWindowEvent()
  Select w_ereignis
  	Case #PB_Event_Gadget
  		
      If EventGadget() = 1
        
        textlaenge = SendMessage_(editorid, #WM_GETTEXTLENGTH, 0, 0)
        text = AllocateMemory(textlaenge)
        SendMessage_(editorid, #WM_GETTEXT, textlaenge, text)
        
        SendMessage_(editorid, #EM_GETSEL, @anfang, @ende)
        
        anfang + SendMessage_(editorid, #EM_EXLINEFROMCHAR, 0, anfang)
        ende + SendMessage_(editorid, #EM_EXLINEFROMCHAR, 0, ende)
        
        SendMessage_(editorid, #EM_REPLACESEL, 0, ">" + PeekS(text + anfang, ende - anfang) + "<")
 
        FreeMemory(text)
      EndIf
 
    Case #PB_Event_CloseWindow
      End
   EndSelect
 
ForEver

Grüße ... Peter

Verfasst: **08.07.2015 03:36**

Danke für deine Version. Ich habe dies mal eingearbeitet.

PS:
bei deiner Version wird bei Zeile 10, am Schluss bei der 10 die "null" weggeschnitten. Da ist auch noch ein Bug

So, weiter im Text.

Hier mein Code:

Code: Alles auswählen

EnableExplicit

Enumeration
   #Window_0
EndEnumeration

Enumeration
  #Editor_Info
  #btnPaste
  #btnBBCode
  #btnClearText
EndEnumeration

Define.l Event, EventWindow, EventGadget, EventType, EventMenu, editorid, textlaenge, text, start, ende

OpenWindow(#Window_0, 0, 0, 600, 400, "BB Code in EditorGadget", #PB_Window_SystemMenu|#PB_Window_TitleBar|#PB_Window_ScreenCentered)
;Editor Gadget
editorid = EditorGadget(#Editor_Info, 20, 70, 560, 280, #PB_Editor_WordWrap)
;Buttons
ButtonGadget(#btnBBCode, 20, 10, 85, 30, "[u][/u]")
ButtonGadget(#btnPaste, 120, 10, 140, 30, "füge Text aus clipboard ein")
ButtonGadget(#btnClearText, 275, 10, 100, 30, "lösche Text")
;MAIN
Repeat
   Event = WaitWindowEvent()
    Select Event
      Case #PB_Event_Gadget
        Select EventGadget()
          Case #btnPaste
            SendMessage_(GadgetID(#Editor_Info),#WM_PASTE,0,0)   
              Case #btnClearText
                 SetGadgetText(#Editor_Info,"")
                    Case #btnBBCode
                      textlaenge = SendMessage_(editorid, #WM_GETTEXTLENGTH, 0, 0)
                      text = AllocateMemory(textlaenge)
                      SendMessage_(editorid, #WM_GETTEXT, textlaenge, text)
                      SendMessage_(editorid, #EM_GETSEL, @start, @ende)
                      start + SendMessage_(editorid, #EM_EXLINEFROMCHAR, 0, start)
                      ende + SendMessage_(editorid, #EM_EXLINEFROMCHAR, 0, ende)
                      SendMessage_(editorid, #EM_REPLACESEL, 0, "[u]" + PeekS(text + start, ende - start) + "[/u]")                     
                      FreeMemory(text)
        EndSelect
           Case #PB_Event_CloseWindow
            EventWindow = EventWindow()
              If EventWindow = #Window_0
                CloseWindow(#Window_0)
                ClearClipboard()
                Break
              EndIf
    EndSelect
Until Event = #PB_Event_CloseWindow
End

funktioniert, wie vorher auch schon mit der Version von Sven - AAAber:
Ich konnte nun das Problem lokalisieren warum es nicht funktioniert wie gedacht.
Vorab: fügst Du in meine Version Langen Text ein und machst irgendwo unten eine Markierung und dann klick auf den [BBCode button], wirst Du sehen, dass wieder etwas weggeschnitten wird. (wer gerade keinen längeren Text zur Hand hat, hier ein Online "Lorem Ipsum" Generator: http://www.blindtextgenerator.com/lorem-ipsum)

Schuld ist in der Zeile:editorid = EditorGadget(#Editor_Info, ... das #PB_Editor_WordWrap am Ende.

nimmst Du: #PB_Editor_WordWrap raus, funktioniert es.

Nun will ich aber nicht, dass der lange Text bis 1 Meter nach rechts geht (als Beispiel) sondern es soll schon am Rand des EditorGadgets umgebrochen werden.

Wie kann man das nun wieder lösen???

Das ist ja zum Mäuse melken.

Grüße aus der Ver2flungs Ecke

Verfasst: **08.07.2015 04:51**

Wir wäre es so? Finde ich auch etwas elegantger, einfach die Tags an die entsprechenden Stellen zu schreiben

Code: Alles auswählen

EnableExplicit

Define.i ev, start, ende, editorID

OpenWindow(0, 0, 0, 300, 300, "Einfügen", #PB_Window_SystemMenu)

EditorGadget(1, 5, 35, 290, 255)
editorID = GadgetID(1)
ButtonGadget(2, 5, 5, 45,20,"Unterstreichen")
Repeat
  ev = WaitWindowEvent()
  If (ev = #PB_Event_Gadget And EventGadget() = 2)
    SendMessage_(editorID, #EM_GETSEL, @start, @ende)
    SendMessage_(editorID, #EM_SETSEL, ende , ende)
    SendMessage_(editorID, #EM_REPLACESEL, 0, "[/u]")
    SendMessage_(editorID, #EM_SETSEL, start, start)
    SendMessage_(editorID, #EM_REPLACESEL, 0, "[u]")
    SendMessage_(editorID, #EM_SETSEL, start, ende + 7)  ; Nur nötig, falls Selektion bestehen bleiben soll
  EndIf
Until ev = #PB_Event_CloseWindow

Damit sollten auch keine Probleme durch Zeilenumbrüchen auftreten da setsel und getsel gleich arbeiten und nichts anderes benutzt wird zur Positionsbestimmung.

Verfasst: **08.07.2015 05:06**

Ligatur! mein Held. So funktioniert es . Kann keine Fehler finden.

CODE: FINAL VERSION

Code: Alles auswählen

EnableExplicit

Enumeration
   #Window_0
EndEnumeration

Enumeration
  #Editor_Info
  #btnPaste
  #btnBBCode
  #btnClearText
EndEnumeration

Define.l Event, EventWindow, EventGadget, EventType, EventMenu, editorid, textlaenge, text, start, ende

OpenWindow(#Window_0, 0, 0, 600, 400, "BB Code in EditorGadget", #PB_Window_SystemMenu|#PB_Window_TitleBar|#PB_Window_ScreenCentered)
;Editor Gadget
EditorGadget(#Editor_Info, 20, 70, 560, 280, #PB_Editor_WordWrap)
editorID = GadgetID(#Editor_Info)
;Buttons
ButtonGadget(#btnBBCode, 20, 10, 85, 30, "[u][/u]")
ButtonGadget(#btnPaste, 120, 10, 140, 30, "füge Text aus clipboard ein")
ButtonGadget(#btnClearText, 275, 10, 100, 30, "lösche Text")
;MAIN
Repeat
   Event = WaitWindowEvent()
    Select Event
      Case #PB_Event_Gadget
        Select EventGadget()
          Case #btnPaste
            SendMessage_(GadgetID(#Editor_Info),#WM_PASTE,0,0)   
              Case #btnClearText
                 SetGadgetText(#Editor_Info,"")
                    Case #btnBBCode
                        SendMessage_(editorID, #EM_GETSEL, @start, @ende)
                        SendMessage_(editorID, #EM_SETSEL, ende , ende)
                        SendMessage_(editorID, #EM_REPLACESEL, 0, "[/u]")
                        SendMessage_(editorID, #EM_SETSEL, start, start)
                        SendMessage_(editorID, #EM_REPLACESEL, 0, "[u]")
                        SendMessage_(editorID, #EM_SETSEL, start, ende + 7)  ; Nur nötig, falls Selektion bestehen bleiben soll
                    EndSelect
           Case #PB_Event_CloseWindow
            EventWindow = EventWindow()
              If EventWindow = #Window_0
                CloseWindow(#Window_0)
                ClearClipboard()
                Break
              EndIf
    EndSelect
Until Event = #PB_Event_CloseWindow
End

PureBoard

erledigt- wie im Forum üblich, geht das? BBCode EditorGadget

Re: Erledigt- wie im Forum üblich, geht das? BBCode EditorGa

Re: Erledigt- wie im Forum üblich, geht das? BBCode EditorGa

Re: Erledigt- wie im Forum üblich, geht das? BBCode EditorGa

Re: noch BUG- wie im Forum üblich, geht das? BBCode EditorGa

Re: noch BUG- wie im Forum üblich, geht das? BBCode EditorGa

Re: noch BUG- wie im Forum üblich, geht das? BBCode EditorGa

Re: noch BUG- wie im Forum üblich, geht das? BBCode EditorGa

Re: noch BUG- wie im Forum üblich, geht das? BBCode EditorGa

Re: noch BUG- wie im Forum üblich, geht das? BBCode EditorGa

Re: noch BUG- wie im Forum üblich, geht das? BBCode EditorGa