PureBasic

Code : Tout sélectionner

Enumeration
  #MainForm
EndEnumeration

Structure Sprite 
  Sprite.i      
  
  x.i           
  y.i           
    
  Animation.i   
  CurrentFrame.i
  
  FrameWidth.i  
  FrameHeight.i 
  FrameMax.i    
  
  FrameRate.i   
  FrameTimeLife.i
EndStructure 

Global MaxBirds=150, Dim Bird.Sprite(MaxBirds), RowAnim = 0

Procedure GamePreload()
  UsePNGImageDecoder()
  
  ;Init birds
  For n=0 To MaxBirds
    With Bird(n)
      \Sprite = LoadSprite(#PB_Any, "bird.png", #PB_Sprite_AlphaBlending)
      \x = Random(1024, 0)
      \y = Random(600, 0)
      \Animation = RowAnim
      \CurrentFrame=0
      \FrameMax = 4
      \FrameWidth = 64
      \FrameHeight = 64
      \FrameTimeLife = ElapsedMilliseconds()
      \FrameRate = Random(130, 50)
    EndWith
  Next
EndProcedure

Procedure GameUpdate()
  For n=0 To MaxBirds
    With Bird(n)
      ClipSprite(\Sprite, \CurrentFrame * \FrameWidth, \Animation * \FrameHeight, \FrameWidth, \FrameHeight)
      DisplayTransparentSprite(\Sprite, \x, \y, 255)
      If ElapsedMilliseconds()-\FrameTimeLife > \FrameRate
        \FrameTimeLife = ElapsedMilliseconds()
        If \CurrentFrame < \FrameMax-1
          \CurrentFrame+1     
        Else
          \CurrentFrame=0  
        EndIf      
      EndIf  
    EndWith
  Next
EndProcedure

Procedure GameStart()
  
  If InitSprite() = 0 Or InitKeyboard() = 0 Or InitMouse() = 0
    MessageRequester("Error", "Sprite system can't be initialized", 0)
    End
  EndIf  
  
  If OpenWindow(#mainform, 0, 0, 800, 600, "Bug Sprite", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)
    If OpenWindowedScreen(WindowID(#mainform), 0, 0, 800, 600)
      GamePreload()
    EndIf
  EndIf
  
  Repeat  
    Repeat
      Event = WindowEvent()
     
      Select event    
        Case #PB_Event_CloseWindow
          End
      EndSelect  
    Until event=0
    
    FlipBuffers()
    ClearScreen(RGB(0,0,0))
                
    ExamineKeyboard()
    ExamineMouse()
    GameUpdate()
  
  Until KeyboardPushed(#PB_Key_Escape)
EndProcedure

GameStart()