PureBasic

Code : Tout sélectionner

Structure int64 
  Long1.l 
  Long2.l 
EndStructure 

drive$ = "c:\" 

SetErrorMode_(#SEM_FAILCRITICALERRORS) 
                                        
If GetDiskFreeSpaceEx_(@drive$, BytesFreeToCaller.int64, TotalBytes.int64, TotalFreeBytes.int64) = 0 
  MessageRequester("","Unité non prête!",0) 
  End 
EndIf 

; initailisation de l'erreur msg
SetErrorMode_(0) 

; calcul de la taille en Mb
TotalMB = ((TotalBytes\Long1 >> 20) & $FFF) | (TotalBytes\Long2 << 12) 
FreeMB = ((TotalFreeBytes\Long1 >> 20) & $FFF) | (TotalFreeBytes\Long2 << 12) 

Debug "Disk: "+drive$ 
Debug "Taille totale: "+Str(TotalMB)+" Mb" 
Debug "Espace libre:"+Str(FreeMB)+" Mb" 

End

Code : Tout sélectionner

;Pour la taille d'un répertoire, il suffit de calculer la différence
;entre la taille de ton fichier et la taille du répertoire destinataire
;(que tu connaitras grâce à cette procédure ci-dessous), sinon il faudra 
;créer une fonction qui le ferait en jumulant les deux... 

Procedure.l DirectorySize(ID.l, Directory.s) 
  Protected Size.l 
  If ExamineDirectory(ID, Directory, "*.*") 
    Repeat 
      Entry.l = NextDirectoryEntry() 
      If Entry = 1 
        Size + DirectoryEntrySize() 
      ElseIf Entry = 2 
        Name.s = DirectoryEntryName() 
        If Name <> ".." And Name <> "." 
          Size + DirectorySize(ID+1, Directory+Name+"\") 
          UseDirectory(ID) 
        EndIf 
      EndIf 
    Until Entry = 0 
  EndIf 
  ProcedureReturn Size 
EndProcedure 

;test
Debug DirectorySize(0, "C:\purebasic\") 

END

Code : Tout sélectionner

; Auteur : Le Soldat Inconnu
; Version de PB : 4
;
; Explication du programme :
; Obtenir l'espace libre ou la taille d'un lecteur, ou afficher l'espace libre ou la taille d'un lecteur (unité et précision personnalisable)


Procedure.q GetDiskFreeSpace(Lecteur.s, Type.l = 0)
  ; lecteur = nom du lecteur
  ; type = choix de la réponse, 0 = espace libre sur le lecteur, 1 = taille du lecteur
  
  Protected EspaceLibre.q,  Taille.q, resultat.q

  GetDiskFreeSpaceEx_(Lecteur, @EspaceLibre, @Taille, 0)
  
  Select Type
    Case 0 : resultat = EspaceLibre
    Case 1 : resultat = Taille
  EndSelect
  
  ProcedureReturn resultat
EndProcedure

Procedure.s DisplayDiskFreeSpace(Taille.q, Unite.l = -1, NbDecimals.l = -1)
  ; Taille = taille du lecteur
  ; Unite = unité de la taille, 0 = Octet, 1 = Ko, 2 = Mo, 3 = Go. Si = -1, Le choix de l'unité et du nombre de décimal sera automatique
  ; NbDecimals = nombre de chiffre après la virgule.
  
  Protected Val.q, Txt.s
  
  If Unite = -1
    NbDecimals = 0 : Unite = 0
    If Taille >= 1000 : Unite = 1 : NbDecimals = 2 : EndIf
    If Taille >= 10000 : Unite = 1 : NbDecimals = 1 : EndIf
    If Taille >= 1000000 : Unite = 2 : NbDecimals = 2 : EndIf
    If Taille >= 10000000 : Unite = 2 : NbDecimals = 1 : EndIf
    If Taille >= 1000000000 : Unite = 3 : NbDecimals = 2 : EndIf
    If Taille >= 10000000000: Unite = 3 : NbDecimals = 1 : EndIf
  EndIf
  Select Unite
    Case 0 : Val = 1 : Txt = " octets"
    Case 1 : Val = 1024 : Txt = " Ko"
    Case 2 : Val = 1024 * 1024 : Txt = " Mo"
    Case 3 : Val = 1024 * 1024 * 1024 : Txt = " Go"
  EndSelect
  ProcedureReturn StrF(Taille / Val, NbDecimals) + Txt
  
EndProcedure


;- Test
Debug GetDiskFreeSpace("c:\program files\", 1)
Debug DisplayDiskFreeSpace(GetDiskFreeSpace("c:\program files\", 1))