PureBasic

Code : Tout sélectionner

; Print WebGadget
; OS : Window

EnableExplicit

Enumeration
  #MainForm
  #Webgadget
  #Preview
  #Print
EndEnumeration

#PWB_PROMPTUSER  = 1   
#PWB_NOPROMPTUSER = 2
#PWB_PRINT = 6
#PWB_PREVIEW = 7

Procedure PrintWebGadget (WebgadgetID, Arg1, Arg2)
  Protected WebObject.IWebBrowser2 = GetWindowLong_(GadgetID(WebgadgetID), #GWL_USERDATA)
  WebObject\ExecWB(Arg1, Arg2, 0, 0)
EndProcedure

OpenWindow(#MainForm, 0,0,800, 600, "Print Webgadget", #PB_Window_ScreenCentered | #PB_Window_SystemMenu)
WebGadget(#Webgadget, 5, 5, 790, 500, "www.purebasic.fr")
ButtonGadget(#Preview, 5, 550, 80, 30, "Preview")
ButtonGadget(#Print, 90, 550, 80, 30, "Print")

Repeat
  Select WaitWindowEvent(50)
    Case #PB_Event_Gadget
      Select EventGadget()
        Case #Preview
          PrintWebGadget(#Webgadget, #PWB_PREVIEW, #PWB_PROMPTUSER)
          
        Case #Print
          PrintWebGadget(#Webgadget, #PWB_PRINT, #PWB_NOPROMPTUSER)
      EndSelect
            
    Case #PB_Event_CloseWindow
      End
      
  EndSelect
ForEver