PureBasic

Code : Tout sélectionner

; German forum: http://www.purebasic.fr/german/viewtopic.php?t=2887&highlight=
; Author: DarkDragon (based on code by Rings, extended by Andre)
; Date: 09. April 2005
; OS: Windows
; Demo: No
; Get the color under the mouse cursor
; Farbe des Punktes unter dem Mauscursor ermitteln
Declare  OpenWindow_Win()
Declare  GetColorUnderMouse()

;{- Enumerations / DataSections
;{ Windows
Enumeration
	#Win
EndEnumeration
;}
;{ Gadgets
Enumeration
	#Text_titre
	#Image
	#Editor
	#timer
EndEnumeration
;}
;{ Fonts
Enumeration
	#Font_Text_titre
EndEnumeration
;}
Define.l Event
;}
Global flag_timer=0
CreateImage(#image,83, 54,32)
OpenWindow_Win()

;{- Event loop
Repeat
	Event = WaitWindowEvent(2)
	Select Event
		Case #PB_Event_Timer 
		if EventTimer() = #timer
			Color.l = GetColorUnderMouse()
			if Color.l<>mem_color.l
				ClearGadgetItems(#Editor)
				AddGadgetItem(#Editor, -1, "Color:" +str(Color))
				AddGadgetItem(#Editor, -1, "Color in Hex :" +Hex(Color))
				AddGadgetItem(#Editor, -1, "Rouge:" +str(Red(Color)))
				AddGadgetItem(#Editor, -1, "Vert:" +str(green(Color)))
				AddGadgetItem(#Editor, -1, "Bleu:" +str(blue(Color)))
				StartDrawing(ImageOutput(#image))
					box(1,1,83, 54,color.l)
				StopDrawing()
				SetGadgetState(#image,ImageId(#image))
				mem_color.l=Color.l
				;SetClipboardText(GetGadgetText(#Editor))
			Endif
		Endif
		; ///////////////////
		Case #PB_Event_Gadget
		Select EventGadget()
			Case #Text_titre
			Case #Image
			Case #Editor
		EndSelect
		; ////////////////////////
		Case #PB_Event_CloseWindow
		Select EventWindow()
			Case #Win
			CloseWindow(#Win)
			Break
		EndSelect
	EndSelect
Forever
;

;}
Procedure OpenWindow_Win()
	If OpenWindow(#Win, 589, 123, 400, 168, "Couleur Graber", #PB_Window_SystemMenu|#PB_Window_SizeGadget|#PB_Window_MinimizeGadget|#PB_Window_TitleBar)
		StickyWindow(#win,1)
		AddWindowTimer( #Win, #timer, 200)
		TextGadget(#Text_titre, 75, 7, 128, 32, "Couleur graber")
		ImageGadget(#Image, 15, 43, 83, 54, ImageId(#image), #PB_Image_Border)
		EditorGadget(#Editor, 116, 44, 250, 108, #PB_Editor_ReadOnly)
		SetGadgetColor(#Editor, #PB_Gadget_BackColor , $0 )
		SetGadgetColor(#Editor, #PB_Gadget_FrontColor , rgb(0,200,0) )
		; Gadget Fonts
		SetGadgetFont(#Text_titre, LoadFont(#Font_Text_titre, "Comic Sans MS", 10, #PB_Font_Bold|#PB_Font_HighQuality))
	EndIf
EndProcedure
Procedure GetColorUnderMouse() 
	GetCursorPos_(@CursorPos.POINT ) 
	hdc = GetDC_(0) 
	If hdc <> 0 
		Color = GetPixel_(hdc,CursorPos\x,CursorPos\y) 
		ReleaseDC_(0, hdc) 
		ProcedureReturn Color 
	EndIf 
EndProcedure 

; Epb