PureBasic

Code : Tout sélectionner

; Auteur : Le Soldat Inconnu
; Version de PB : 3.92
; 
; Explication du programme :
; Faire un test entre chaque valeur d'une liste chainée
; cette exemple s'appuie sur des balles en position X Y, le test qui n'est pas représenté ici est une collision

Structure InfoBalle
  x.l
  y.l
  ; etc ....
EndStructure

NewList Balle.InfoBalle()

NbBalles = 4

; On ajoute #NbBalles balles
For n = 1 To NbBalles
  AddElement(Balle())
  Balle()\x = n
  Balle()\y = n
Next

PosListeBalle1 = -1
ResetList(Balle())
; Boucle 1
While NextElement(Balle()) ; On passe à l'élément suivant
  PosListeBalle1 + 1 ; On compte pour connaître le numéro de l'élément
  *BalleTemp.InfoBalle = @Balle() ; On récupère l'élément courant de la boucle 1
  
  PosListeBalle2 = -1
  ResetList(Balle())
   ; Boucle 2
  While NextElement(Balle()) ; On passe à l'élément suivant
    PosListeBalle2 + 1 ; On compte pour connaître le numéro de l'élément
    
    ; On compare la balle à la position PosListeBalle1 dans la boucle 1 avec celle à la position PosListeBalle2 dans la boucle 2
    If PosListeBalle1 <> PosListeBalle2 ; Ce test sert à éviter d'avoir le test sur la même balle
      Debug Str(*BalleTemp\x) + ", " + Str(*BalleTemp\y) + " / " + Str(Balle()\x) + ", " + Str(Balle()\y) 
    EndIf
    
  Wend
  ChangeCurrentElement(Balle(), *BalleTemp) ; On remet l'élément courant de la boucle 1
Wend



;- Test de rapidité

ClearList(Balle())
NbBalles = 10000

; On ajoute NbBalles balles
For n = 1 To NbBalles
  AddElement(Balle())
  Balle()\x = n
  Balle()\y = n
Next

Temps1 = GetTickCount_()

PosListeBalle1 = -1
ResetList(Balle())
While NextElement(Balle())
  PosListeBalle1 + 1
  *BalleTemp.InfoBalle = @Balle()
  
  PosListeBalle2 = -1
  ResetList(Balle())
  While NextElement(Balle())
    PosListeBalle2 + 1
    If PosListeBalle1 <> PosListeBalle2
      Debug Str(*BalleTemp\x) + ", " + Str(*BalleTemp\y) + " / " + Str(Balle()\x) + ", " + Str(Balle()\y) 
    EndIf
  Wend
  ChangeCurrentElement(Balle(), *BalleTemp)
Wend

Temps2 = GetTickCount_()

ResetList(Balle())
While NextElement(Balle())
  PosListeBalle = ListIndex(Balle())
  *BalleTemp.InfoBalle = @Balle()
  
  ResetList(Balle())
  While NextElement(Balle())
    If PosListeBalle <> ListIndex(Balle())
      Debug Str(*BalleTemp\x) + ", " + Str(*BalleTemp\y) + " / " + Str(Balle()\x) + ", " + Str(Balle()\y) 
    EndIf
  Wend
  SelectElement(Balle(), PosListeBalle)
Wend

Temps3 = GetTickCount_()

; On teste avec un tableau
; d'abord, on recopie les données dans un tableau pour travailler sur le même échantillon
Dim TableauBalle.InfoBalle(NbBalles - 1)
ResetList(Balle())
For n = 0 To NbBalles - 1
  NextElement(Balle())
  TableauBalle(n)\x = Balle()\x
  TableauBalle(n)\y = Balle()\y
Next

Temps4 = GetTickCount_()

For n = 0 To NbBalles - 1
  For nn = 0 To NbBalles - 1
    If n <> nn
      Debug Str(TableauBalle(n)\x) + ", " + Str(TableauBalle(n)\y) + " / " + Str(TableauBalle(nn)\x) + ", " + Str(TableauBalle(nn)\y) 
    EndIf
  Next
Next

Temps5 = GetTickCount_()

MessageRequester("Rapidité", "Méthode 1 = " + Str(Temps2 - Temps1) + Chr(10) + "Méthode 2 = " + Str(Temps3 - Temps2) + Chr(10) + "Méthode 3 (Tableau) = " + Str(Temps5 - Temps4), 0)