PureBasic

Code : Tout sélectionner

Enumeration Window
  #MainForm
EndEnumeration

Enumeration Gadget
  #MyTable
EndEnumeration


Procedure MainFormCallBack(hwnd, msg, wParam, lParam)
  Protected *pnmhdr.NMHDR, *pnmlistview.NMLISTVIEW
  
  Select msg    
    Case #WM_NOTIFY
      
      *pnmhdr = lParam
      
      If *pnmhdr\code = #LVN_COLUMNCLICK           
        *pnmlistview = lParam
        If *pnmlistview\hdr\hwndFrom = GadgetID(#MyTable) 
                    
          ;Quel est le numéro de la colonne cliquée ?
          NumCol = *pnmlistview\iSubItem
          Debug NumCol
          
          ;Quel est la largeur de la colonne cliquée 
          Debug GetGadgetItemAttribute(#MyTable, 0, #PB_ListIcon_ColumnWidth, NumCol)
          
        EndIf
      EndIf
      
  EndSelect
  ProcedureReturn #PB_ProcessPureBasicEvents
EndProcedure


If OpenWindow(#MainForm, 0, 0, 800, 600, "New Project", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)      
  ListIconGadget(#MyTable, 10, 10, 780, 580, "Col 1", 150, #PB_ListIcon_FullRowSelect)
  AddGadgetColumn(#MyTable, 1, "Col 2", 300)
  
  ;Jeu test pour remplir un peu la table
  For Row = 0 To 9
    AddGadgetItem(#MyTable, -1, "Item " + Str(Row) + Chr(10) + "Value " + Str(Row))
  Next
  
  SetWindowCallback(@MainFormCallBack())
    
  Repeat : Until WaitWindowEvent(10) = #PB_Event_CloseWindow
EndIf