PureBasic

Code : Tout sélectionner

;Fonctionalités 5.10b1

;StrF()
Debug StrF(8.0)   ; 8   '.0' supprimé, pas de décimales spécifiées
Debug StrF(8.0,1) ; 8.0  rien d'enlevé, 1 décimale spécifiée

;===========================
;ReAllocateMemory()
#Taille = 65536
#DemiTaille = #Taille / 2
#DoubleTaille = #Taille * 2
#n = 100000


time = ElapsedMilliseconds()
For i = 0 To #n-1
	*mem = AllocateMemory(#Taille)
	;*mem = ReAllocateMemory(*mem, #DemiTaille)
	*mem = ReAllocateMemory(*mem, #DoubleTaille)
	FreeMemory(*mem)
Next
time1 = ElapsedMilliseconds() - time


time = ElapsedMilliseconds()
For i = 0 To #n-1
	*mem = AllocateMemory(#Taille)
	;*mem = ReAllocateMemory(*mem, #DemiTaille, #PB_Memory_NoClear)
	*mem = ReAllocateMemory(*mem, #DoubleTaille, #PB_Memory_NoClear)
	FreeMemory(*mem)
Next
time2 = ElapsedMilliseconds() - time


MessageRequester("Info", Str(time1) + "/" + Str(time2))

;===========================
;Nouvelles fonctions
Debug "Nom Ordinateur: "+ComputerName()
Debug "Nom Utilisateur: "+UserName()
Debug "Memoire physique: "+Str(MemoryStatus(0))
Debug "Mémoire disponible: "+Str(MemoryStatus(1))
Debug "Nombre de processeurs: "+Str(CountCPUs())

;==============================
;MacroExpandedCount
Macro CallCount()
	Debug MacroExpandedCount
	CompilerIf MacroExpandedCount = 2
		Debug "Version étendue"
	CompilerEndIf
EndMacro

CallCount()

CallCount()

CallCount()

;=======================
;TypeOf()
Structure Test
  a.a
EndStructure

a.Test
If TypeOf(a\a) = #PB_Ascii
  Debug "La structure est de type ascii"
EndIf
;====================
;UndefineMacro
Macro test
  Debug "1"
EndMacro

test

UndefineMacro test

Macro test
  Debug "2"
EndMacro

test
;=============================

;PostEvent()
Enumeration
	#maFenetre = 0
	#Bouton_1 = 0
	#Bouton_2
EndEnumeration

OpenWindow(#maFenetre, 0, 0, 150, 100, "Test", #PB_Window_SystemMenu)

ButtonGadget(#Bouton_1, 25, 20, 100, 20, "Basculer Bouton 2")
ButtonGadget(#Bouton_2, 25, 60, 100, 20, "Bouton 2", #PB_Button_Toggle)

Repeat
	event = WaitWindowEvent(10)
	Select event
		Case #PB_Event_CloseWindow
			CloseWindow(#maFenetre)
			End
		Case #PB_Event_Gadget
			
			Select EventGadget()
				Case #Bouton_1
					; PostEvent(Type, Window, Object, Type)
					PostEvent(#PB_Event_Gadget, #maFenetre, #Bouton_2, #PB_EventType_LeftClick) ;??? Ceci ne marche pas.
				Case #Bouton_2
					Select EventType()
						Case #PB_EventType_LeftClick
							Debug "Vous avez envoyé un clic gauche"
					EndSelect
			EndSelect
	EndSelect
	
ForEver