Charger des sprites.
Un petit topo suite à ce que j'ai lu sur le chat de PureBasic.
Charger des sprites avec SpiderBasic ne se fait pas de la même manière qu'avec PureBasic.
Quand vous compilez avec SpiderBasic, vous obtenez un script en JavaScript qui sera interpréter par votre navigateur.
Votre navigateur a besoin de savoir quand un élément est chargé et si il y a des erreurs.
Les événements
#PB_Event_Loading et #
PB_Event_LoadingError sont là pour vous aider.
Chacun de ces deux événements sera associé à une procédure.
Code : Tout sélectionner
BindEvent(#PB_Event_Loading, @Loading())
BindEvent(#PB_Event_LoadingError, @LoadingError())
SpiderBasic utilise le framework
pixi.js pour le rendu 2D.
pixi.js a besoin de connaitre le nom de la procédure de rendering. Si le nom de votre procédure est par exemple RenderFrame alors le code sera celui-çi
Le code généré étant du JavaScript, l'interprétation du code sera effectuée de haut en bas. Les variables globales doivent être déclarées au début du code.
■
Exemple.
On va faire simple : Nous allons afficher un background et une balle.
Code : Tout sélectionner
Declare Loading(Type, Filename$)
Declare LoadingError(Type, Filename$)
Declare RenderFrame()
;La génération de ce code sera du JavaScript
;JavaScript est interprété par le navigateur
;Le navigateur a besoin de savoir quand un elément est chargé et si il y a des erreurs
BindEvent(#PB_Event_Loading, @Loading())
BindEvent(#PB_Event_LoadingError, @LoadingError())
;Ici un déclencheur necessaire au moteur de rendu pixi.js
BindEvent(#PB_Event_RenderFrame, @RenderFrame())
;On commence par ouvrir un screen
OpenScreen(800, 600, 32, "Test Sprites")
;On charge les sprites : A chaque LoasSprite l'évenement #PB_Event_Loading sera déclenché
Global background = LoadSprite(#PB_Any, "assets/images/blur1.jpg")
Global ball = LoadSprite(#PB_Any, "assets/images/ball.png")
;Chaque sprite chargé fera appel à cette procédure
Procedure Loading(Type, Filename$)
;Un compteur pour chaque élément chargé
Static NbLoadedElements
NbLoadedElements+1
If NbLoadedElements = 2
;Les deux sprites sont chargés
;On va pouvoir procéder à la manipulation des sprites si necessaire
ZoomSprite(background, 800, 600)
;Rappelez vous de BindEvent(#PB_Event_RenderFrame, @RenderFrame())
;FlipBuffers va déclencher le render
FlipBuffers()
EndIf
EndProcedure
;En cas d'erreur de chargement de sprite, c'est cette procédure qui va être appeler
Procedure LoadingError(Type, Filename$)
Debug Filename$ + ": loading error"
EndProcedure
;Le rendu visuel est ici
Procedure RenderFrame()
DisplayTransparentSprite(background, 0, 0)
DisplaySprite(ball, 400, 300)
;Appel recursif à la procédure RenderFrame
FlipBuffers()
EndProcedure
■
Reflexe
Clear du cache navigateur avec Ctrl + F5 aprés avoir relancer l'exécution de votre code.
Votre code ne fonctionne pas ? Il n'y a rien dans la fenêtre de debug ? pensez à regarder la console de votre navigateur (
Chrome / Firefox /Edge : Touche F12 Onglet console)
■
Téléchargement.
http://falsam.com/download/spiderbasic/openscreen.zip (Source + Images)
à droite du pseudo, ce qui est en effet pratique
. We needed to rework a lot of things to switch to cordova for Android on Windows, but it will brings some nice new features ! Keep tuned