PureBasic

Forums PureBasic - Français
https://www.purebasic.fr/french/

Easy Loader 1.4

https://www.purebasic.fr/french/viewtopic.php?t=14713

Page 1 sur 2

Easy Loader 1.4

Publié : jeu. 21/août/2014 23:48
par Ar-S
EasyLoader est un petit logiciel sans prétention permettant de récupérer sur les sites des editeurs les dernières moutures de certains logiciels que j'affectionne et que j'installe souvent chez mes clients. ça évite de devoir les rechercher à chaque fois.
Certains sont en téléchargement directe mais la plupart des boutons vous amènent sur la page ou vous pourrez choisir quel versions vous souhaitez (windows/linux x86 x64...)



Image

Téléchargement : http://stock.ldvmultimedia.com/Easy_Loader1.4.exe

VERSION 1.4
- Nouvelle icone
- Bouton don
- Ajout de 2 utilitaires (Gifcam et Toycon)
- Agrandissement de la police des infos

VERSION 1.3
Passage aux combos Box
Ajout des principaux constructeurs pour récupérer les pilotes facilement.

Code source de la v1.0

Code : Tout sélectionner

;*****************************************************************************
;*
;* Easy Loader - Aout 2014 
;* PureBasic 5.30
;* V1.0
;*
;* Author   :	Ar-S / LDVMULTIMEDIA
;* Notes    :	Merci à NetMaestro pour la routine de détection du survol des boutons
;*
;*****************************************************************************

Declare IsMouseOver()

Enumeration fenetre
  #LDVM
EndEnumeration
;}
;{ Gadgets
Enumeration 0
  #BT_FF
  #BT_MBAM
  #BT_ADWC
  #BT_Faststone
  #BT_AIMP
  #BT_Infra
  #BT_JAVA
  #BT_FlashP
  #BT_FlashR
  #BT_LOFF
  #BT_VLC
  #BT_BTSync
  #info
EndEnumeration

Enumeration fonts
#Font_BT
#Font_EDIT
EndEnumeration

Global BT_FF_TT, BT_MBAM_TT, BT_ADWC_TT, BT_Faststone_TT, BT_AIMP_TT, BT_Infra_TT, BT_JAVA_TT, BT_FlashP_TT, BT_FlashR_TT, BT_LOFF_TT, BT_VLC_TT, BT_BTSync_TT
;}
Global.s U_FF, U_MBAM, U_ADWC, U_FST, U_AIMP, U_INFRA, U_JAVA, U_FP, U_AR, U_LO, U_VLC, U_BTS
Global.i Lb, Hb, x1, x2, y1
Global Path$ = GetCurrentDirectory()
Global hwnd
Global info$ = "Bienvenue sur Easy Loader" + Chr(13) + Chr(13) +"Logiciel réalisé par Ar-S"+Chr(13)+"http://ldvmultimedia.com"

LoadFont(#Font_BT, "Arial", 11,#PB_Font_HighQuality) 
LoadFont(#Font_EDIT, "Arial", 10,#PB_Font_HighQuality) 
SetGadgetFont(#PB_Default, FontID(#Font_BT)) 


x1 = 5 		; x colonne 1
x2 = 170	; x colonne 2
y1 = 5		; y ligne 1
Lb = 160	; larg gadget
Hb = 25		; hauteur gadget

U_FF 		= "https://ftp.mozilla.org/pub/mozilla.org/firefox/releases/latest/win32/fr/" ; page
U_MBAM 	= "http://downloads.malwarebytes.org/file/mbam/"				; DDL
U_ADWC 	= "https://toolslib.net/downloads/finish/1/get/OkLn/"			; DDL
U_FST 		= "http://www.faststone.org/FSViewerDownload.htm"			; Page
U_AIMP 	= "http://www.aimp.ru/index.php?do=download"				; Page
U_INFRA 	= "http://infrarecorder.org/?page_id=5"				 			; Page
U_JAVA 		= "https://www.java.com/fr/download/manual.jsp"				; Page
U_FP			=	"http://get.adobe.com/fr/flashplayer/"							; Page
U_AR 		= 	"http://get.adobe.com/fr/reader/"								; Page
U_LO			=	"https://fr.libreoffice.org/download/libreoffice-fresh/"		; Page
U_VLC		=	"http://www.videolan.org/vlc/"										; Page
U_BTS		=	"http://download-lb.utorrent.com/endpoint/btsync/os/windows/track/stable"	;	DDL

Procedure GOsoft(URL$)
	RunProgram (URL$,"","",0)
EndProcedure

Structure App
	name.s
	url.s
	info.s
	id.b
EndStructure

Global Dim App.App(11)

App(0)\name = "Firefox"
App(0)\url = U_FF
App(0)\info ="Accés : Page de téléchargement"+Chr(13)+Chr(13)+"Navigateur libre et gratuit, Firefox est un navigateur sans malware ni espion, à installer sans crainte. Nous vous recommandons l'ajout de l'extension AdBlock Plus contre les pubs."
App(0)\id = #BT_FF

App(1)\name = "Malwarebytes Antimalware"
App(1)\url = U_MBAM
App(1)\info = "Accés : Téléchargement directe"+Chr(13)+Chr(13)+"Malwabytes Antimalware est un logiciel destiné à nettoyer votre PC des multiples malwares que vous pourrez croiser sur le net. La version gratuite vous permet de nettoyer, la version payante vous assure une protection en temps réel."
App(1)\id = #BT_MBAM

App(2)\name = "ADW Cleaner"
App(2)\url = U_ADWC
App(2)\info = "Accés : Téléchargement directe"+Chr(13)+Chr(13)+"ADW Cleaner est petit mais puissant, il est destiné aux malwares infectant les navigateurs. Il nettoie aussi le registre et les éventuels dossiers corrompus."
App(2)\id = #BT_ADWC

App(3)\name = "Faststone Image Viewer"
App(3)\url = U_FST
App(3)\info = "Accés : Page de téléchargement"+Chr(13)+Chr(13)+"Faststone Image Viewer est un visionneur d'images/photos légé et puissant, il permet en plus d'effectuer des opérations simples de recadrement, pivotement et diaporama..."
App(3)\id = #BT_Faststone

App(4)\name = "AIMP"
App(4)\url = U_AIMP
App(4)\info = "Accés : Page de téléchargement"+Chr(13)+Chr(13)+"AIMP est un excellent lecteur audio. Outre le fait de pouvoir le skinner, il lit un format très conséquent de sons (Flac, mod, xm...) et permet l'écoute de webradios."
App(4)\id = #BT_AIMP

App(5)\name = "Infra Recorder"
App(5)\url = U_INFRA
App(5)\info = "Accés : Page de téléchargement"+Chr(13)+Chr(13)+"Infra Recorder est un logiciel de gravure simple, efficace et libre."
App(5)\id = #BT_Infra

App(6)\name = "Environnement JAVA"
App(6)\url = U_JAVA
App(6)\info = "Accés : Page de téléchargement"+Chr(13)+Chr(13)+"JAVA est nécessaire au bon fonctionnement de certains programmes (libre office entre autre)."+Chr(13)+Chr(13)+"Attention ! Pendant l'installation il vous propose d'ajouter la barre d'outils ASK. Vous devez décocher cette installation si vous souhaitez ne pas être envahi de pubs."
App(6)\id = #BT_JAVA

App(7)\name = "Plugin Flash Player"
App(7)\url = U_FP
App(7)\info = "Accés : Page de téléchargement"+Chr(13)+Chr(13)+"Flash player est un plugin (greffon) pour vos navigateurs internet."+Chr(13)+Chr(13)+"Attention ! pensez à décocher l'offre facultative 'McAfee security scan plus' avant de cliquer sur télécharger."
App(7)\id = #BT_FlashP

App(8)\name = "Adobe Acrobat Reader"
App(8)\url = U_AR
App(8)\info = "Accés : Page de téléchargement"+Chr(13)+Chr(13)+"Acrobat Reader est LE lecteur de fichiers PDF le plus efficace."+Chr(13)+Chr(13)+"Attention ! Pensez à décocher l'offre facultative 'McAfee security scan plus' avant de cliquer sur télécharger."
App(8)\id = #BT_FlashR

App(9)\name = "Libre Office"
App(9)\url = U_LO
App(9)\info = "Accés : Page de téléchargement"+Chr(13)+Chr(13)+"Libre Office est la solution bureautique libre et gratuite ! Traitement de texte, tableur, logos et diaporamas. Tout y est."
App(9)\id = #BT_LOFF

App(10)\name = "VLC"
App(10)\url = U_VLC
App(10)\info = "Accés : Page de téléchargement"+Chr(13)+Chr(13)+"VLC est un lecteur vidéo autonome qui ne nécessite pas de 'codec tiers'. Il permet de lire un très grand nombre de formats. Il prend en compte les sous titres et les langues et permet aussi l'ecoute et la lecture de videos et chaines TV en ligne. Pour finir, c'est un logiciel libre."
App(10)\id = #BT_VLC

App(11)\name = "Bittorent Sync"
App(11)\url = U_BTS
App(11)\info = "Accés : Téléchargement directe"+Chr(13)+Chr(13)+"BTsync est un petit logiciel qui vous permet de synchroniser des dossiers automatiquement de PC à PC via internet. A contario de nombreux autres logiciels, celui ci ne passe pas par un serveur tiers (ce n'est pas du 'cloud' !). Encore en phase beta, il fonctionne très bien."
App(11)\id = #BT_BTSync

Procedure GetCurrentButton(window, FirstGad, LastGad)
  Protected currentbutton = -1
  For thisbutton = FirstGad To LastGad
    br.RECT
    br\left   =           GadgetX      ( thisbutton )
    br\top    =           GadgetY      ( thisbutton )
    br\right  = br\left + GadgetWidth  ( thisbutton )
    br\bottom = br\top  + GadgetHeight ( thisbutton )
    If WindowMouseX(window) >= br\left And WindowMouseX(window) <= br\right
      If WindowMouseY(window) >= br\top And WindowMouseY(window) <= br\bottom
        currentbutton = thisbutton
        Break
      EndIf
    EndIf
  Next
  ProcedureReturn currentbutton
EndProcedure 

; Create tooltip
Procedure GadgetBalloonToolTip(WindowNumber.l, GadgetNumber.l, Text.s)
  Protected Tooltip.l, Balloon.TOOLINFO
  Tooltip = CreateWindowEx_(0, "ToolTips_Class32", "", #WS_POPUP | #TTS_NOPREFIX | #TTS_BALLOON, 0, 0, 0, 0, WindowID(WindowNumber), 0, GetModuleHandle_(0), 0)
  SendMessage_(Tooltip, #TTM_SETTIPTEXTCOLOR, GetSysColor_(#COLOR_INFOTEXT), 0)
  SendMessage_(Tooltip, #TTM_SETTIPBKCOLOR, GetSysColor_(#COLOR_INFOBK), 0)
  SendMessage_(Tooltip, #TTM_SETMAXTIPWIDTH, 0, 180)
  Balloon\cbSize = SizeOf(TOOLINFO)
  Balloon\uFlags = #TTF_IDISHWND | #TTF_SUBCLASS
  If IsGadget(GadgetNumber)
    Balloon\hwnd = GadgetID(GadgetNumber)
    Balloon\uId = GadgetID(GadgetNumber)
  Else
    Balloon\hwnd = GadgetNumber
    Balloon\uId = GadgetNumber
  EndIf
  Balloon\lpszText = @Text
  SendMessage_(Tooltip, #TTM_ADDTOOL, 0, @Balloon)
  ProcedureReturn Tooltip
EndProcedure
; Change tooltip text
Procedure ChangeGadgetBalloonToolTip(Tooltip.l, GadgetNumber.l, Text.s)
  Protected Balloon.TOOLINFO
  Balloon\cbSize = SizeOf(TOOLINFO)
  Balloon\uFlags = #TTF_IDISHWND | #TTF_SUBCLASS
  If IsGadget(GadgetNumber)
    Balloon\hwnd = GadgetID(GadgetNumber)
    Balloon\uId = GadgetID(GadgetNumber)
  Else
    Balloon\hwnd = GadgetNumber
    Balloon\uId = GadgetNumber
  EndIf
  Balloon\lpszText = @Text
  SendMessage_(Tooltip, #TTM_ADDTOOL, 0, @Balloon)
EndProcedure
; Free tooltip
Procedure FreeBalloonTooltip(Tooltip.l)
  DestroyWindow_(Tooltip.l)
EndProcedure 
;

; Programme /////////////////////////////////////////////////////////

  hwnd = OpenWindow(#LDVM, 498, 278, 335, 349, "Easy Loader v1.0", #PB_Window_SystemMenu|#PB_Window_MinimizeGadget|#PB_Window_TitleBar)
     StickyWindow(#ldvm,1)
      ButtonGadget(#BT_FF, 5, 5, Lb, Hb, "Firefox", #BS_FLAT)
      BT_FF_TT = GadgetBalloonToolTip(#LDVM, #BT_FF, "Le Navigateur internet libre")
      ButtonGadget(#BT_MBAM, x2, 5, Lb, Hb, "MBAM", #BS_FLAT)
      BT_MBAM_TT = GadgetBalloonToolTip(#LDVM, #BT_MBAM, "Sécurité antimalware")
      ButtonGadget(#BT_ADWC, x2, 35, Lb, Hb, "ADW CLeaner", #BS_FLAT)
      BT_ADWC_TT = GadgetBalloonToolTip(#LDVM, #BT_ADWC, "Sécurité antimalware")
      ButtonGadget(#BT_Faststone, 5, 35, Lb, Hb, "Faststone Image Viewer", #BS_FLAT)
      BT_Faststone_TT = GadgetBalloonToolTip(#LDVM, #BT_Faststone, "Visionneuse d'image")
      ButtonGadget(#BT_AIMP, 5, 65, Lb, Hb, "AIMP", #BS_FLAT)
      BT_AIMP_TT = GadgetBalloonToolTip(#LDVM, #BT_AIMP, "Lecteur audio")
      ButtonGadget(#BT_Infra, 5, 95, Lb, Hb, "Infra Recorder", #BS_FLAT)
      BT_Infra_TT = GadgetBalloonToolTip(#LDVM, #BT_Infra, "Programme de Gravure")
      ButtonGadget(#BT_JAVA, x2, 155, Lb, Hb, "Java", #BS_FLAT)
      BT_JAVA_TT = GadgetBalloonToolTip(#LDVM, #BT_JAVA, "Machine virtuelle")
      ButtonGadget(#BT_FlashP, 5, 155, Lb, Hb, "Flash Player", #BS_FLAT)
      BT_FlashP_TT = GadgetBalloonToolTip(#LDVM, #BT_FlashP, "Plugin Flash")
      ButtonGadget(#BT_FlashR, x2, 125, Lb, Hb, "Acrobat Reader", #BS_FLAT)
      BT_FlashR_TT = GadgetBalloonToolTip(#LDVM, #BT_FlashR, "Lecteur PDF")
      ButtonGadget(#BT_LOFF, x2, 65, Lb, Hb, "Libre Office", #BS_FLAT)
      BT_LOFF_TT = GadgetBalloonToolTip(#LDVM, #BT_LOFF, "Suite bureautique libre")
      ButtonGadget(#BT_VLC, x2, 95, Lb, Hb, "VLC", #BS_FLAT)
      BT_VLC_TT = GadgetBalloonToolTip(#LDVM, #BT_VLC, "Lecteur Video Libre")
      ButtonGadget(#BT_BTSync, 5, 125, Lb, Hb, "Bittorent Sync", #BS_FLAT)
      BT_BTSync_TT = GadgetBalloonToolTip(#LDVM, #BT_BTSync, "Synchronisation de fichiers de PC à PC")
      EditorGadget(#info, 5, 185, 326, 160, #PB_Editor_ReadOnly|#PB_Editor_WordWrap)
      SetGadgetFont(#Info, FontID(#Font_EDIT)) 
      SetGadgetText(#info, info$)
	SetGadgetFont(#info, FontID(#Font_BT)) 


Repeat

; =========== Mouseover Button Section =================
  currentbutton = GetCurrentButton(#ldvm, #BT_FF, #BT_BTSync)
  If currentbutton <> oldButton
  	If currentbutton > -1 And currentbutton < 12
    	SetGadgetText(#info, app(currentbutton)\info)
    	oldButton = currentbutton
    Else
    	SetGadgetText(#info, info$)
    	oldButton = currentbutton
  	EndIf
  EndIf		
  ; ======== End Mouseover Button Section ================ 

Select WaitWindowEvent(20)

    Case #PB_Event_Gadget
      Select EventGadget()
        Case #BT_FF
     		GOsoft(U_FF)
        Case #BT_MBAM
        	GOsoft(U_MBAM)
        Case #BT_ADWC
        	GOsoft(U_ADWC)
        Case #BT_Faststone
        	GOsoft(U_FST)
        Case #BT_AIMP
        	GOsoft(U_AIMP)
        Case #BT_Infra
        	GOsoft(U_INFRA)
        Case #BT_JAVA
        	GOsoft(U_JAVA)
        Case #BT_FlashP
        	GOsoft(U_FP)
        Case #BT_FlashR
        	GOsoft(U_AR)
        Case #BT_LOFF
        	GOsoft(U_LO)
        Case #BT_VLC
        	GOsoft(U_VLC)
        Case #BT_BTSync
        	GOsoft(U_BTS)
        
      EndSelect
    ; ////////////////////////
    Case #PB_Event_CloseWindow
      Select EventWindow()
        Case #LDVM
          CloseWindow(#LDVM)
          FreeFont(#Font_BT)
          FreeFont(#Font_EDIT)
          Break
      EndSelect
  EndSelect
ForEver

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 0:23
par falsam
Sympa le loader. j'aime bien le résumé de l'application au survol de la souris. Merci :)

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 10:56
par Lemaquis
tu installe Bittorent chez tes clients :mrgreen:

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 14:31
par Ar-S
Lemaquis a écrit :tu installe Bittorent chez tes clients :mrgreen:
Bittorent Sync.... Renseigne toi un peu sur son utilité avant de troller. :wink:

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 14:46
par Lemaquis
tu as oublié de rajouté CCleaner

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 16:06
par Ar-S
Je n'ai rien oublié.. C'est la version 1.0.
Les autres versions vont s'organiser par thèmes. CCleaner en fera surement partie, tout comme team viewer et d'autres.
Là j'ai vraiment paré au plus fréquent (me concernant).

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 16:08
par falsam
Lemaquis a écrit :tu as oublié de rajouté CCleaner
Rien ne t’empêche de le rajouter :)

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 16:33
par Lemaquis
Ar-S a écrit :Je n'ai rien oublié.. C'est la version 1.0.
Les autres versions vont s'organiser par thèmes. CCleaner en fera surement partie, tout comme team viewer et d'autres.
Là j'ai vraiment paré au plus fréquent (me concernant).
Ok je comprend mieux

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 16:39
par raven
exellent ce petit loader,c'est bien pratique après une installation windows.

bon choix de logiciels,pour la personnalisation,on peut ajouter ce qu'on veut,les liens pour les pilotes nvidia/ati etc...

merci du partage ars :wink:

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 17:03
par MLD
Merci Ar-S

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 19:13
par Ar-S
De rien, si ça peu servir. Pas mal de monde se font leurrer par de faux sites pour récupérer ces softs et se retrouvent avec des merdes. (softonic et j'en passe). Pour les versions ultérieurs, je vais surement migrer les infos dans un fichier prefs crypté et ferait un autre soft dédié pour gérer les listes. ça évitera de compiler l'exe à chaque fois. J'ai pas de dates car de gros changements dans ma vie approchent. Je vais déménager dans le sud, avant cela on doit finir l'appart, le vendre etc... donc du pain sur la planche. Mais c'est fou comme PB me manque dès que je fais un break, même petit ;)

@raven bien vu pour les drivers je n'y avait pas pensé.

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 19:41
par raven
un loader pour gamer aussi peut etre sympas,genre(mumble,ts,skype,etc...)

se faire un loader mods pour( les jeux style skyrim)

on peut faire ce qu'on veut en faite :mrgreen:

Re: Easy Loader 1.0

Publié : ven. 22/août/2014 22:10
par Ar-S
Des softs du genre on déjà été fait si tu cherches bien.

Re: Easy Loader 1.3

Publié : mer. 27/mai/2015 17:49
par Ar-S
VERSION 1.3
Passage aux combos Box
Ajout des principaux constructeurs pour récupérer les pilotes facilement.

Re: Easy Loader 1.3

Publié : mer. 27/mai/2015 18:47
par Micheao
Un grand merci Ar-S de ce partage
Fuseau horaire sur UTC+01:00
Page 1 sur 2

Développé par phpBB® Forum Software © phpBB Limited

Traduction française officielle © Qiaeru