Purebasic et concepts de POO

Vous avez une idée pour améliorer ou modifier PureBasic ? N'hésitez pas à la proposer.
Avatar de l’utilisateur
omega
Messages : 617
Inscription : sam. 26/nov./2011 13:04
Localisation : Alger

Re: Purebasic et concepts de POO

Message par omega »

Ben oui banane ^-^tu n'es pas ingénieur
Je ne crois pas que ce soit une affaire de diplôme, cela relève d'un spécialiste en Pb+C+ASM, quelqu'un qui maitrise parfaitement ces 3 précieux outils pourrait peut être faire quelque chose mais le meilleur ingénieur du monde ne pourra rien faire s'il ne connait rien de ces 3 langages. En plus, je ne crois pas qu'il y a un ingénieur aujourd'hui spécialisé en Pb, car la plupart des langages actuels abordés au niveau des universités sont surtout Java et C++. Même Python qui semble grimper au début de la liste des langages préférés au niveau mondial n'est pas enseigné au niveau de la plupart des universités (sauf aux USA ou en Asie où j'ignore totalement leurs programmes universitaires)...
Ne doutant pas de la compétence confirmée de la plupart d'entre vous, je suis sûr qu'il y aura quelqu'un parmi l'équipe qui trouvera la solution...à savoir (pourquoi pas) faire un pré compilateur qui transformerait un code Objet en code Pb....
Win7 (x64) 64 bits Pb 5.72
Avatar de l’utilisateur
microdevweb
Messages : 1798
Inscription : mer. 29/juin/2011 14:11
Localisation : Belgique

Re: Purebasic et concepts de POO

Message par microdevweb »

Petite remise en place.

Il ne s'agit absolument pas de refaire le compilateur de Pb qui est je pense très performant. Il s'agit juste de créer de nouvelles commandes qui faciliteraient l'approche Poo.

Nulle besoin de connaitre l'asm puisque nous n'en taperons pas une ligne. Et nulle besoin d'être ingénieur ce que je pense peux de nous sommes.

Il s'agit simplement de traduire une commande en instruction Pb, ce qui est à l’instar de Pb qui traduit les instructions en Asm.

D'ailleurs j'ai parlé de pré compilateur et non de compilateur, maintenant cela reste une tache ardue et qui même si elle est à la portée de beaucoup reste difficile, car le fonctionnement est très similaire à un compilateur.

Le teste que j'avais fais était fonctionnel mais pas assez performant à mon gout et moi je sais reconnaître mes limites et je sais par exemple que je suis incapable de concevoir l'architecture d'un cpu ou même de concevoir ses instructions machine.

Au même titre je suis incapable de concevoir ou de réaliser un langage comme Pb,C,C++ ou Java mais me débrouille en toutes modestie à leurs utilisation.

Et dans le cas contraire je ne pense pas que je serais sur ce forum à demander des fois comment faire tel ou tel chose.

On peut être pilote de course et ne pas s'avoir créer une moteur.

Remarque: Dans mon école le premier langage à apprendre était le Python, personnellement je ne raffole pas de ce langage car il n'est pas typé et je me suis habitué au langage plutôt typé. Maintenant plus on connait de langages et mieux c'est. Mais quelque que soit le langage choisi la logique restera presque toujours la même.
Dernière modification par microdevweb le dim. 19/août/2018 20:15, modifié 1 fois.
Windows 10 64 bits PB: 5.70 ; 5.72 LST
Work at Centre Spatial de Liège
Avatar de l’utilisateur
Kwai chang caine
Messages : 6962
Inscription : sam. 23/sept./2006 18:32
Localisation : Isere

Re: Purebasic et concepts de POO

Message par Kwai chang caine »

Donc en fin de compte un traducteur ?
Comme si on essayait de traduire PB en C, ou inversement, le français en anglais etc .. ?
Mais alors est il besoin de s'y connaitre en pointeurs ?
Peut être qu'une maitrise en POO d'un langage quelconque (Java, C++, etc ..) et en PB suffirait ?
ImageLe bonheur est une route...
Pas une destination

PureBasic Forum Officiel - Site PureBasic
poshu
Messages : 1138
Inscription : sam. 31/juil./2004 22:32

Re: Purebasic et concepts de POO

Message par poshu »

Kwai chang caine a écrit :je suis cartésien
J'ai jamais autant ri de ma vie.
Avatar de l’utilisateur
omega
Messages : 617
Inscription : sam. 26/nov./2011 13:04
Localisation : Alger

Re: Purebasic et concepts de POO

Message par omega »

D'ailleurs j'ai parlé de pré compilateur et non de compilateur
J'ai bien dit pré compilateur et non pas compilateur...
Dans mon école le premier langage à apprendre était le Python, personnellement je ne raffole pas de ce langage car il n'est pas typé et je me suis habitué au langage plutôt typé. Maintenant plus on connait de langages et mieux c'est.
Personnellement, je ne connais pas Python, je le connais par réputation sur le net, il semble qu'il est classé très haut, tu es sûr qu'il n'est pas si intéressant ? Le Pb est préférable d'après toi? Je te cache pas que je viens juste de le télécharger (il y a quelques jours) pour voir si vraiment il est intéressant comme on dit (je ne l'ai pas encore installé).
Dernière modification par omega le dim. 19/août/2018 20:28, modifié 1 fois.
Win7 (x64) 64 bits Pb 5.72
Avatar de l’utilisateur
microdevweb
Messages : 1798
Inscription : mer. 29/juin/2011 14:11
Localisation : Belgique

Re: Purebasic et concepts de POO

Message par microdevweb »

Comme si on essayait de traduire PB en C,
Oui et non.
Non parce que le c est plus bas niveau que Pb et oui parce que l'on pourrait créer un compilateur en n'importe quel langage. Analysez du texte est à la portée de n'importe quel langage, le tout après c'est de le traduire la ça peut ce compliquer.

Je ne parle de réinventer la roue, juste de l'ajout de quelques commandes spécifiques.

Maintenant dans mon cas même si j'adore Pb, j'ai fais mon choix et ne vais pas me complique la vie. J'utilise d'autres langages approprié qui répondent à mes attentes.
Windows 10 64 bits PB: 5.70 ; 5.72 LST
Work at Centre Spatial de Liège
Avatar de l’utilisateur
microdevweb
Messages : 1798
Inscription : mer. 29/juin/2011 14:11
Localisation : Belgique

Re: Purebasic et concepts de POO

Message par microdevweb »

Personnellement, je ne connais pas Python, je le connais par réputation sur le net, il semble qu'il est classé très haut, tu es sûr qu'il n'est pas si intéressant ? Le Pb est préférable d'après toi?
Je ne dis pas que Python n'est pas intéressant, loin de la.

Déjà l'énorme différence Pb est compilé et Python est interprété. Maintenant avec les performances des machines la différence est moins sensible.

Python possède des trucs vraiment top, comme la possibilité à une procédure de pouvoir renvoyer plusieurs variables ou le fait de pouvoir avec Eval obtenir le résultat mathématique d'une chaîne de caractère.

Mais je préfère d'autre langage, maintenant si je fais un code pour Rasberry ce sera en python.
Windows 10 64 bits PB: 5.70 ; 5.72 LST
Work at Centre Spatial de Liège
Avatar de l’utilisateur
omega
Messages : 617
Inscription : sam. 26/nov./2011 13:04
Localisation : Alger

Re: Purebasic et concepts de POO

Message par omega »

J'ai vu quelque part sur ce forum que tu avais abandonné (pour un certain temps) Pb et que tu es revenu. Tu dis maintenant que Python n'est pas (en premier lieu) ton langage préféré. Est ce que je peux savoir (tu n'es pas obligé de répondre mais je suis curieux de savoir) quel est ton langage préféré habituel?
Win7 (x64) 64 bits Pb 5.72
Avatar de l’utilisateur
microdevweb
Messages : 1798
Inscription : mer. 29/juin/2011 14:11
Localisation : Belgique

Re: Purebasic et concepts de POO

Message par microdevweb »

Cela dépend du projet à faire. Mais j'aime beaucoup le Java surtout depuis la couche graphique JavaFx. C'est certainement le plus portable.

J'aime toujours Pb et pas nécessairement pour sa syntaxe mais pour le résultat obtenu un exe petit et performant sans dépendance, ce qui lui manque (et ceci n'engage que moi ) c'est la Poo parce que j'aime concevoir mon analyse en orienté objet.
Windows 10 64 bits PB: 5.70 ; 5.72 LST
Work at Centre Spatial de Liège
Avatar de l’utilisateur
falsam
Messages : 7244
Inscription : dim. 22/août/2010 15:24
Localisation : IDF (Yvelines)
Contact :

Re: Purebasic et concepts de POO

Message par falsam »

microdevweb a écrit : ... ce qui lui manque (et ceci n'engage que moi ) c'est la Poo
Toi je vais t'appeler Idefix :mrgreen:
Configuration : Windows 11 Famille 64-bit - PB 6.03 x64 - AMD Ryzen 7 - 16 GO RAM
Vidéo NVIDIA GeForce GTX 1650 Ti - Résolution 1920x1080 - Mise à l'échelle 125%
Avatar de l’utilisateur
microdevweb
Messages : 1798
Inscription : mer. 29/juin/2011 14:11
Localisation : Belgique

Re: Purebasic et concepts de POO

Message par microdevweb »

En partant des exemples de G-rom, voici une manière de faire, avec héritage et méthode abstraite.
Plus facile à mettre en place car on n'utilise pas les interface, mais moins élégante à utiliser puisque on est obligé de passé par des pointeurs et de passer l'adresse du dit pointeur à chaque méthode.

Remarque : Il n'y à pas d'encapsulation des données.

Code : Tout sélectionner

; porotype des functions
Prototype draw(*this)
Prototype addForm(*this,*form)
; class form
Structure form
  x.l
  y.l
  draw.draw
EndStructure
; class rec hérite de form
Structure rec Extends form
  w.l
  h.l
EndStructure
; class Cercle hérite de form
Structure Cercle Extends form
  radius.l
EndStructure
; class drawing
Structure drawing
  List *myForm.form()
  idCanvas.l
  draw.draw
  addForm.addForm
EndStructure
; Méthode draw de rec
Procedure _drawRec(*this.rec)
  With *this
    Box(\x,\y,\w,\h,0)
  EndWith
EndProcedure
; Méthode draw de cercle
Procedure _drawCircle(*this.Cercle)
  With *this
    Circle(\x,\y,\radius,0)
  EndWith
EndProcedure
; Méthode draw de drawing
Procedure _drawDrawing(*this.drawing)
  With *this
    StartDrawing(CanvasOutput(\idCanvas))
    Box(0,0,GadgetWidth(\idCanvas),GadgetHeight(\idCanvas),$FFFFFF)
    Protected *f.form
    ForEach \myForm()
      *f = \myForm()
      *f\draw(*f)
    Next
    StopDrawing()
  EndWith
EndProcedure
; Méthode addForm de drawing
Procedure _addForm(*this.drawing,*f)
  With *this
    AddElement(\myForm())
    \myForm() = *f
  EndWith
EndProcedure
; Constructeur de rec
Procedure newRec(x.l,y.l,w.l,h.l)
  Protected *this.rec = AllocateStructure(rec)
  With *this
    \x = x
    \y = y
    \w = w
    \h = h
    \draw = @_drawRec()
    ProcedureReturn *this
  EndWith
EndProcedure
; Constructeur de  Cercle
Procedure newCircle(x.l,y.l,radius)
  Protected *this.Cercle = AllocateStructure(Cercle)
  With *this
    \x = x
    \y = y
    \radius = radius
    \draw = @_drawCircle()
    ProcedureReturn *this
  EndWith
EndProcedure
; Constructeur de Drawing
Procedure newDrawing(idCanvas)
  Protected *this.drawing = AllocateStructure(drawing)
  With *this
    \idCanvas = idCanvas
    \draw = @_drawDrawing()
    \addForm = @_addForm()
    ProcedureReturn *this
  EndWith
EndProcedure

Procedure exit()
  End
EndProcedure
; création de la fenêtre
OpenWindow(0,0,0,800,600,"teste",#PB_Window_ScreenCentered|#PB_Window_SystemMenu)
CanvasGadget(0,0,0,800,600)
; définition et création des objets
Define *myDrawing.drawing = newDrawing(0)
Define.rec *rec1 = newRec(10,10,20,20),*rec2 = newRec(40,10,30,30)
Define.Cercle *cer1 = newCircle(40,100,30), *cer2 = newCircle(100,100,20)
; ajout des formes au dessin
*myDrawing\addForm(*myDrawing,*rec1)
*myDrawing\addForm(*myDrawing,*rec2)
*myDrawing\addForm(*myDrawing,*cer1)
*myDrawing\addForm(*myDrawing,*cer2)
; dessin des formes
*myDrawing\draw(*myDrawing)
BindEvent(#PB_Event_CloseWindow,@exit(),0)

Repeat:WaitWindowEvent():ForEver

Windows 10 64 bits PB: 5.70 ; 5.72 LST
Work at Centre Spatial de Liège
Marc56
Messages : 2146
Inscription : sam. 08/févr./2014 15:19

Re: Purebasic et concepts de POO

Message par Marc56 »

Bon,
http://www.purearea.net/pb/english/interview.htm (2005)

29. Will the support of OOP in PureBasic be further extended/improved? Or will PureBasic be orientated rather at the procedural BASIC also in the future?

No. It will stay a procedural BASIC, I don't plan to add class and such I think it will split the PB world in 2 classes (!): the one which have understood fully how OOP work and other which don't. Which means than you couldn't share source codes easily anymore at one place. Procedural and Object Oriented Programming are two opposite concepts and it's not a good idea to mix them in a BASIC language (which is intended for beginners...)


Et à nouveau en 2018 sur le forum us: il n'y aurait pas d'acheteurs pour une version orientée POO qui ne serait alors qu'un produit concurrent aux actuels (C+, #, VC etc) et très long à mettre au point.

La philosophie PureBasic c'est "Think simple" ou https://fr.wikipedia.org/wiki/Principe_KISS
Ne cherchez pas à rendre compliqué et lourd le seul langage léger, rapide, simple, fiable (même plus que certains langages "pro") qui existe encore.

Faut circuler maintenant, allez admirer le C++, C# et parler POO sur les forums ad hoc et laissez passer les modos, ils doivent mettre un cadenas ici 8)
Avatar de l’utilisateur
Ar-S
Messages : 9472
Inscription : dim. 09/oct./2005 16:51
Contact :

Re: Purebasic et concepts de POO

Message par Ar-S »

De toute façon chaque année on a les mêmes demandes de POO et chaque année on vous dit que PB n'est pas conçu pour être un langage Objets.
N'espérez pas que ça arrive... Créez vos propres outils, IDE si vous le souhaitez, ou changez d'environnement de dev... Mais ne demandez pas pas au jaguar de bêler :D
~~~~Règles du forum ~~~~
⋅.˳˳.⋅ॱ˙˙ॱ⋅.˳Ar-S ˳.⋅ॱ˙˙ॱ⋅.˳˳.⋅
W11x64 PB 6.x
Section HORS SUJET : ICI
LDV MULTIMEDIA : Dépannage informatique & mes Logiciels PB
UPLOAD D'IMAGES : Uploader des images de vos logiciels
Avatar de l’utilisateur
Kwai chang caine
Messages : 6962
Inscription : sam. 23/sept./2006 18:32
Localisation : Isere

Re: Purebasic et concepts de POO

Message par Kwai chang caine »

LE PRINCIPE KISS !!!
Marc56 a écrit :La philosophie PureBasic c'est "Think simple" ou https://fr.wikipedia.org/wiki/Principe_KISS
Image
Image
Image
Image
Image
Je viens d'apprendre quelque chose de plus grâce à toi 8)

Waooouuuh ! je savais pas que j'utilisais depuis des années une méthode de pros et hacker de haut niveau 8O :mrgreen:
Coooll !!! merci Marco 8)
Je me rappelle que le grand SROD dont le top niveau n'est plus à prouver, disait déjà à l'époque :
"Mon deuxième prénom est SIMPLE" depuis j'ai essayé de suivre cette philosophie 8)
Je vous l'accorde quand on y connait rien c'est beaucoup plus facile :mrgreen:
Faut circuler maintenant, allez admirer le C++, C# et parler POO sur les forums ad hoc et laissez passer les modos, ils doivent mettre un cadenas ici 8)
D'un autre coté les POOistes ne font de mal à personne :wink:
Ils génèrent des codes de hauts niveaux à coups de pointeurs et bien que je déteste toujours la POO, je trouve ce sujet intéressant, tout comme le fait de faire valser la mémoire 8)
Aprés tout un enfant qui réclame, ne vole pas, ce n'est pas la même punition :mrgreen:

Et qui sait, comme on l'a déjà dit, peut être qu'à force d'en parler il y en aura un, ou un groupe, qui trouveront le GRAAL, ça n’enlèvera rien à PB, voir même, et ça satisfera tout le monde.
Je suis mal placé pour le dire, car comme PB, je suis très bas niveau, mais les nombreux membres qui en parlent constamment feraient mieux de s'y atteler, quitte à se faire aider, et l'on sait que sur PB ceux qui aident sont légion, comme dirait mon copain GRom de se sortir les ..... :wink:
Ars a écrit :Mais ne demandez pas pas au jaguar de bêler
Tiens j'la connaissait pas non plus celle là :lol:
Quoi que, un bon tirroir et une paire de .... ça fait quel bruit ? :mrgreen:

Quand j'vous dit qu'on en apprend tous les jours sur ce forum
C'est un peu la gazette du matin, manque plus que le petit crème et la terrasse :D
ImageLe bonheur est une route...
Pas une destination

PureBasic Forum Officiel - Site PureBasic
Avatar de l’utilisateur
microdevweb
Messages : 1798
Inscription : mer. 29/juin/2011 14:11
Localisation : Belgique

Re: Purebasic et concepts de POO

Message par microdevweb »

Je suis personnellement acheteur d'une version Poo :mrgreen:

Mais j'ai suivi ton conseille et suis en effet passé à d'autres langages...

Bon je poste quand même ce code le même que l'exemple précédent, mais avec les interfaces.

Reprend les principes suivants
  • Encapsulation
  • Classes et méthodes abstraites
  • Héritage
La évidement pour la mise ne place c'est plus compliqué, mais plus simple et intuitif pour l'utilisateur final.

Code : Tout sélectionner

DeclareModule Drawing
  ; Methodes public
  Interface Rectangle
    getPosX()
    getPosY()
    setPosX(x)
    setPosY(Y)
    getWidth()
    getHeigth()
    setWidth(w)
    setHeigth(H)
  EndInterface
  Interface Cercle
    getPosX()
    getPosY()
    setPosX(x)
    setPosY(Y)
    getRadius()
    setRadius(radius)
  EndInterface
  Interface Drawing
    addForm(form)
    draw()
  EndInterface
  
  Declare new_drawing(idCanvas)
  Declare new_rectangle(x,y,w,h)
  Declare new_circle(x,y,radius)
EndDeclareModule
Module Drawing
  ; REMARQUE : Normalement pour être plus propre on incluerait le fichier avec le code de la class
  ; class definition
  Prototype draw(*this)
  Structure _Form
    *methods
    x.l
    y.l
    draw.draw ; methode abstraite draw
  EndStructure
  Structure _Rec Extends _Form
    w.l
    h.l
  EndStructure
  Structure _Cercle Extends _Form
    radius.l
  EndStructure
  Structure _Drawing
    *methods
    idCanvas.l
    List *myForm._Form()
  EndStructure
  
  ;-* Methodes de _Form
  ; --> Getters
  Procedure Form_getPosX(*this._Form)
    With *this
      ProcedureReturn \x
    EndWith
  EndProcedure
  Procedure Form_getPosY(*this._Form)
    With *this
      ProcedureReturn \Y
    EndWith
  EndProcedure
  ; --> Setters
  Procedure Form_setPosX(*this._Form,x)
    With *this
      \x = x
    EndWith
  EndProcedure
  Procedure Form_setPosY(*this._Form,y)
    With *this
      \Y = y
    EndWith
  EndProcedure
  ;}
  
  ;-* Methodes de _Rec
  ; --> Getters
  Procedure Rec_getW(*this._Rec)
    With *this
      ProcedureReturn \w
    EndWith
  EndProcedure
  
  Procedure Rec_getH(*this._Rec)
    With *this
      ProcedureReturn \h
    EndWith
  EndProcedure
  ; --> Setters
  Procedure Rec_setW(*this._Rec,w)
    With *this
      \w = w
    EndWith
  EndProcedure
  
  Procedure Rec_setH(*this._Rec,h)
    With *this
      \h = h
    EndWith
  EndProcedure
  ; --> protected abstract method
  Procedure Rec_draw(*this._Rec)
    With *this
      Box(\x,\y,\w,\h,0)
    EndWith
  EndProcedure
  ;}
  
  ;-* Methodes de _Cercle
  ; --> Getters
  Procedure Cercle_getRadius(*this._Cercle)
    With *this
      ProcedureReturn \radius
    EndWith
  EndProcedure
  ; --> Setters
  Procedure Cercle_setRadius(*this._Cercle,radius)
    With *this
      \radius = radius
    EndWith
  EndProcedure
  ; --> Abstract methods
  Procedure Cercle_draw(*this._Cercle)
    With *this
      Circle(\x,\y,\radius,0)
    EndWith
  EndProcedure
  ;}
  
  ;-* Methodes de drawing
  Procedure Drawing_addForm(*this._Drawing,*form)
    With *this
      AddElement(\myForm())
      \myForm() = *form
    EndWith
  EndProcedure
  
  Procedure Drawing_draw(*this._Drawing)
    With *this
      StartDrawing(CanvasOutput(\idCanvas))
      ForEach \myForm()
        \myForm()\draw(\myForm())
      Next
      StopDrawing()
    EndWith
  EndProcedure
  ;}
  
  ;-* Constructeurs
  Procedure new_drawing(idCanvas)
    Protected *this._Drawing = AllocateStructure(_Drawing)
    With *this
      \methods = ?S_DRAWING ; copie les adresser de méthodes
      \idCanvas = idCanvas
      ProcedureReturn *this
    EndWith
  EndProcedure
  
  Procedure new_rectangle(x,y,w,h)
    Protected *this._Rec = AllocateStructure(_Rec)
    With *this
      \methods = AllocateMemory((?E_FORM - ?S_FORM) + (?E_REC - ?S_REC))
      ; copie des addresses des méthodes de form
      MoveMemory(?S_FORM,\methods,(?E_FORM - ?S_FORM)) 
      ; copie des addresses des méthodes de rec
      MoveMemory(?S_REC,\methods + (?E_FORM - ?S_FORM),(?E_REC - ?S_REC)) 
      \x = x
      \y = y
      \w = w
      \h = h
      \draw = @Rec_draw()
      ProcedureReturn *this
    EndWith
  EndProcedure
  
  Procedure new_circle(x,y,radius)
    Protected *this._Cercle = AllocateStructure(_Cercle)
    With *this
      \methods = AllocateMemory((?E_FORM - ?S_FORM) + (?E_CERCLE - ?S_CERCLE))
      ; copie des addresses des méthodes de form
      MoveMemory(?S_FORM,\methods,(?E_FORM - ?S_FORM)) 
      ; copie des addresses des méthodes de rec
      MoveMemory(?S_REC,\methods + (?E_FORM - ?S_FORM),(?E_CERCLE - ?S_CERCLE)) 
      \x = x
      \y = y
      \radius = radius
      \draw = @Cercle_draw()
      ProcedureReturn *this
    EndWith
  EndProcedure
  ;}
  DataSection
    S_FORM:
    Data.i @Form_getPosX()
    Data.i @Form_getPosY()
    Data.i @Form_setPosX()
    Data.i @Form_setPosY()
    E_FORM:
    S_REC:
    Data.i @Rec_getW()
    Data.i @Rec_getH()
    Data.i @Rec_setW()
    Data.i @Rec_setH()
    E_REC:
    S_CERCLE:
    Data.i @Cercle_getRadius()
    Data.i @Cercle_setRadius()
    E_CERCLE:
    S_DRAWING:
    Data.i @Drawing_addForm()
    Data.i @Drawing_draw()
    E_DRAWING:
  EndDataSection
EndModule

UseModule Drawing
#MAIN_FROM = 0
#MAIN_CANVAS = 0
Define myDrawing.Drawing = new_drawing(#MAIN_CANVAS)
myDrawing\addForm(new_rectangle(40,10,60,30))
myDrawing\addForm(new_rectangle(40,80,100,30))
myDrawing\addForm(new_circle(40,150,30))
myDrawing\addForm(new_circle(140,300,50))

Procedure Exit()
  End
EndProcedure

; création de la fenêtre
OpenWindow(#MAIN_FROM,0,0,800,600,"teste",#PB_Window_ScreenCentered|#PB_Window_SystemMenu)
CanvasGadget(#MAIN_CANVAS,0,0,800,600)
BindEvent(#PB_Event_CloseWindow,@Exit(),#MAIN_FROM)
myDrawing\draw()
Repeat:WaitWindowEvent():ForEver
Conclusion on peut faire la Poo avec Pb et avec certaines limites. Mais il n'est en effet pas prévu à cet effet et ceal demande plus de travail qu'avec un autre langage qui est prévu pour cela
Windows 10 64 bits PB: 5.70 ; 5.72 LST
Work at Centre Spatial de Liège
Répondre