PureBasic

Code : Tout sélectionner

UseJPEGImageDecoder()
UsePNGImageDecoder()

Enumeration
	
	#Ouvrir = 0
	#Fermer
	#Quitter
	#FenetreAjustementAuto
	
	#Image = 0
	#ImageAjuster
	
EndEnumeration

Procedure ReduireImage(Ecran_X, Ecran_Y)
	CopyImage(#Image, #ImageAjuster)
	If ImageHeight(#Image) > Ecran_Y Or ImageWidth(#Image) > Ecran_X
		If Ecran_X * ImageHeight(#Image) <= ImageWidth(#Image) * Ecran_Y
			ResizeImage(#ImageAjuster, Ecran_X, ImageHeight(#Image) * Ecran_X / ImageWidth(#Image), #PB_Image_Smooth)
		Else
			ResizeImage(#ImageAjuster, ImageWidth(#Image) * Ecran_Y / ImageHeight(#Image), Ecran_Y, #PB_Image_Smooth)
		EndIf
	EndIf
EndProcedure

Procedure ChangementDimension()
	Protected Ecran_Quantite, Fenetre.rect, Fenetre_Bordure_H, Fenetre_Bordure_L, Fenetre_Centre_X, Fenetre_Centre_Y, Fenetre_H, Fenetre_L
	
	; Dimension de la fenêtre
	GetWindowRect_(WindowID(0), Fenetre.rect)
	Fenetre_Centre_X = Fenetre\left + (Fenetre\right - Fenetre\left) / 2
	Fenetre_Centre_Y = Fenetre\top + (Fenetre\bottom - Fenetre\top) / 2
	Fenetre_H = WindowHeight(0) - MenuHeight() - StatusBarHeight(0)
	Fenetre_L = WindowWidth(0)
	Fenetre_Bordure_H = (Fenetre\bottom - Fenetre\top) - Fenetre_H
	Fenetre_Bordure_L = (Fenetre\right - Fenetre\left) - Fenetre_L
	
	; Position de la fenêtre
	Ecran_Quantite = ExamineDesktops()
	Ecran_Cible = 0
	For Ecran = 0 To Ecran_Quantite - 1
		If Fenetre_Centre_X >= DesktopX(Ecran) And Fenetre_Centre_X < DesktopX(0) + DesktopWidth(0) And Fenetre_Centre_Y >= DesktopY(Ecran) And Fenetre_Centre_Y < DesktopY(0) + DesktopHeight(0)
			Ecran_Cible = Ecran
		EndIf
	Next
	
	If IsImage(#Image)
		Image_H = ImageHeight(#Image)
		Image_L = ImageWidth(#Image)
		If Image_H < 40
			Image_H = 40
		EndIf
		If Image_L < 300
			Image_L= 300
		EndIf
	Else
		Image_H = 40
		Image_L = 300
	EndIf
	
	; Détermine si il faut maximiser la fenêtre
	If Image_L + 128 >= DesktopWidth(Ecran_Cible) - Fenetre_Bordure_L Or Image_H + 128 >= DesktopHeight(Ecran_Cible) - Fenetre_Bordure_H
		If GetWindowState(0) <> #PB_Window_Maximize
			SetWindowState(0, #PB_Window_Maximize)
			ChangementDimension()
			ProcedureReturn
		EndIf
	Else
		If GetWindowState(0) = #PB_Window_Maximize
			SetWindowState(0, #PB_Window_Normal)
			ChangementDimension()
			ProcedureReturn
		EndIf
	EndIf
	
	If GetWindowState(0) = #PB_Window_Normal
		x = WindowX(0) + (Fenetre_L - Image_L) / 2
		y = WindowY(0) + (Fenetre_H - Image_H) / 2
		If x < DesktopX(Ecran_Cible)
			x = DesktopX(Ecran_Cible)
		EndIf
		If y < DesktopY(Ecran_Cible)
			y = DesktopY(Ecran_Cible)
		EndIf
		ResizeWindow(0, x, y, Image_L, Image_H + MenuHeight() + StatusBarHeight(0))
	EndIf
	
EndProcedure

Procedure Dimension()
	Protected Fenetre_H, Fenetre_L
	
	; Dimension de la fenêtre
	Fenetre_H = WindowHeight(0) - MenuHeight() - StatusBarHeight(0)
	Fenetre_L = WindowWidth(0)
	
	If IsImage(#Image)
		ReduireImage(Fenetre_L, Fenetre_H)
		If IsGadget(#Image) = 0
			ImageGadget(#Image, (Fenetre_L - ImageWidth(#ImageAjuster)) / 2, (Fenetre_H - ImageHeight(#ImageAjuster)) / 2, ImageWidth(#ImageAjuster), ImageHeight(#ImageAjuster), ImageID(#ImageAjuster))
		Else
			ResizeGadget(#Image, (Fenetre_L - ImageWidth(#ImageAjuster)) / 2, (Fenetre_H - ImageHeight(#ImageAjuster)) / 2, ImageWidth(#ImageAjuster), ImageHeight(#ImageAjuster))
			SetGadgetState(#Image, ImageID(#ImageAjuster))
		EndIf
	EndIf
	
EndProcedure

Procedure Image_Fermer(OuvertureImage = 0)
	If IsImage(#Image)
		If IsGadget(#Image)
			FreeGadget(#Image)
		EndIf
		FreeImage(#Image)
		If IsImage(#ImageAjuster)
			FreeImage(#ImageAjuster)
		EndIf
	EndIf
	If OuvertureImage = 0
		ChangementDimension()
		Dimension()
		StatusBarText(0, 1, "", #PB_StatusBar_Center)
		StatusBarText(0, 0, "")
	EndIf
EndProcedure
Procedure Image_Ouvrir()
	Protected Image.i, Image_Fichier.s
	Image_Fichier = OpenFileRequester("Image", "", "Image BMP, JPG, PNG|*.bmp;*.jpg;*.png|Tous les fichiers|*.*", 0)
	If Image_Fichier
		If FileSize(Image_Fichier) >= 0
			Image = LoadImage(#PB_Any, Image_Fichier)
			If Image
				Image_Fermer(1)
				CopyImage(Image, #Image)
				FreeImage(Image)
				ChangementDimension()
				Dimension()
				StatusBarText(0, 1, Str(ImageWidth(#Image)) + " x " + Str(ImageWidth(#Image)), #PB_StatusBar_Center)
				StatusBarText(0, 0, GetFilePart(Image_Fichier))
			Else
				MessageRequester("Image", "Le format du fichier n'est pas reconnu")
			EndIf
		Else
			MessageRequester("Image", "Le fichier est introuvable")
		EndIf
	EndIf
EndProcedure

If OpenWindow(0, 0, 0, 300, 40, "Ouvrir une image", #PB_Window_MaximizeGadget | #PB_Window_MinimizeGadget | #PB_Window_ScreenCentered | #PB_Window_SizeGadget | #PB_Window_SystemMenu) = 0
	End
EndIf

If CreateMenu(0, WindowID(0))
	MenuTitle("Programme")
	MenuItem(#Quitter, "Quitter")
	MenuTitle("Image")
	MenuItem(#Ouvrir, "Ouvrir")
	MenuItem(#Fermer, "Fermer")
	MenuTitle("Fenêtre")
	MenuItem(#FenetreAjustementAuto, "Ajustement automatique de la fenêtre à l'image")
Else
	End
EndIf

If CreateStatusBar(0, WindowID(0))
	AddStatusBarField(#PB_Ignore)
	AddStatusBarField(160)
Else
	End
EndIf

WindowBounds(0, 300, 40 + MenuHeight() + StatusBarHeight(0), #PB_Ignore, #PB_Ignore)
ChangementDimension()
Dimension()

Repeat
	Event = WaitWindowEvent()
	Select Event
		Case #PB_Event_SizeWindow
			Dimension()
		Case #PB_Event_Menu
			Select EventMenu()
				Case #Ouvrir
					Image_Ouvrir()
				Case #Fermer
					Image_Fermer()
			EndSelect
	EndSelect
Until Event = #PB_Event_CloseWindow