Windows Directory und Name der Executable

[DerMeister]

Hallo
Ich hätte mal 2 kleine Fragen.
Zuerst: Ist es möglich die Windows Directory (die ja standardmäßig bei C:\Windows ist) ähnlich wie mit GetHomeDirectory() herauszufinden? Oder kann die Windows Directory sowieso nirgendwo anders sein?

Und dann noch ob es möglich ist, ob eine bereits kompilierte Exe Datei ihren eigenen Dateinamen herausfinden kann (falls die Exe zB vom Benutzer umbenannt wurde)?

Danke schon mal falls jemand antwortet

[c4s]

Code: Alles auswählen

Procedure.s GetSpecialFolderPath(CSIDL.l)
	Protected LibraryID
	Protected Path.s = Space(#MAX_PATH)

	LibraryID = OpenLibrary(#PB_Any, "shell32.dll")
	If LibraryID
		CallFunction(LibraryID, "SHGetSpecialFolderPathA", 0, @Path, CSIDL, 0)
		CloseLibrary(LibraryID)
	EndIf

	ProcedureReturn Path
EndProcedure

Debug GetSpecialFolderPath(#CSIDL_WINDOWS) ;Windows-Pfad
Debug GetFilePart(ProgramFilename()) ;Programmname

Für die Prozedur GetSpecialFolderPath() findest du je nach belieben auch etwas andere herangehensweisen mit der Forensuche. So sollte es aber auch funktionieren.

[TomS]

@1:

Code: Alles auswählen

Debug GetEnvironmentVariable("windir")

EDIT
@2:

Code: Alles auswählen

ProgramFilename()

Wo auch immer in der Hilfe der Befehl wieder versteckt ist oO

[Kiffi]

Wo auch immer in der Hilfe der Befehl wieder versteckt ist oO

Im Kapitel Process

oder einfacher: Cursor auf ProgramFilename() setzen, <F1> drücken und tadaaa!

Grüße ... Kiffi

[ts-soft]

Wer ein Ergebnis für Windir unter allen WinVersionen wünscht sollte nach Möglichkeit dies,
und nicht die anderen Vorschläge, nutzen

Code: Alles auswählen

Define windir.s{#MAX_PATH}
GetWindowsDirectory_(@windir, #MAX_PATH)
Debug windir

Dasselbe gilt für das Systemdirectory, möglichst keine Environmentvars oder Specialfolders,
die es z.B. unter Win95 nicht gibt.

Bei Programmen, die für W2K und aufwärts sind, ist dies aber vernachlässigbar.

Gruß
Thomas

[Mok]

Wer ein Ergebnis für Windir unter allen WinVersionen wünscht sollte nach Möglichkeit dies,
und nicht die anderen Vorschläge, nutzen

Code: Alles auswählen

...

@DerMeister: Für dich wird das nicht gehen, da du eine Demo-Version hast (WinAPI und so...).

[DerMeister]

Ja, als ich den Code kompilieren wollte kannte Purebasic die Konstante #MAX_PATH nicht.
Aber trotzdem Danke.

[Kiffi]

Ja, als ich den Code kompilieren wollte kannte Purebasic die Konstante #MAX_PATH nicht.

kleiner Tipp: es gibt mittlerweile die V4.41 als Demo.

-> http://www.purebasic.com/download.php

Aber trotzdem Danke.

schon aufgegeben?

Grüße ... Kiffi

[DerMeister]

kleiner Tipp: es gibt mittlerweile die V4.41 als Demo.

Ah Danke für die Info. Ich schau da nicht immer so regelmäßig nach.

schon aufgegeben?

Mir gerade noch eingefallen is, dass es evtl. über EnvironmentVariablen geht, in der PB Hilfe is auch bei ExamineEnvironmentVariables() ein Beispiel vorhanden. Da kann man auch verschiedene Sachen wie HomeDrive, WindowsDirectory, Userdomain etc. herausfinden.

Edit:
Hier noch ein Beispiel wie es gehen könnte.

Code: Alles auswählen

OpenConsole()
If ExamineEnvironmentVariables()
  While NextEnvironmentVariable()
    If EnvironmentVariableName() = "windir"
      PrintN(EnvironmentVariableValue())
    EndIf
  Wend
EndIf
Input()

[ts-soft]

Demokompatible Version (hoffe ich mal )

Code: Alles auswählen

Prototype GetWindowsDirectory(lpBuffer.s, uSize)

Procedure.s GetWindowsDirectory()
  Protected result.s = Space(260)
  Protected DLL = OpenLibrary(#PB_Any, "kernel32.dll")
  Protected _GetWindowsDirectory.GetWindowsDirectory
  If DLL
    CompilerIf #PB_Compiler_Unicode
    _GetWindowsDirectory = GetFunction(DLL, "GetWindowsDirectoryW")
    CompilerElse
    _GetWindowsDirectory = GetFunction(DLL, "GetWindowsDirectoryA")
    CompilerEndIf
    If _GetWindowsDirectory
      _GetWindowsDirectory(result, 260)
      If result
        If Right(result, 1) <> "\" : result + "\" : EndIf
      EndIf
    EndIf
    CloseLibrary(DLL)
  EndIf
  ProcedureReturn result
EndProcedure

Debug GetWindowsDirectory()