Aktuelle Zeit: 11.12.2019 18:25

Alle Zeiten sind UTC + 1 Stunde [ Sommerzeit ]




Ein neues Thema erstellen Auf das Thema antworten  [ 14 Beiträge ]  Gehe zu Seite 1, 2  Nächste
Autor Nachricht
 Betreff des Beitrags: Frohes neues Jahr - 2016
BeitragVerfasst: 01.01.2016 00:59 
Offline
Admin
Benutzeravatar

Registriert: 05.10.2006 18:55
Wohnort: Berlin
Hi meine lieben,

ich wünsche euch ein frohes neues Jahr. Feliz año nuevo! Feiert schön. :allright:

Bild
BildBild

_________________
BildBildBildBild BildBild


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Frohes neues Jahr - 2016
BeitragVerfasst: 01.01.2016 13:10 
Offline
Benutzeravatar

Registriert: 10.10.2014 13:14
Wohnort: Wolfenbüttel
Ein frohes neues Jahr euch allen

_________________
weil einfach einfach einfach ist ... mach' ich es anders


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Frohes neues Jahr - 2016
BeitragVerfasst: 01.01.2016 14:31 
Offline
Benutzeravatar

Registriert: 24.11.2004 13:12
Wohnort: Germany
Von mir auch ein Frohes neues Jahr :D

_________________
Alles ist möglich, fragt sich nur wie...
Projekte ThreadToGUI / EventDesigner V3 / OOP-BaseClass-Modul / OPC-Helper DLL
PB v3.30 / v5.4x - OS Mac Mini OSX 10.xx / Window 10 Pro. (X64) /Window 7 Pro. (X64) / Window XP Pro. (X86) / Ubuntu 14.04
Downloads auf Webspace


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: AW: Frohes neues Jahr - 2016
BeitragVerfasst: 01.01.2016 16:17 
Offline
Benutzeravatar

Registriert: 25.04.2006 17:29
Wohnort: Nähe Hamburg
Ein frohes neues Jahr und alles Gute vom Frosch. :-)

_________________
"Never run a changing system!"
PB 5.71 x64, OS: Windows 7 Pro x64, Desktopscaling: 125%, CPU: I7 6500, RAM: 16 GB, GPU: Intel Graphics HD 520
Ich bin Baujahr 1968, also aktuell 51.


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Frohes neues Jahr - 2016
BeitragVerfasst: 01.01.2016 16:18 
Offline
Kommando SG1
Benutzeravatar

Registriert: 01.11.2005 13:34
Wohnort: Glienicke
Code:
EnableExplicit

InitSprite()

Structure Vector
   X.f
   Y.f
EndStructure

Structure Spark
   Position.Vector
   Velocity.Vector
   Time.i
   Color.i
   Blink.i
   Weight.i
EndStructure

Structure Bullet
   Position.Vector
   Velocity.Vector
   Time.i
   Color.i
   Weight.i
   Type.i
EndStructure

Global NewList Bullet.Bullet()
Global NewList Spark.Spark()

Enumeration
   #Window
EndEnumeration

OpenWindow(#Window, 0, 0, 1200, 800, "ScreenTitle", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)
OpenWindowedScreen(WindowID(#Window), 0, 0, WindowWidth(#Window), WindowHeight(#Window), 0, 0, 0)
RandomSeed(4)

Define Time.i, OldTime.i, TimeFactor.f, Length.f, I.i, Angle.f, Radius.f, Factor.f, *Spark.Spark

Repeat
   
   Repeat
      Select WindowEvent()
         Case #PB_Event_CloseWindow
            End
         Case #PB_Event_None
            Break
      EndSelect
   ForEver
   
   ClearScreen(0)
   
   Time = ElapsedMilliseconds()
   TimeFactor = (Time-OldTime)*0.001
   OldTime = Time
   
   StartDrawing(ScreenOutput())
   
   ForEach Spark()
      Spark()\Position\X + Spark()\Velocity\X*TimeFactor
      Spark()\Position\Y + Spark()\Velocity\Y*TimeFactor
      Spark()\Velocity\Y + 98.1*TimeFactor
      If Time > Spark()\Time-250
         Factor = (Spark()\Time-Time)/250.
      Else
         Factor = 1.0
      EndIf
      If Spark()\Weight Or Spark()\Blink
         Circle(Spark()\Position\X, Spark()\Position\Y, Spark()\Blink+Sqr(Spark()\Weight/100), RGB(Red(Spark()\Color)*(Factor*0.5+0.5), Green(Spark()\Color)*(Factor*0.5+0.5), Blue(Spark()\Color)*(Factor*0.5+0.5)))
      Else
         Line(Spark()\Position\X, Spark()\Position\Y, 1, 1, RGB(Red(Spark()\Color)*Factor, Green(Spark()\Color)*Factor, Blue(Spark()\Color)*Factor))
      EndIf
      If Spark()\Blink
         *Spark = Spark()
         Angle = Radian(Random(3600)/10.)
         Radius = Sqr(Random(1000)/1000.)*10
         AddElement(Spark())
         Spark()\Position = *Spark\Position
         ;Spark()\Velocity = *Spark\Velocity
         Spark()\Velocity\X + Cos(Angle)*Radius
         Spark()\Velocity\Y + Sin(Angle)*Radius
         Spark()\Color = $40B0F0 + (Random($F)|Random($F)<<8|Random($F)<<16)
         Spark()\Time = Time + 250 + Random(250)
      ChangeCurrentElement(Spark(), *Spark)
      EndIf
      If Time > Spark()\Time
         If Spark()\Weight
            *Spark = Spark()
            For I = 1 To *Spark\Weight
               Angle = Radian(Random(3600)/10.)
               Radius = Sqr(Random(1000)/1000.)*40+10
               AddElement(Spark())
               Spark()\Position = *Spark\Position
               Spark()\Velocity = *Spark\Velocity
               Spark()\Velocity\X + Cos(Angle)*Radius
               Spark()\Velocity\Y + Sin(Angle)*Radius
               Spark()\Color = $40B0F0 + (Random($F)|Random($F)<<8|Random($F)<<16)
               Spark()\Time = Time + 250 + Random(250)
            Next
            ChangeCurrentElement(Spark(), *Spark)
         EndIf
         DeleteElement(Spark())
      EndIf
   Next

   ForEach Bullet()
      Bullet()\Position\X + Bullet()\Velocity\X*TimeFactor
      Bullet()\Position\Y + Bullet()\Velocity\Y*TimeFactor
      Bullet()\Velocity\Y + 98.1*TimeFactor
      Length = Sqr(Bullet()\Velocity\X*Bullet()\Velocity\X+Bullet()\Velocity\Y*Bullet()\Velocity\Y)
      Circle(Bullet()\Position\X, Bullet()\Position\Y, 1+Sqr(Bullet()\Weight/100), $C0C0C0)
      LineXY(Bullet()\Position\X, Bullet()\Position\Y, Bullet()\Position\X-Bullet()\Velocity\X*20/Length, Bullet()\Position\Y-Bullet()\Velocity\Y*20/Length, $808080)
      If Bullet()\Time < Time
         Select Bullet()\Type
            Case 0
               For I = 1 To Bullet()\Weight
                  Angle = Radian(Random(3600)/10.)
                  Radius = Pow(Random(1000)/1000., 0.25)*Sqr(Bullet()\Weight)*5
                  AddElement(Spark())
                  Spark()\Position = Bullet()\Position
                  Spark()\Velocity = Bullet()\Velocity
                  Spark()\Velocity\X + Cos(Angle)*Radius
                  Spark()\Velocity\Y + Sin(Angle)*Radius
                  Spark()\Color = Bullet()\Color + (Random($F)|Random($F)<<8|Random($F)<<16)
                  Spark()\Time = Time + 1000 + Random(1000)
               Next
            Case 1
               For I = 1 To Bullet()\Weight/10
                  Angle = Radian(Random(3600)/10.)
                  Radius = Sqr(Random(1000)/1000.)*Sqr(Bullet()\Weight)*5
                  AddElement(Spark())
                  Spark()\Position = Bullet()\Position
                  Spark()\Velocity = Bullet()\Velocity
                  Spark()\Velocity\X + Cos(Angle)*Radius
                  Spark()\Velocity\Y + Sin(Angle)*Radius
                  Spark()\Color = Bullet()\Color + (Random($F)|Random($F)<<8|Random($F)<<16)
                  Spark()\Time = Time + 500 + Random(500)
                  Spark()\Weight = 50
               Next
            Case 2
               For I = 1 To Bullet()\Weight/10
                  Angle = Radian(Random(3600)/10.)
                  Radius = Sqr(Random(1000)/1000.)*Sqr(Bullet()\Weight)*5
                  AddElement(Spark())
                  Spark()\Position = Bullet()\Position
                  Spark()\Velocity = Bullet()\Velocity
                  Spark()\Velocity\X + Cos(Angle)*Radius
                  Spark()\Velocity\Y + Sin(Angle)*Radius
                  Spark()\Color = Bullet()\Color + (Random($F)|Random($F)<<8|Random($F)<<16)
                  Spark()\Time = Time + 2500 + Random(500)
                  Spark()\Blink = #True
               Next
         EndSelect
         DeleteElement(Bullet())
      ElseIf Random(1) = 0
         Radius = Random(50)+50
         Angle = Radian(Random(100)/10.-5) + ATan2(Bullet()\Velocity\X, Bullet()\Velocity\Y)
         AddElement(Spark())
         Spark()\Position = Bullet()\Position
         Spark()\Velocity = Bullet()\Velocity
         Spark()\Velocity\X - Cos(Angle)*Radius
         Spark()\Velocity\Y - Sin(Angle)*Radius
         Spark()\Color = $40B0F0 + (Random($F)|Random($F)<<8|Random($F)<<16)
         Spark()\Time = Time + 1000 + Random(1000)
      EndIf
   Next
   
   If Random(20) = 0
      Angle = Radian(Random(400)/10.+250)
      AddElement(Bullet())
      Bullet()\Position\X = ScreenWidth()/2 - 100 + Random(200)
      Bullet()\Position\Y = ScreenHeight()
      Bullet()\Velocity\X = Cos(Angle)*350
      Bullet()\Velocity\Y = Sin(Angle)*350
      Bullet()\Color = PeekI(?Color+Random(5)*SizeOf(Integer))
      Bullet()\Time = Time + 2000 + Random(500)
      Bullet()\Weight = 100+Random(800)
      Bullet()\Type = Random(2)
   EndIf
   
   StopDrawing()
   
   FlipBuffers()
   
ForEver

DataSection
   Color:
   Data.i $4060F0, $00F040, $F08040, $00D0F0, $F040C0, $F0F0F0
EndDataSection
Edit: 3 Typen

_________________
Bild
 
BildBildBild


Zuletzt geändert von STARGÅTE am 01.01.2016 16:28, insgesamt 3-mal geändert.

Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Frohes neues Jahr - 2016
BeitragVerfasst: 01.01.2016 16:23 
Offline
Admin
Benutzeravatar

Registriert: 05.10.2006 18:55
Wohnort: Berlin
@STARGÅTE
Nice :allright:

_________________
BildBildBildBild BildBild


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Frohes neues Jahr - 2016
BeitragVerfasst: 01.01.2016 16:41 
Offline

Registriert: 13.05.2010 09:26
Wohnort: Berlin
Ich wünsche ebenfalls ein Frohes Neues Jahr!

_________________
Dieser Satz ist falsch.


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Frohes neues Jahr - 2016
BeitragVerfasst: 01.01.2016 18:37 
Offline

Registriert: 25.03.2013 09:59
Ich wünsche Euch auch ein gutes neues Jahr. <)

_________________
PureBasic Linux-API-Library: http://www.chabba.de


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Frohes neues Jahr - 2016
BeitragVerfasst: 01.01.2016 19:44 
Offline
Benutzeravatar

Registriert: 08.09.2004 00:57
Wohnort: Berlin
Von mir auch ein schönes neues Jahr!

@STARGÅTE
Cool!
Unter Linux kommt leider ein IMA in WindowEvent(), aber unter Windows läuft es einwandfrei. Schätze mal ein Bug in Linux
und nicht in Deinem Code.

_________________
PureBasic 5.71 | SpiderBasic 2.21 | Windows 10 Pro (x64) | Linux Mint 19.2 (x64)
Nutella hat nur sehr wenig Vitamine. Deswegen muss man davon relativ viel essen.
Bild


Nach oben
 Profil  
Mit Zitat antworten  
 Betreff des Beitrags: Re: Frohes neues Jahr - 2016
BeitragVerfasst: 01.01.2016 20:02 
Offline
Benutzeravatar

Registriert: 11.08.2005 19:08
So, hoffentlich sind alle gut durchgekommen. Ich wünsche euch allen viel Erfolg und Gesundheit fürs neue Jahr. :)

@STARGÅTE: Immer wieder verblüffend, was mit so wenig Code möglich ist. Echt klasse gemacht! :allright:

@ts-soft: Bei mir läuft es unter Linux mit PB_5.41_x64 ohne Probleme. Edit: Ok, wenn man das Fenster verschieben möchte oder wenn das Fenster den Fokus verliert, kommt der von ts-soft besagte Fehler.

_________________
Bild
Warum OpenSource eine Lizenz haben sollte
PureBasic-CodeArchiv-Rebirth: Git-Repository / Download -- Jede Hilfe ist willkommen!
Manjaro Xfce x64 (Hauptsystem) :: WindowsXP/Xubuntu x86 (VirtualBox) :: PureBasic (Linux: x86/x64, Windows: x86) :: jeweils neueste Version


Nach oben
 Profil  
Mit Zitat antworten  
Beiträge der letzten Zeit anzeigen:  Sortiere nach  
Ein neues Thema erstellen Auf das Thema antworten  [ 14 Beiträge ]  Gehe zu Seite 1, 2  Nächste

Alle Zeiten sind UTC + 1 Stunde [ Sommerzeit ]


Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 4 Gäste


Sie dürfen keine neuen Themen in diesem Forum erstellen.
Sie dürfen keine Antworten zu Themen in diesem Forum erstellen.
Sie dürfen Ihre Beiträge in diesem Forum nicht ändern.
Sie dürfen Ihre Beiträge in diesem Forum nicht löschen.

Suche nach:
Gehe zu:  

 


Powered by phpBB © 2008 phpBB Group | Deutsche Übersetzung durch phpBB.de
subSilver+ theme by Canver Software, sponsor Sanal Modifiye