Problem mit Dll

[GerhardHoeberth]

Danke euch allen für diese Beiträge.

glomph für den coolen code, der mir sicherlich viel Rumprobiererei erspart.

und auch Andreas21 für den Link zur 64bit. dll

[andi256]

Hi

vielleicht gibt es hier im Forum ein paar Hobby Astronomen

muß sagen mit dieser lib (Swiss Ephemeris) kann man einiges anstellen ...

link: http://www.astro.com/swisseph/swephprg.htm
download 64: http://www.astro.com/ftp/swisseph/contr ... ll64_2.00/
download 32: http://www.astro.com/ftp/swisseph/sweph161/

hab mir da ein Programm gebastel das die Sonne/Mond & Planeten in den verschiedenen Koordinatensytemen ausgibt bzw. umrechnet.


richtige Sternzeichen
----------------------

als Draufgabe errechnet das Programm das "richtige" Sternzeichen.

(dh. in welchem Astronomischen Sternbild die Sonne,Mond / der Planet zum eingegeben Datum steht/stand)

Die Tierkreiszeichen der Astrologie sind ja vom ~ Stand Christi Geburt und stimmen mit dem tatsächlichen Stand nicht überein.

Die Sternzeichen der Astronomie wurden im Jahr 1875 genormt.
Mein Programm rechnet den eingeben Datumswert mittels Procedure HGTPRC(..) auf dieses Jahr um und bestimmt dann das richtige Sternbild.

Datum UTC
---------

zum Rechnen mit Datum verwende ich
SendMessage_(GadgetID(#dat), #DTM_GETSYSTEMTIME, 0, time) = #GDT_VALID
damit auch Datum-Werte vor 1970 zugelassen werden
und die "kernel32" Funktion "TzSpecificLocalTimeToSystemTime" um auf UTC Zeit zu kommen. (ist leider in PB nicht enthalten)

zum Programm
astro.pb .... GUI + Swiss Ephemeris
sternzeichen.pb .... ermittelt das Sternzeichen
sternzeichen_namen.pb .... Daten zu den Sternbilder

Sollte auf 64 + 32 bit Systemen laufen .. getestet (PB5.30 x64) (PB5.22 x86)

bitte den Pfad zur dll anpassen !!!
#libpath32 = "D:\_astro\swedll32.dll"
#libpath64 = "D:\_astro\swedll64.dll"

Viel Spass bzw Dank für weitere Anregung:-)

Andi256

astro.pb

Code: Alles auswählen

EnableExplicit

XIncludeFile "sternzeichen.pb"

#libpath32 = "D:\_astro\swedll32.dll"
#libpath64 = "D:\_astro\swedll64.dll"
#libpath2 = "kernel32.dll"

#SE_SUN                  =    0
#SE_MOON                 =    1
#SE_MERCURY              =    2
#SE_VENUS                =    3
#SE_MARS                 =    4
#SE_JUPITER              =    5
#SE_SATURN               =    6
#SE_URANUS               =    7
#SE_NEPTUNE              =    8
#SE_PLUTO                =    9  

#SE_EARTH                =   14
#SE_CHIRON               =   15
#SE_PHOLUS               =   16
#SE_CERES                =   17
#SE_PALLAS               =   18
#SE_JUNO                 =   19
#SE_VESTA                =   20
   
#SE_JUL_CAL              =    0
#SE_GREG_CAL             =    1

#SEFLG_JPLEPH            =    1
#SEFLG_SWIEPH            =    2
#SEFLG_MOSEPH            =    4
#SEFLG_HELCTR            =    8
#SEFLG_TRUEPOS           =   16
#SEFLG_J2000             =   32
#SEFLG_NONUT             =   64
#SEFLG_SPEED             =  256
#SEFLG_NOGDEFL           =  512
#SEFLG_NOABERR           = 1024
#SEFLG_EQUATORIAL        = 2048
#SEFLG_XYZ               = 4096
#SEFLG_RADIANS           = 8192
#SEFLG_BARYCTR           =16384
#SEFLG_TOPOCTR           =32768
#SEFLG_SIDERAL           =65536

#SE_ECL2HOR              =    0
#SE_EQU2HOR              =    1
 
#SE_CALC_RISE            =    1
#SE_CALC_SET             =    2
#SE_CALC_MTRANSIT        =    4     
#SE_CALC_ITRANSIT        =    8      

#SE_BIT_DISC_CENTER      =  256 
#SE_BIT_NO_REFRACTION    =  512     
#SE_BIT_DISC_BOTTOM      = 8192    
#SE_BIT_CIVIL_TWILIGHT   = 1024   
#SE_BIT_NAUTIC_TWILIGHT  = 2048    
#SE_BIT_ASTRO_TWILIGHT   = 4096    
#SE_BIT_FIXED_DISC_SIZE  =16384

#lib1    = 0
#lib2    = 1

#window = 0

#mask = "%yyyy %mm %dd Zeit: %hh:%ii"

Enumeration
 #planet
 #planet_txt
 #pos_txt
 #pos_lg_txt
 #pos_lg
 #pos_lm
 #pos_ls
 #pos_bg_txt
 #pos_bg
 #pos_bm
 #pos_bs
 #pos_l_w
 #pos_l_o
 #pos_b_n
 #pos_b_s
 #calc
 #editor 
 #dat_txt
 #dat
 #UTC
 #zwoelf
 #jetzt
EndEnumeration

Prototype.d SWE_JulDay     (jahr.i,monat.i,tag.i,stunde.d,iflag.i)
Prototype.d SWE_revjul     (tjd_ut.d,iflag.i,*jahr,*monat,*tag,*stunde)
Prototype.i SWE_Calc_ut    (tjd_ut.d,planet.i,   iflag.i,*x,*err)
Prototype.i SWE_azalt      (tjd_ut.d,            iflag.i,           *geo,press.d,temp.d,*xin,*xout)
Prototype.i SWE_rise_trans (tjd_ut.d,planet.i,*name,iflag.i,rflag.i,*geo,press.d,temp.d,*x  ,*err)
Prototype.i TzSpecificLocalTimeToSystemTime (*i,*j,*k)

CompilerSelect #PB_Compiler_Processor
 CompilerCase #PB_Processor_x86
  If OpenLibrary(#lib1,#libpath32 )
   Global JulDay.  SWE_JulDay         = GetFunction(#lib1,"_swe_julday@24")
   Global Dayjul.  SWE_revjul         = GetFunction(#lib1,"_swe_revjul@28")
   Global Calc_ut. SWE_Calc_ut        = GetFunction(#lib1,"_swe_calc_ut@24")
   Global azalt.   SWE_azalt          = GetFunction(#lib1,"_swe_azalt@40")
   Global aufgang. SWE_rise_trans     = GetFunction(#lib1,"_swe_rise_trans@52")
  Else
   MessageRequester("Achtung","Lib swedll32.dll nicht gefunden")
   End
  EndIf
 CompilerCase #PB_Processor_x64
   If OpenLibrary(#lib1,#libpath64 )
    Global JulDay.  SWE_JulDay         = GetFunction(#lib1,"swe_julday")
    Global Dayjul.  SWE_revjul         = GetFunction(#lib1,"swe_revjul")
    Global Calc_ut. SWE_Calc_ut        = GetFunction(#lib1,"swe_calc_ut")
    Global azalt.   SWE_azalt          = GetFunction(#lib1,"swe_azalt")
    Global aufgang. SWE_rise_trans     = GetFunction(#lib1,"swe_rise_trans")
   Else
    MessageRequester("Achtung","Lib swedll64.dll nicht gefunden")
    End
   EndIf
CompilerEndSelect

If OpenLibrary(#lib2, #libpath2)
 Global LOC_UTC.TzSpecificLocalTimeToSystemTime = GetFunction(#lib2,"TzSpecificLocalTimeToSystemTime")
Else
 MessageRequester("Achtung","Lib kernel32.dll nicht gefunden")
 End
EndIf

Global Font1.i = LoadFont(#PB_Any, "monospac821 bt" , 8)

Procedure.s umrechnen_dezimalgrad_auf_grad(zahl.d)  
 Protected grad.i = Int(zahl)
 Protected Str$ = RSet(Str(grad)+"°",4," ")
 Protected min.i  = Int(Abs(zahl-grad)*60)
 Str$ + RSet(Str(min),2,"0")+"'"
 Str$ + RSet(StrF((Abs(zahl-grad)*60-min)*60,2)+ Chr(34),6,"0")
 ProcedureReturn str$
EndProcedure

Procedure.s min1(zahl.d)  
 Protected grad.i = Int(zahl)
 Protected Str$   = Str(grad)+":"
 Protected min.i  = Int(Abs(zahl-grad)*60)
 Str$ + RSet(Str(min),2,"0")+":"
 Str$ + StrF((Abs(zahl-grad)*60-min)*60,1)
 ProcedureReturn str$
EndProcedure

Procedure.s std(zahl.d)     
 zahl*24/360
 Protected grad.i = Int(zahl)
 Protected Str$   = RSet(Str(grad)+"h",3," ")
 Protected min.i  = Int(Abs(zahl-grad)*60)
 Str$ + RSet(Str(min),2,"0")+"'"
 Str$ + RSet(StrF((Abs(zahl-grad)*60-min)*60,2)+ Chr(34),6,"0") 
 ProcedureReturn str$
EndProcedure

Procedure testmax(gd,max)
 Protected val
 val = Val(GetGadgetText(gd))
 If val>max
  SetGadgetText(gd,Str(max))
 EndIf
EndProcedure

Procedure gui()
 Protected a.i
 OpenWindow(#window,500,500,450,580,"Planeten Position")
 
 TextGadget(#planet_txt,10,10,50,20,"Planet:")
 ComboBoxGadget(#planet,60,8,70,20)
 For a = 1 To CountString(Planeten$,",") 
  AddGadgetItem(#planet, -1,StringField(Planeten$,a,","))
 Next
 SetGadgetState(#planet,0)
 FrameGadget (#pos_txt,10,35,280,80,"Beobachtungsposition:")
 
 TextGadget    (#pos_lg_txt, 20, 50, 70, 20,"Längengrad:")
 SpinGadget    (#pos_lg,     20, 70, 40, 20,0,90,#PB_Spin_Numeric)
 SpinGadget    (#pos_lm,     60, 70, 40, 20,0,59,#PB_Spin_Numeric)
 SpinGadget    (#pos_ls,    100, 70, 40, 20,0,59,#PB_Spin_Numeric)
 SetGadgetState(#pos_lg,14)
 SetGadgetState(#pos_lm,0)
 SetGadgetState(#pos_ls,0)
 OptionGadget  (#pos_l_w,    20, 90, 60, 20,"West")
 OptionGadget  (#pos_l_o,    80, 90, 60, 20,"Ost")
 SetGadgetState(#pos_l_o,#True)
   
 TextGadget    (#pos_bg_txt,160, 50, 70, 20,"Breitengrad:")
 SpinGadget    (#pos_bg,    160, 70, 40, 20,0,90,#PB_Spin_Numeric)
 SpinGadget    (#pos_bm,    200, 70, 40, 20,0,59,#PB_Spin_Numeric)
 SpinGadget    (#pos_bs,    240, 70, 40, 20,0,59,#PB_Spin_Numeric)
 SetGadgetState(#pos_bg,48)
 SetGadgetState(#pos_bm,0)
 SetGadgetState(#pos_bs,0)
 OptionGadget  (#pos_b_n,   160, 90, 60, 20,"Nord")
 OptionGadget  (#pos_b_s,   220, 90, 60, 20,"Süd")
 SetGadgetState(#pos_b_n,#True)
 
 FrameGadget   (#dat_txt,    10,140,280, 80,"Datum:")
 DateGadget    (#dat,        20,160,180, 25, #mask)
 TextGadget    (#UTC,        21,190,180, 20,"UTC:")
 ButtonGadget  (#jetzt,     210,160, 70, 20,"Jetzt")
 CheckBoxGadget(#zwoelf,    210,180, 70, 20,"12:00 UTC")
   
 ButtonGadget  (#calc,       10,230, 70, 20,"Berechnen")
 
 EditorGadget  (#editor,     10,250,430,400)
 SetGadgetFont (#editor, FontID(Font1))

EndProcedure

Procedure out(text$)
 AddGadgetItem(#editor,-1,text$)
EndProcedure

Procedure out1(in.d,bez$)
 out(RSet(StrD(in,3),7," ") +"° "+ umrechnen_dezimalgrad_auf_grad(in) +  " " + RSet(StrD(in*24/360,2),7," ") + "h  "+ std(in)+ bez$  )
EndProcedure

Procedure calc()
 Protected E.d,RAH.d,DECD.d,con.s
 Protected time.SYSTEMTIME
 Protected Dim x.d(6)
 Protected Dim xout.d(3)
 Protected Dim geo.d(3)

 Protected planet.i   = GetGadgetState(#planet)
 Protected tjd_ut.d
 Protected iflag.i,rflag.i
 Protected err
 Protected jahr.i,Monat.i,tag.i,minute.i    
 Protected stunde.d
   
 SetGadgetText(#editor,"")
 
 If SendMessage_(GadgetID(#dat), #DTM_GETSYSTEMTIME, 0, time) = #GDT_VALID
  LOC_UTC (#Null, @time, @time)
  jahr  = time\wYear 
  monat = time\wMonth 
  tag   = time\wDay  
  If GetGadgetState(#zwoelf) = #True
   stunde = 12
   minute = 0
  Else
   stunde = time\wHour
   minute = time\wminute
  EndIf 
 EndIf 
     
 SetGadgetText(#utc,Str(jahr) +" " + RSet(Str(monat),2,"0") +" " + RSet(Str(tag),2,"0") +" Zeit: " + RSet(Str(stunde),2,"0") +":" + RSet(Str(Minute),2,"0") )

 geo(0)   =  GetGadgetState(#pos_lg) + GetGadgetState(#pos_lm)/60 + GetGadgetState(#pos_ls)/3600 ;(längengrad)  ost
 If GetGadgetState(#pos_l_w) = #True
  geo(0)*-1
 EndIf
 
 geo(1)   =  GetGadgetState(#pos_bg) + GetGadgetState(#pos_bm)/60 + GetGadgetState(#pos_bs)/3600 ;(Breitengrad) nord
 If GetGadgetState(#pos_b_s) = #True
  geo(1)*-1
 EndIf
 out("Position "+ StringField(Planeten$,GetGadgetState(#planet)+1,","))
    
 stunde + minute/60
 
 tjd_ut.d=JulDay(jahr,monat,tag,stunde,#SE_GREG_CAL)
 out( "juldate: " + StrD(tjd_ut,4))

 iflag=#SEFLG_SWIEPH
 
 Calc_ut(tjd_ut,planet  ,iflag,@x.d(0),err)
 out("Entfernung: " + StrF(x(2),4) + " AE")
 out("")
 out("Geozentrisch / Ekliptikale Koordinaten:")
 out1(x(0)," Länge")
 out1(x(1)," Breite")
  
 con = StringField(Tierkreiszeichen$,Int(x(0)/30)+1,",")
 out("im Tierkreiszeichen: "+ findname(con) + " (" + con+")")
   
 iflag=#SEFLG_SWIEPH|#SEFLG_EQUATORIAL
 Calc_ut(tjd_ut,planet   ,iflag,@x.d(0),err)
  
 con.s = sternzeichen(jahr,x(0)*24/360,x(1) )
 out("im Sternzeichen:     "+ findname(con) + " (" + con+")")
  
 out("")
 out("Äquatoriale Koordinaten:")
 out1(x(0)," RA")
 out1(x(1)," DEC")

 iflag=#SEFLG_SWIEPH
 Calc_ut(tjd_ut,planet  ,iflag,@x.d(0),err)

 iflag=#SE_ECL2HOR
 azalt(tjd_ut,iflag,@geo.d(0),0,0,@x.d(0),@xout.d(0))

 out("")
 out("Azimutale Koordinaten:")
 out1(xout(0)," AZI")
 out1(xout(1)," ALT")

 iflag=#SEFLG_SWIEPH
 rflag=#SE_CALC_RISE

 aufgang(tjd_ut,planet,#Null,iflag,rflag,@geo.d(0),0,0,@xout(0),err)

 out("")
 out("Aufgang "+ StringField(Planeten$,GetGadgetState(#planet)+1,","))
 Dayjul(xout(0),1,@jahr,@monat,@tag,@stunde)

 out( Str(jahr) + " "+Str(monat) + " " +Str(tag) + " Zeit: " +min1(stunde))

 rflag=#SE_CALC_SET

 aufgang(tjd_ut,planet,#Null,iflag,rflag,@geo.d(0),0,0,@xout(0),err)

 out("Untergang " + StringField(Planeten$,GetGadgetState(#planet)+1,","))

 Dayjul(xout(0),1,@jahr,@monat,@tag,@stunde)

 out( Str(jahr) + " "+Str(monat) + " " +Str(tag) + " Zeit: " +min1(stunde))

EndProcedure

gui()
Repeat
 Select WindowEvent()
  Case 0 
   Delay(1)
  Case #PB_Event_CloseWindow
   CloseLibrary(#lib1)
   CloseLibrary(#lib2)
   End
  Case #PB_Event_Gadget  
   Select EventGadget()
    Case #pos_lg
     testmax(#pos_lg,89)
    Case #pos_lm
     testmax(#pos_lm,59)
    Case #pos_ls
     testmax(#pos_ls,59)
    Case #pos_bg
     testmax(#pos_bg,89)
    Case #pos_bm
     testmax(#pos_bm,59)
    Case #pos_bs
     testmax(#pos_bs,59)
    Case #calc
     calc() 
    Case #jetzt 
     SetGadgetState (#dat,Date())
   EndSelect
 EndSelect 
ForEver

sternzeichen.pb

Code: Alles auswählen

XIncludeFile "sternzeichen_namen.pb"

EnableExplicit

Procedure HGTPRC(RA1.d,DEC1.d,EPOCH1.d,EPOCH2.d,zRA2.d,zDEC2.d)
    
  Protected CDR.d,CSR.d
  Protected A.d,B.d,C.d,T.d,ST.d,EP1.d,EP2.d,RA2.d,DEC2.d
  Protected SINA.d,SINB.d,SINC.d,COSA.d,COSB.d,COSC.d
  Protected i.i,j.i
  
  CDR.d = 0.17453292519943e-01
  EP1.d = 0
  EP2.d = 0 
  
  RA2.d
  DEC2.d
  
  Dim X1.d(3)
  Dim X2.d(3)
  Dim R.d(3,3)
  
  A=Cos(DEC1) 
  X1(1)=A*Cos(RA1) 
  X1(2)=A*Sin(RA1) 
  X1(3)=Sin(DEC1) 
  If EP1 = EPOCH1 And  EP2 = EPOCH2
  Else 
    EP1 = EPOCH1 
    EP2 = EPOCH2 
    CSR=CDR/3600.0 
    T=0.001*(EP2-EP1) 
    ST=0.001*(EP1-1900.0)
    A=CSR*T*(23042.53+ST*(139.75+0.06*ST)+T*(30.23-0.27*ST+18.0*T)) 
    B=CSR*T*T*(79.27+0.66*ST+0.32*T)+A 
    C=CSR*T*(20046.85-ST*(85.33+0.37*ST)+T*(-42.67-0.37*ST-41.8*T)) 
    SINA=Sin(A) 
    SINB=Sin(B) 
    SINC=Sin(C) 
    COSA=Cos(A) 
    COSB=Cos(B) 
    COSC=Cos(C) 
    R(1,1)=COSA*COSB*COSC-SINA*SINB 
    R(1,2)=-COSA*SINB-SINA*COSB*COSC 
    R(1,3)=-COSB*SINC 
    R(2,1)=SINA*COSB+COSA*SINB*COSC 
    R(2,2)=COSA*COSB-SINA*SINB*COSC 
    R(2,3)=-SINB*SINC 
    R(3,1)=COSA*SINC 
    R(3,2)=-SINA*SINC 
    R(3,3)=COSC 
  EndIf
  For i=1 To 3 
    X2(i)=0.0 
    For j=1 To 3
      X2(i)+R(i,j)*X1(j) 
    Next j 
  Next i
  RA2=ATan2(X2(1),X2(2)) 
  If RA2 <  0 
    RA2 = 6.28318530717948 + RA2 
  EndIf 
  DEC2=ASin(X2(3)) 
  PokeD(zRA2,RA2)
  PokeD(zDEC2,DEC2)
EndProcedure

Procedure.s sternzeichen(E.d,RAH.d,DECD.d )
 Protected CONVH.d,CONVD.d,PI4.d,E75.d,A.d,D.d,RAL.d,RAU.d,RA.d,DEC.d,DECL.d,ARAD.d,DRAD.d
 Protected zeile.s,CON.s,temp.s
 CONVH.d = 0.2617993878
 CONVD.d = 0.1745329251994e-01
 PI4.d = 6.28318530717948     
 E75.d = 1875.0
 ARAD.d = CONVH * RAH 
 DRAD.d = CONVD * DECD 
 HGTPRC(ARAD,DRAD,E,E75,@A,@D) 
 A=PeekD(@A)
 D=PeekD(@D)
 If A < 0 
  A+PI4 
 EndIf 
 If A >= PI4
  A-PI4 
 EndIf 
 RA= A/CONVH 
 DEC=D/CONVD 
 Restore stern
 Repeat
  Read.s temp
  RAL = ValD(temp)
  Read.s temp
  RAU = ValD(temp)
  Read.s temp
  DECL= ValD(temp)
  Read.s CON
  If DECL >  DEC
   Continue
  EndIf
  If RAU <= RA
   Continue 
  EndIf 
  If RAL > RA
   Continue 
  EndIf 
  If RA >= RAL And  RA < RAU And DECL <= DEC
   ProcedureReturn con
  ElseIf RAU < RA
   Continue 
  Else 
   ProcedureReturn "Constellation NOT FOUND"
  EndIf
  Break 
 Until RAL = -1
EndProcedure

sternzeichen_namen.pb

Code: Alles auswählen

Global Planeten$          = "Sonne,Mond,Merkur,Venus,Mars,Jupiter,Saturn,Uranus,Neptun,Pluto"
Global tierkreiszeichen$  = "Ari,Tau,Gem,Cnc,Leo,Vir,Lib,Sco,Sgr,Cap,Aqr,Psc"

DataSection
namen: 
Data.s "Achterdeck des Schiffs","Puppis","Puppis","Pup"
Data.s "Adler","Aquila","Aquilae","Aql"
Data.s "Altar","Ara","Arae","Ara"
Data.s "Andromeda","Andromeda","Andromedae","And"
Data.s "Bärenhüter","Bootes / Boötes","Bootis / Boötis","Boo"
Data.s "Becher","Crater","Crateris","Crt"
Data.s "Bildhauer","Sculptor","Sculptoris","Scl"
Data.s "Chamäleon","Chamaeleon","Chamaeleontis","Cha"
Data.s "Chemischer Ofen","Fornax","Fornacis","For"
Data.s "Delphin","Delphinus","Delphini","Del"
Data.s "Drache","Draco","Draconis","Dra"
Data.s "Dreieck","Triangulum","Trianguli","Tri"
Data.s "Eidechse","Lacerta","Lacertae","Lac"
Data.s "Einhorn","Monoceros","Monocerotis","Mon"
Data.s "Eridanus","Eridanus","Eridani","Eri"
Data.s "Fische","Pisces","Piscium","Psc"
Data.s "Fliege","Musca","Muscae","Mus"
Data.s "Fliegender Fisch","Volans","Volantis","Vol"
Data.s "Fuchs","Vulpecula","Vulpeculae","Vul"
Data.s "Fuhrmann","Auriga","Aurigae","Aur"
Data.s "Füllen","Equuleus","Equulei","Equ"
Data.s "Giraffe","Camelopardalis","Camelopardalis","Cam"
Data.s "Grabstichel","Caelum","Caeli","Cae"
Data.s "Großer Bär (Großer Wagen)","Ursa Major","Ursae Majoris","UMa"
Data.s "Großer Hund","Canis Major","Canis Majoris","CMa"
Data.s "Haar der Berenike","Coma Berenices","Comae Berenices","Com"
Data.s "Hase","Lepus","Leporis","Lep"
Data.s "Herkules","Hercules","Herculis","Her"
Data.s "Indianer (Inder)","Indus","Indi","Ind"
Data.s "Jagdhunde","Canes Venatici","Canum Venaticorum","CVn"
Data.s "Jungfrau","Virgo","Virginis","Vir"
Data.s "Kassiopeia","Cassiopeia","Cassiopeiae","Cas"
Data.s "Kepheus","Cepheus","Cephei","Cep"
Data.s "Kiel des Schiffs","Carina","Carinae","Car"
Data.s "Kleine Wasserschlange","Hydrus","Hydri","Hyi"
Data.s "Kleiner Bär (Kleiner Wagen)","Ursa Minor","Ursae Minoris","UMi"
Data.s "Kleiner Hund","Canis Minor","Canis Minoris","CMi"
Data.s "Kleiner Löwe","Leo Minor","Leonis Minoris","LMi"
Data.s "Kranich","Grus","Gruis","Gru"
Data.s "Krebs","Cancer","Cancri","Cnc"
Data.s "Kreuz des Südens","Crux","Crucis","Cru"
Data.s "Leier","Lyra","Lyrae","Lyr"
Data.s "Löwe","Leo","Leonis","Leo"
Data.s "Luchs","Lynx","Lyncis","Lyn"
Data.s "Luftpumpe","Antlia","Antliae","Ant"
Data.s "Maler","Pictor","Pictoris","Pic"
Data.s "Mikroskop","Microscopium","Microscopii","Mic"
Data.s "Netz","Reticulum","Reticuli","Ret"
Data.s "Nördliche Krone","Corona Borealis","Coronae Borealis","CrB"
Data.s "Oktant","Octans","Octantis","Oct"
Data.s "Orion","Orion","Orionis","Ori"
Data.s "Paradiesvogel","Apus","Apodis","Aps"
Data.s "Pegasus","Pegasus","Pegasi","Peg"
Data.s "Pendeluhr","Horologium","Horologii","Hor"
Data.s "Perseus","Perseus","Persei","Per"
Data.s "Pfau","Pavo","Pavonis","Pav"
Data.s "Pfeil","Sagitta","Sagittae","Sge"
Data.s "Phoenix","Phoenix","Phoenicis","Phe"
Data.s "Rabe","Corvus","Corvi","Crv"
Data.s "Schiffskompass","Pyxis","Pyxidis","Pyx"
Data.s "Schild","Scutum","Scuti","Sct"
Data.s "Schlange","Serpens","Serpentis","Ser"
Data.s "Schlangenträger","Ophiuchus","Ophiuchi","Oph"
Data.s "Schütze","Sagittarius","Sagittarii","Sgr"
Data.s "Schwan","Cygnus","Cygni","Cyg"
Data.s "Schwertfisch","Dorado","Doradus","Dor"
Data.s "Segel des Schiffs","Vela","Velorum","Vel"
Data.s "Sextant","Sextans","Sextantis","Sex"
Data.s "Skorpion","Scorpius","Scorpii","Sco"
Data.s "Steinbock","Capricornus","Capricorni","Cap"
Data.s "Stier","Taurus","Tauri","Tau"
Data.s "Südliche Krone","Corona Australis","Coronae Australis","CrA"
Data.s "Südlicher Fisch","Piscis Austrinus","Piscis Austrini","PsA"
Data.s "Südliches Dreieck","Triangulum Australe","Trianguli Australis","TrA"
Data.s "Tafelberg","Mensa","Mensae","Men"
Data.s "Taube","Columba","Columbae","Col"
Data.s "Teleskop","Telescopium","Telescopii","Tel"
Data.s "Tukan","Tucana","Tucanae","Tuc"
Data.s "Waage","Libra","Librae","Lib"
Data.s "Walfisch","Cetus","Ceti","Cet"
Data.s "Wassermann","Aquarius","Aquarii","Aqr"
Data.s "Wasserschlange","Hydra","Hydrae","Hya"
Data.s "Widder","Aries","Arietis","Ari"
Data.s "Winkelmaß","Norma","Normae","Nor"
Data.s "Wolf","Lupus","Lupi","Lup"
Data.s "Zentaur","Centaurus","Centauri","Cen"
Data.s "Zirkel","Circinus","Circini","Cir"
Data.s "Zwillinge","Gemini","Geminorum","Gem"
Data.s "ENDE","","",""
EndDataSection

DataSection
stern: 
Data.s " 0.0000","24.0000","88.0000","UMi"
Data.s " 8.0000","14.5000","86.5000","UMi"
Data.s "21.0000","23.0000","86.1667","UMi"
Data.s "18.0000","21.0000","86.0000","UMi"
Data.s " 0.0000"," 8.0000","85.0000","Cep"
Data.s " 9.1667","10.6667","82.0000","Cam"
Data.s " 0.0000"," 5.0000","80.0000","Cep"
Data.s "10.6667","14.5000","80.0000","Cam"
Data.s "17.5000","18.0000","80.0000","UMi"
Data.s "20.1667","21.0000","80.0000","Dra"
Data.s " 0.0000"," 3.5083","77.0000","Cep"
Data.s "11.5000","13.5833","77.0000","Cam"
Data.s "16.5333","17.5000","75.0000","UMi"
Data.s "20.1667","20.6667","75.0000","Cep"
Data.s " 7.9667"," 9.1667","73.5000","Cam"
Data.s " 9.1667","11.3333","73.5000","Dra"
Data.s "13.0000","16.5333","70.0000","UMi"
Data.s " 3.1000"," 3.4167","68.0000","Cas"
Data.s "20.4167","20.6667","67.0000","Dra"
Data.s "11.3333","12.0000","66.5000","Dra"
Data.s " 0.0000"," 0.3333","66.0000","Cep"
Data.s "14.0000","15.6667","66.0000","UMi"
Data.s "23.5833","24.0000","66.0000","Cep"
Data.s "12.0000","13.5000","64.0000","Dra"
Data.s "13.5000","14.4167","63.0000","Dra"
Data.s "23.1667","23.5833","63.0000","Cep"
Data.s " 6.1000"," 7.0000","62.0000","Cam"
Data.s "20.0000","20.4167","61.5000","Dra"
Data.s "20.5367","20.6000","60.9167","Cep"
Data.s " 7.0000"," 7.9667","60.0000","Cam"
Data.s " 7.9667"," 8.4167","60.0000","UMa"
Data.s "19.7667","20.0000","59.5000","Dra"
Data.s "20.0000","20.5367","59.5000","Cep"
Data.s "22.8667","23.1667","59.0833","Cep"
Data.s " 0.0000"," 2.4333","58.5000","Cas"
Data.s "19.4167","19.7667","58.0000","Dra"
Data.s " 1.7000"," 1.9083","57.5000","Cas"
Data.s " 2.4333"," 3.1000","57.0000","Cas"
Data.s " 3.1000"," 3.1667","57.0000","Cam"
Data.s "22.3167","22.8667","56.2500","Cep"
Data.s " 5.0000"," 6.1000","56.0000","Cam"
Data.s "14.0333","14.4167","55.5000","UMa"
Data.s "14.4167","19.4167","55.5000","Dra"
Data.s " 3.1667"," 3.3333","55.0000","Cam"
Data.s "22.1333","22.3167","55.0000","Cep"
Data.s "20.6000","21.9667","54.8333","Cep"
Data.s " 0.0000"," 1.7000","54.0000","Cas"
Data.s " 6.1000"," 6.5000","54.0000","Lyn"
Data.s "12.0833","13.5000","53.0000","UMa"
Data.s "15.2500","15.7500","53.0000","Dra"
Data.s "21.9667","22.1333","52.7500","Cep"
Data.s " 3.3333"," 5.0000","52.5000","Cam"
Data.s "22.8667","23.3333","52.5000","Cas"
Data.s "15.7500","17.0000","51.5000","Dra"
Data.s " 2.0417"," 2.5167","50.5000","Per"
Data.s "17.0000","18.2333","50.5000","Dra"
Data.s " 0.0000"," 1.3667","50.0000","Cas"
Data.s " 1.3667"," 1.6667","50.0000","Per"
Data.s " 6.5000"," 6.8000","50.0000","Lyn"
Data.s "23.3333","24.0000","50.0000","Cas"
Data.s "13.5000","14.0333","48.5000","UMa"
Data.s " 0.0000"," 1.1167","48.0000","Cas"
Data.s "23.5833","24.0000","48.0000","Cas"
Data.s "18.1750","18.2333","47.5000","Her"
Data.s "18.2333","19.0833","47.5000","Dra"
Data.s "19.0833","19.1667","47.5000","Cyg"
Data.s " 1.6667"," 2.0417","47.0000","Per"
Data.s " 8.4167"," 9.1667","47.0000","UMa"
Data.s " 0.1667"," 0.8667","46.0000","Cas"
Data.s "12.0000","12.0833","45.0000","UMa"
Data.s " 6.8000"," 7.3667","44.5000","Lyn"
Data.s "21.9083","21.9667","44.0000","Cyg"
Data.s "21.8750","21.9083","43.7500","Cyg"
Data.s "19.1667","19.4000","43.5000","Cyg"
Data.s " 9.1667","10.1667","42.0000","UMa"
Data.s "10.1667","10.7833","40.0000","UMa"
Data.s "15.4333","15.7500","40.0000","Boo"
Data.s "15.7500","16.3333","40.0000","Her"
Data.s " 9.2500"," 9.5833","39.7500","Lyn"
Data.s " 0.0000"," 2.5167","36.7500","And"
Data.s " 2.5167"," 2.5667","36.7500","Per"
Data.s "19.3583","19.4000","36.5000","Lyr"
Data.s " 4.5000"," 4.6917","36.0000","Per"
Data.s "21.7333","21.8750","36.0000","Cyg"
Data.s "21.8750","22.0000","36.0000","Lac"
Data.s " 6.5333"," 7.3667","35.5000","Aur"
Data.s " 7.3667"," 7.7500","35.5000","Lyn"
Data.s " 0.0000"," 2.0000","35.0000","And"
Data.s "22.0000","22.8167","35.0000","Lac"
Data.s "22.8167","22.8667","34.5000","Lac"
Data.s "22.8667","23.5000","34.5000","And"
Data.s " 2.5667"," 2.7167","34.0000","Per"
Data.s "10.7833","11.0000","34.0000","UMa"
Data.s "12.0000","12.3333","34.0000","CVn"
Data.s " 7.7500"," 9.2500","33.5000","Lyn"
Data.s " 9.2500"," 9.8833","33.5000","LMi"
Data.s " 0.7167"," 1.4083","33.0000","And"
Data.s "15.1833","15.4333","33.0000","Boo"
Data.s "23.5000","23.7500","32.0833","And"
Data.s "12.3333","13.2500","32.0000","CVn"
Data.s "23.7500","24.0000","31.3333","And"
Data.s "13.9583","14.0333","30.7500","CVn"
Data.s " 2.4167"," 2.7167","30.6667","Tri"
Data.s " 2.7167"," 4.5000","30.6667","Per"
Data.s " 4.5000"," 4.7500","30.0000","Aur"
Data.s "18.1750","19.3583","30.0000","Lyr"
Data.s "11.0000","12.0000","29.0000","UMa"
Data.s "19.6667","20.9167","29.0000","Cyg"
Data.s " 4.7500"," 5.8833","28.5000","Aur"
Data.s " 9.8833","10.5000","28.5000","LMi"
Data.s "13.2500","13.9583","28.5000","CVn"
Data.s " 0.0000"," 0.0667","28.0000","And"
Data.s " 1.4083"," 1.6667","28.0000","Tri"
Data.s " 5.8833"," 6.5333","28.0000","Aur"
Data.s " 7.8833"," 8.0000","28.0000","Gem"
Data.s "20.9167","21.7333","28.0000","Cyg"
Data.s "19.2583","19.6667","27.5000","Cyg"
Data.s " 1.9167"," 2.4167","27.2500","Tri"
Data.s "16.1667","16.3333","27.0000","CrB"
Data.s "15.0833","15.1833","26.0000","Boo"
Data.s "15.1833","16.1667","26.0000","CrB"
Data.s "18.3667","18.8667","26.0000","Lyr"
Data.s "10.7500","11.0000","25.5000","LMi"
Data.s "18.8667","19.2583","25.5000","Lyr"
Data.s " 1.6667"," 1.9167","25.0000","Tri"
Data.s " 0.7167"," 0.8500","23.7500","Psc"
Data.s "10.5000","10.7500","23.5000","LMi"
Data.s "21.2500","21.4167","23.5000","Vul"
Data.s " 5.7000"," 5.8833","22.8333","Tau"
Data.s " 0.0667"," 0.1417","22.0000","And"
Data.s "15.9167","16.0333","22.0000","Ser"
Data.s " 5.8833"," 6.2167","21.5000","Gem"
Data.s "19.8333","20.2500","21.2500","Vul"
Data.s "18.8667","19.2500","21.0833","Vul"
Data.s " 0.1417"," 0.8500","21.0000","And"
Data.s "20.2500","20.5667","20.5000","Vul"
Data.s " 7.8083"," 7.8833","20.0000","Gem"
Data.s "20.5667","21.2500","19.5000","Vul"
Data.s "19.2500","19.8333","19.1667","Vul"
Data.s " 3.2833"," 3.3667","19.0000","Ari"
Data.s "18.8667","19.0000","18.5000","Sge"
Data.s " 5.7000"," 5.7667","18.0000","Ori"
Data.s " 6.2167"," 6.3083","17.5000","Gem"
Data.s "19.0000","19.8333","16.1667","Sge"
Data.s " 4.9667"," 5.3333","16.0000","Tau"
Data.s "15.9167","16.0833","16.0000","Her"
Data.s "19.8333","20.2500","15.7500","Sge"
Data.s " 4.6167"," 4.9667","15.5000","Tau"
Data.s " 5.3333"," 5.6000","15.5000","Tau"
Data.s "12.8333","13.5000","15.0000","Com"
Data.s "17.2500","18.2500","14.3333","Her"
Data.s "11.8667","12.8333","14.0000","Com"
Data.s " 7.5000"," 7.8083","13.5000","Gem"
Data.s "16.7500","17.2500","12.8333","Her"
Data.s " 0.0000"," 0.1417","12.5000","Peg"
Data.s " 5.6000"," 5.7667","12.5000","Tau"
Data.s " 7.0000"," 7.5000","12.5000","Gem"
Data.s "21.1167","21.3333","12.5000","Peg"
Data.s " 6.3083"," 6.9333","12.0000","Gem"
Data.s "18.2500","18.8667","12.0000","Her"
Data.s "20.8750","21.0500","11.8333","Del"
Data.s "21.0500","21.1167","11.8333","Peg"
Data.s "11.5167","11.8667","11.0000","Leo"
Data.s " 6.2417"," 6.3083","10.0000","Ori"
Data.s " 6.9333"," 7.0000","10.0000","Gem"
Data.s " 7.8083"," 7.9250","10.0000","Cnc"
Data.s "23.8333","24.0000","10.0000","Peg"
Data.s " 1.6667"," 3.2833"," 9.9167","Ari"
Data.s "20.1417","20.3000"," 8.5000","Del"
Data.s "13.5000","15.0833"," 8.0000","Boo"
Data.s "22.7500","23.8333"," 7.5000","Peg"
Data.s " 7.9250"," 9.2500"," 7.0000","Cnc"
Data.s " 9.2500","10.7500"," 7.0000","Leo"
Data.s "18.2500","18.6622"," 6.2500","Oph"
Data.s "18.6622","18.8667"," 6.2500","Aql"
Data.s "20.8333","20.8750"," 6.0000","Del"
Data.s " 7.0000"," 7.0167"," 5.5000","CMi"
Data.s "18.2500","18.4250"," 4.5000","Ser"
Data.s "16.0833","16.7500"," 4.0000","Her"
Data.s "18.2500","18.4250"," 3.0000","Oph"
Data.s "21.4667","21.6667"," 2.7500","Peg"
Data.s " 0.0000"," 2.0000"," 2.0000","Psc"
Data.s "18.5833","18.8667"," 2.0000","Ser"
Data.s "20.3000","20.8333"," 2.0000","Del"
Data.s "20.8333","21.3333"," 2.0000","Equ"
Data.s "21.3333","21.4667"," 2.0000","Peg"
Data.s "22.0000","22.7500"," 2.0000","Peg"
Data.s "21.6667","22.0000"," 1.7500","Peg"
Data.s " 7.0167"," 7.2000"," 1.5000","CMi"
Data.s " 3.5833"," 4.6167"," 0.0000","Tau"
Data.s " 4.6167"," 4.6667"," 0.0000","Ori"
Data.s " 7.2000"," 8.0833"," 0.0000","CMi"
Data.s "14.6667","15.0833"," 0.0000","Vir"
Data.s "17.8333","18.2500"," 0.0000","Oph"
Data.s " 2.6500"," 3.2833","-01.7500","Cet"
Data.s " 3.2833"," 3.5833","-01.7500","Tau"
Data.s "15.0833","16.2667","-03.2500","Ser"
Data.s " 4.6667"," 5.0833","-04.0000","Ori"
Data.s " 5.8333"," 6.2417","-04.0000","Ori"
Data.s "17.8333","17.9667","-04.0000","Ser"
Data.s "18.2500","18.5833","-04.0000","Ser"
Data.s "18.5833","18.8667","-04.0000","Aql"
Data.s "22.7500","23.8333","-04.0000","Psc"
Data.s "10.7500","11.5167","-06.0000","Leo"
Data.s "11.5167","11.8333","-06.0000","Vir"
Data.s " 0.0000","00.3333","-07.0000","Psc"
Data.s "23.8333","24.0000","-07.0000","Psc"
Data.s "14.2500","14.6667","-08.0000","Vir"
Data.s "15.9167","16.2667","-08.0000","Oph"
Data.s "20.0000","20.5333","-09.0000","Aql"
Data.s "21.3333","21.8667","-09.0000","Aqr"
Data.s "17.1667","17.9667","-10.0000","Oph"
Data.s " 5.8333"," 8.0833","-11.0000","Mon"
Data.s " 4.9167"," 5.0833","-11.0000","Eri"
Data.s " 5.0833"," 5.8333","-11.0000","Ori"
Data.s " 8.0833"," 8.3667","-11.0000","Hya"
Data.s " 9.5833","10.7500","-11.0000","Sex"
Data.s "11.8333","12.8333","-11.0000","Vir"
Data.s "17.5833","17.6667","-11.6667","Oph"
Data.s "18.8667","20.0000","-12.0333","Aql"
Data.s " 4.8333"," 4.9167","-14.5000","Eri"
Data.s "20.5333","21.3333","-15.0000","Aqr"
Data.s "17.1667","18.2500","-16.0000","Ser"
Data.s "18.2500","18.8667","-16.0000","Sct"
Data.s " 8.3667"," 8.5833","-17.0000","Hya"
Data.s "16.2667","16.3750","-18.2500","Oph"
Data.s " 8.5833"," 9.0833","-19.0000","Hya"
Data.s "10.7500","10.8333","-19.0000","Crt"
Data.s "16.2667","16.3750","-19.2500","Sco"
Data.s "15.6667","15.9167","-20.0000","Lib"
Data.s "12.5833","12.8333","-22.0000","Crv"
Data.s "12.8333","14.2500","-22.0000","Vir"
Data.s " 9.0833"," 9.7500","-24.0000","Hya"
Data.s " 1.6667"," 2.6500","-24.3833","Cet"
Data.s " 2.6500"," 3.7500","-24.3833","Eri"
Data.s "10.8333","11.8333","-24.5000","Crt"
Data.s "11.8333","12.5833","-24.5000","Crv"
Data.s "14.2500","14.9167","-24.5000","Lib"
Data.s "16.2667","16.7500","-24.5833","Oph"
Data.s " 0.0000"," 1.6667","-25.5000","Cet"
Data.s "21.3333","21.8667","-25.5000","Cap"
Data.s "21.8667","23.8333","-25.5000","Aqr"
Data.s "23.8333","24.0000","-25.5000","Cet"
Data.s " 9.7500","10.2500","-26.5000","Hya"
Data.s " 4.7000"," 4.8333","-27.2500","Eri"
Data.s " 4.8333"," 6.1167","-27.2500","Lep"
Data.s "20.0000","21.3333","-28.0000","Cap"
Data.s "10.2500","10.5833","-29.1667","Hya"
Data.s "12.5833","14.9167","-29.5000","Hya"
Data.s "14.9167","15.6667","-29.5000","Lib"
Data.s "15.6667","16.0000","-29.5000","Sco"
Data.s " 4.5833"," 4.7000","-30.0000","Eri"
Data.s "16.7500","17.6000","-30.0000","Oph"
Data.s "17.6000","17.8333","-30.0000","Sgr"
Data.s "10.5833","10.8333","-31.1667","Hya"
Data.s " 6.1167"," 7.3667","-33.0000","CMa"
Data.s "12.2500","12.5833","-33.0000","Hya"
Data.s "10.8333","12.2500","-35.0000","Hya"
Data.s " 3.5000"," 3.7500","-36.0000","For"
Data.s " 8.3667"," 9.3667","-36.7500","Pyx"
Data.s " 4.2667"," 4.5833","-37.0000","Eri"
Data.s "17.8333","19.1667","-37.0000","Sgr"
Data.s "21.3333","23.0000","-37.0000","PsA"
Data.s "23.0000","23.3333","-37.0000","Scl"
Data.s " 3.0000"," 3.5000","-39.5833","For"
Data.s " 9.3667","11.0000","-39.7500","Ant"
Data.s " 0.0000"," 1.6667","-40.0000","Scl"
Data.s " 1.6667"," 3.0000","-40.0000","For"
Data.s " 3.8667"," 4.2667","-40.0000","Eri"
Data.s "23.3333","24.0000","-40.0000","Scl"
Data.s "14.1667","14.9167","-42.0000","Cen"
Data.s "15.6667","16.0000","-42.0000","Lup"
Data.s "16.0000","16.4208","-42.0000","Sco"
Data.s " 4.8333"," 5.0000","-43.0000","Cae"
Data.s " 5.0000"," 6.5833","-43.0000","Col"
Data.s " 8.0000"," 8.3667","-43.0000","Pup"
Data.s " 3.4167"," 3.8667","-44.0000","Eri"
Data.s "16.4208","17.8333","-45.5000","Sco"
Data.s "17.8333","19.1667","-45.5000","CrA"
Data.s "19.1667","20.3333","-45.5000","Sgr"
Data.s "20.3333","21.3333","-45.5000","Mic"
Data.s " 3.0000"," 3.4167","-46.0000","Eri"
Data.s " 4.5000"," 4.8333","-46.5000","Cae"
Data.s "15.3333","15.6667","-48.0000","Lup"
Data.s " 0.0000"," 2.3333","-48.1667","Phe"
Data.s " 2.6667"," 3.0000","-49.0000","Eri"
Data.s " 4.0833"," 4.2667","-49.0000","Hor"
Data.s " 4.2667"," 4.5000","-49.0000","Cae"
Data.s "21.3333","22.0000","-50.0000","Gru"
Data.s " 6.0000"," 8.0000","-50.7500","Pup"
Data.s " 8.0000"," 8.1667","-50.7500","Vel"
Data.s " 2.4167"," 2.6667","-51.0000","Eri"
Data.s " 3.8333"," 4.0833","-51.0000","Hor"
Data.s " 0.0000"," 1.8333","-51.5000","Phe"
Data.s " 6.0000"," 6.1667","-52.5000","Car"
Data.s " 8.1667"," 8.4500","-53.0000","Vel"
Data.s " 3.5000"," 3.8333","-53.1667","Hor"
Data.s " 3.8333"," 4.0000","-53.1667","Dor"
Data.s " 0.0000"," 1.5833","-53.5000","Phe"
Data.s " 2.1667"," 2.4167","-54.0000","Eri"
Data.s " 4.5000"," 5.0000","-54.0000","Pic"
Data.s "15.0500","15.3333","-54.0000","Lup"
Data.s " 8.4500"," 8.8333","-54.5000","Vel"
Data.s " 6.1667"," 6.5000","-55.0000","Car"
Data.s "11.8333","12.8333","-55.0000","Cen"
Data.s "14.1667","15.0500","-55.0000","Lup"
Data.s "15.0500","15.3333","-55.0000","Nor"
Data.s " 4.0000"," 4.3333","-56.5000","Dor"
Data.s " 8.8333","11.0000","-56.5000","Vel"
Data.s "11.0000","11.2500","-56.5000","Cen"
Data.s "17.5000","18.0000","-57.0000","Ara"
Data.s "18.0000","20.3333","-57.0000","Tel"
Data.s "22.0000","23.3333","-57.0000","Gru"
Data.s " 3.2000"," 3.5000","-57.5000","Hor"
Data.s " 5.0000"," 5.5000","-57.5000","Pic"
Data.s " 6.5000"," 6.8333","-58.0000","Car"
Data.s " 0.0000"," 1.3333","-58.5000","Phe"
Data.s " 1.3333"," 2.1667","-58.5000","Eri"
Data.s "23.3333","24.0000","-58.5000","Phe"
Data.s " 4.3333"," 4.5833","-59.0000","Dor"
Data.s "15.3333","16.4208","-60.0000","Nor"
Data.s "20.3333","21.3333","-60.0000","Ind"
Data.s " 5.5000"," 6.0000","-61.0000","Pic"
Data.s "15.1667","15.3333","-61.0000","Cir"
Data.s "16.4208","16.5833","-61.0000","Ara"
Data.s "14.9167","15.1667","-63.5833","Cir"
Data.s "16.5833","16.7500","-63.5833","Ara"
Data.s " 6.0000"," 6.8333","-64.0000","Pic"
Data.s " 6.8333"," 9.0333","-64.0000","Car"
Data.s "11.2500","11.8333","-64.0000","Cen"
Data.s "11.8333","12.8333","-64.0000","Cru"
Data.s "12.8333","14.5333","-64.0000","Cen"
Data.s "13.5000","13.6667","-65.0000","Cir"
Data.s "16.7500","16.8333","-65.0000","Ara"
Data.s " 2.1667"," 3.2000","-67.5000","Hor"
Data.s " 3.2000"," 4.5833","-67.5000","Ret"
Data.s "14.7500","14.9167","-67.5000","Cir"
Data.s "16.8333","17.5000","-67.5000","Ara"
Data.s "17.5000","18.0000","-67.5000","Pav"
Data.s "22.0000","23.3333","-67.5000","Tuc"
Data.s " 4.5833"," 6.5833","-70.0000","Dor"
Data.s "13.6667","14.7500","-70.0000","Cir"
Data.s "14.7500","17.0000","-70.0000","TrA"
Data.s " 0.0000"," 1.3333","-75.0000","Tuc"
Data.s " 3.5000"," 4.5833","-75.0000","Hyi"
Data.s " 6.5833"," 9.0333","-75.0000","Vol"
Data.s " 9.0333","11.2500","-75.0000","Car"
Data.s "11.2500","13.6667","-75.0000","Mus"
Data.s "18.0000","21.3333","-75.0000","Pav"
Data.s "21.3333","23.3333","-75.0000","Ind"
Data.s "23.3333","24.0000","-75.0000","Tuc"
Data.s " 0.7500"," 1.3333","-76.0000","Tuc"
Data.s " 0.0000"," 3.5000","-82.5000","Hyi"
Data.s " 7.6667","13.6667","-82.5000","Cha"
Data.s "13.6667","18.0000","-82.5000","Aps"
Data.s " 3.5000"," 7.6667","-85.0000","Men"
Data.s " 0.0000","24.0000","-90.0000","Oct"
Data.s "-1"     ,"0"      ,"0"       ,"0"       
EndDataSection

Procedure.s findname(nam.s)
 Protected vollername.s,a.s,abkur.s
 Restore namen
 Repeat
  Read.s vollername
  Read.s a
  Read.s a
  Read.s abkur
  If UCase(abkur) = UCase(nam)
    ProcedureReturn vollername
  EndIf
 Until vollername = "ENDE"
EndProcedure

[GerhardHoeberth]

Hallo andi256

tolle Arbeit für Astronomen

nur in einem muss ich dich korrigieren:

richtige Sternzeichen
----------------------
Die Tierkreiszeichen der Astrologie sind ja vom ~ Stand Christi Geburt und stimmen mit dem tatsächlichen Stand nicht überein.

Du verwechselst - wie viele Astronomen bei ihrer Kritik an der Astrologie - Tierkreiszeichen mit Sternbildern.
Die Astronomie arbeitet mit Sternbildern (siderischer Kreis), die sich aufgrund der Präzession im Verhältnis zu unseren Jahreszeiten permanent verschieben.
In nicht ganz 25.800 Jahren einmal im Kreis.
Die Astrologie arbeitet aber bei ihrer Einteilung mit den Tierkreiszeichen (tropischer Kreis), von denen es nur 12 gibt und die sich nicht an den Sternen, sondern am Frühlingspunkt orientieren.
Dein Programm rechnet also das richtige Sternbild, aber das falsche Tierkreiszeichen aus
(Okay, du berechnest mit dem Programm beides )

herzlichen Gruß
Gerhard

[andi256]

Ich werd der Astrologie nie etwas abgewinnen .... ist für mich reiner Aberglaube (Unwissenheit *duck*) ... ist aber nur meine Meinung!

Die Astrologie arbeitet aber bei ihrer Einteilung mit den Tierkreiszeichen (tropischer Kreis), von denen es nur 12 gibt und die sich nicht an den Sternen, sondern am Frühlingspunkt orientieren.

aus der Wiki

Der Frühlingspunkt wird auch Widderpunkt genannt, weil er sich historisch zum Zeitpunkt seiner Bestimmung im Sternbild Aries (Widder) befand. Er ist inzwischen jedoch aufgrund der Präzession in das Sternbild Pisces (Fische) gerückt.

also Frühlingspunkt im Widder ist ja genau so falsch
aber

Für die westliche Astrologie ist dieser Umstand allerdings nicht von Belang. Sie arbeitet mit dem tropischen Tierkreis, dessen Beginn, der Frühlingspunkt, grundsätzlich als Null Grad Widder definiert wird.

ist natürlich auch ein Ansatz wie man solche Probleme übergehen kann .... wir definieren kurzer Hand mal, das sich die Sonne um die Erde dreht ... und alles ist Gut ...
zum Nachdenken einmal lesen

mfg Andi