Les opérateurs logiques ca peut servir!

Informations pour bien débuter en PureBasic
Avatar de l’utilisateur
microdevweb
Messages : 1798
Inscription : mer. 29/juin/2011 14:11
Localisation : Belgique

Les opérateurs logiques ca peut servir!

Message par microdevweb »

Je sais que pour beaucoup d'entre vous les opérateurs logiques sont inutiles et pourtant. Pour le fun je développe actuellement un petit jeux d'échec en Pb.

Je traite l'échiquier sous forme de matrice carrée (8,8) (si vous préfère avec un tableau de 8 lignes et 8 colonnes ).

Reste le problème de mémorisé dans chaque case de la matrice le type de pion ainsi que sa couleur.

Voila entre autre à quoi peuvent servir les opérateurs logiques :wink:

Voila une exemple avec une partie (adapté pour l'exemple) de mon code.

Nb: Ne voulant pas vous imposé le chargement d'images les pions ne sont pas représentés visuellement mais seulement en mémoire

Utilisation: déplacez la souri à l'emplacement d'un pion, si vous avez déjà joué au échecs cela ne devrait pas posé de problème

Code : Tout sélectionner

Global Dim ChessBoard.l(8,8)
EnableExplicit

#CaseSize=64
#Rook=$00000001
#Knight=$00000002
#Bishop=$00000004
#King=$00000008
#Queen=$00000010
#Pawn=$00000020
#WhiteC=$01000000
#BlackC=$10000000
Enumeration 
  #MainForm
  #Canvas
EndEnumeration

Declare OpenForm()
Declare DrawChessBoard()
Declare ManageStartChessPawn()
Declare Exit()
Declare ManageCanvas()
Declare WhoIsThere(Line,Column)

Procedure OpenForm()
  Protected W=(8 * #CaseSize),H=(8 * #CaseSize)
  OpenWindow(#MainForm,0,0,W,H,"Pb chess board",$CB0001)
  CanvasGadget(#Canvas,0,0,W,H,#PB_Canvas_Key)
  BindGadgetEvent(#Canvas,@ManageCanvas())
  BindEvent(#PB_Event_CloseWindow,@Exit(),0)
  AddKeyboardShortcut(0,#PB_Shortcut_Escape,0)
  BindEvent(#PB_Event_Menu,@Exit(),0,0)
  ManageStartChessPawn()
  DrawChessBoard()
EndProcedure
Procedure DrawChessBoard()
  Protected Dim Color(2),nColor=1,i,j,X,Y
  Color(0)=$B5E4FF
  Color(1)=$13458B
  StartDrawing(CanvasOutput(#Canvas))
  DrawingMode(#PB_2DDrawing_Default)
  For i=0 To 7
    X=0
    nColor+1
    If nColor>1
      nColor=0
    EndIf
    For j=0 To 7
      Box(X,Y,#CaseSize,#CaseSize,Color(nColor))
      nColor+1
      If nColor>1
        nColor=0
      EndIf
      X+#CaseSize
    Next
    Y+#CaseSize
  Next
  StopDrawing()
EndProcedure
Procedure ManageStartChessPawn()
  Protected i
  ; Black chess pawns
  ChessBoard(0,0)=#BlackC|#Rook
  ChessBoard(0,1)=#BlackC|#Knight
  ChessBoard(0,2)=#BlackC|#Bishop
  ChessBoard(0,3)=#BlackC|#Queen
  ChessBoard(0,4)=#BlackC|#King
  ChessBoard(0,5)=#BlackC|#Bishop
  ChessBoard(0,6)=#BlackC|#Knight
  ChessBoard(0,7)=#BlackC|#Rook
  For i=0 To 7
    ChessBoard(1,i)=#BlackC|#Pawn
  Next
  ; white chess pawns
  ChessBoard(7,0)=#WhiteC|#Rook
  ChessBoard(7,1)=#WhiteC|#Knight
  ChessBoard(7,2)=#WhiteC|#Bishop
  ChessBoard(7,3)=#WhiteC|#Queen
  ChessBoard(7,4)=#WhiteC|#King
  ChessBoard(7,5)=#WhiteC|#Bishop
  ChessBoard(7,6)=#WhiteC|#Knight
  ChessBoard(7,7)=#WhiteC|#Rook
  For i=0 To 7
    ChessBoard(6,i)=#WhiteC|#Pawn
  Next
EndProcedure
Procedure Exit()
  CloseWindow(#MainForm)
  End
EndProcedure
Procedure ManageCanvas()
  Protected MousePosX,MousePosY,CurrentLine.w,CurrentColumn.w
  MousePosY=GetGadgetAttribute(#Canvas,#PB_Canvas_MouseY)
  MousePosX=GetGadgetAttribute(#Canvas,#PB_Canvas_MouseX)
  CurrentLine=MousePosY/#CaseSize
  CurrentColumn=MousePosX/#CaseSize
  Select EventType()
    Case #PB_EventType_MouseMove
      WhoIsThere(CurrentLine,CurrentColumn)
  EndSelect
EndProcedure
Procedure WhoIsThere(Line,Column)
  Protected CurrentPiece,Message.s="Je suis "
  If ChessBoard(Line,Column)>0
    CurrentPiece=ChessBoard(Line,Column)&$00FFFFFF ; Extract the piece value only
    Select CurrentPiece
      Case #Pawn
        Message+"un Pion"
      Case #Rook
        Message+"une Tour"
      Case #King
        Message+"le Roi"
      Case #Queen
        Message+"la Reine"
      Case #Knight
        Message+"un cavalier"
      Case #Bishop
        Message+"un Fou"
    EndSelect
    If ChessBoard(Line,Column)&#WhiteC
      Message+" blanc"
    Else
      Message+" noir"
    EndIf
    Debug Message
  EndIf
EndProcedure

OpenForm()

Repeat:WaitWindowEvent():ForEver
Dernière modification par microdevweb le sam. 04/févr./2017 22:58, modifié 1 fois.
Windows 10 64 bits PB: 5.70 ; 5.72 LST
Work at Centre Spatial de Liège
Avatar de l’utilisateur
Micoute
Messages : 2522
Inscription : dim. 02/oct./2011 16:17
Localisation : 35520 La Mézière

Re: Les opérateurs logiques ca peut servir!

Message par Micoute »

Et comment que ça peut servir, merci pour ce partage ludique, moi ça m'éclate.
Dernière modification par Micoute le dim. 05/févr./2017 7:06, modifié 1 fois.
Microsoft Windows 10 Famille 64 bits : Carte mère : ASRock 970 Extreme3 R2.0 : Carte Graphique NVIDIA GeForce RTX 3080 : Processeur AMD FX 6300 6 cœurs 12 threads 3,50 GHz PB 5.73 PB 6.00 LTS (x64)
Un homme doit être poli, mais il doit aussi être libre !
Avatar de l’utilisateur
Zorro
Messages : 2185
Inscription : mar. 31/mai/2016 9:06

Re: Les opérateurs logiques ca peut servir!

Message par Zorro »

Code : Tout sélectionner

Message+"une Toure"
hum sans le "e" ;)
Image
Image
Site: http://michel.dobro.free.fr/
Devise :"dis moi ce dont tu as besoin, je t'expliquerai comment t'en passer"
Avatar de l’utilisateur
microdevweb
Messages : 1798
Inscription : mer. 29/juin/2011 14:11
Localisation : Belgique

Re: Les opérateurs logiques ca peut servir!

Message par microdevweb »

Hum Zorro est arrivé et d'un coup de lasso à corrigé une grosse erreur.

Merci je corrige :wink:
Windows 10 64 bits PB: 5.70 ; 5.72 LST
Work at Centre Spatial de Liège
Avatar de l’utilisateur
Zorro
Messages : 2185
Inscription : mar. 31/mai/2016 9:06

Re: Les opérateurs logiques ca peut servir!

Message par Zorro »

n'y vois pas de malice :)
c'est juste que ça m'a arraché la vue :lol:
en général j'aime pas les redresseurs de torts syntaxique :)
mais là, c’était trop pour moi :)
Image
Image
Site: http://michel.dobro.free.fr/
Devise :"dis moi ce dont tu as besoin, je t'expliquerai comment t'en passer"
Avatar de l’utilisateur
falsam
Messages : 7244
Inscription : dim. 22/août/2010 15:24
Localisation : IDF (Yvelines)
Contact :

Re: Les opérateurs logiques ca peut servir!

Message par falsam »

Zorro a écrit :c'est juste que ça m'a arraché la vue
en général j'aime pas les redresseurs de torts syntaxique :)
mais là, c’était trop pour moi :)
Trop pour toi ? ^^

Moi aussi certaines de tes phrases m'arrachent la vue et ce n'est qu'un exemple.
Zorro a écrit :sans erreurs ce serai mieux
ne voit pas de malice ni aucune agression de ma part hein? Soit beau joueur ^^
Le post en question : http://www.purebasic.fr/french/viewtopi ... 41#p189141
Configuration : Windows 11 Famille 64-bit - PB 6.03 x64 - AMD Ryzen 7 - 16 GO RAM
Vidéo NVIDIA GeForce GTX 1650 Ti - Résolution 1920x1080 - Mise à l'échelle 125%
Avatar de l’utilisateur
microdevweb
Messages : 1798
Inscription : mer. 29/juin/2011 14:11
Localisation : Belgique

Re: Les opérateurs logiques ca peut servir!

Message par microdevweb »

Zorro cela ne me vexe pas, et il est vrai que je suis plutôt nul en orthographe. Et on apprend de ses erreurs.
Windows 10 64 bits PB: 5.70 ; 5.72 LST
Work at Centre Spatial de Liège
Avatar de l’utilisateur
Micoute
Messages : 2522
Inscription : dim. 02/oct./2011 16:17
Localisation : 35520 La Mézière

Re: Les opérateurs logiques ca peut servir!

Message par Micoute »

Je pense qu'on devrait corriger les erreurs de code plutôt que les erreurs d'orthographe, l'école n'a pas toujours fait son travail d'apprentissage car elle chouchoute les meilleurs au lieu des nuls.
Microsoft Windows 10 Famille 64 bits : Carte mère : ASRock 970 Extreme3 R2.0 : Carte Graphique NVIDIA GeForce RTX 3080 : Processeur AMD FX 6300 6 cœurs 12 threads 3,50 GHz PB 5.73 PB 6.00 LTS (x64)
Un homme doit être poli, mais il doit aussi être libre !
Avatar de l’utilisateur
Zorro
Messages : 2185
Inscription : mar. 31/mai/2016 9:06

Re: Les opérateurs logiques ca peut servir!

Message par Zorro »

Micoute a écrit :Je pense qu'on devrait corriger les erreurs de code plutôt que les erreurs d'orthographe, l'école n'a pas toujours fait son travail d'apprentissage car elle chouchoute les meilleurs au lieu des nuls.
heu, lorsque tu aura corrigé autant de codes sur le forum, que j'ai pu le faire , on en reparlera ;)
quant a l’école, j'ai arrêté l’école en 6em ;)

mais comme je l'ai dis, c'etait une remarque sans intentions aucune, et microdevweb l'a tres bien compris , donc ça ne vous concerne pas ..
Image
Image
Site: http://michel.dobro.free.fr/
Devise :"dis moi ce dont tu as besoin, je t'expliquerai comment t'en passer"
Avatar de l’utilisateur
Micoute
Messages : 2522
Inscription : dim. 02/oct./2011 16:17
Localisation : 35520 La Mézière

Re: Les opérateurs logiques ca peut servir!

Message par Micoute »

Ce n'était pas toi que je visais, je voulais juste faire remarquer qu'on était sur un forum PB et non pas de cours de grammaire
Microsoft Windows 10 Famille 64 bits : Carte mère : ASRock 970 Extreme3 R2.0 : Carte Graphique NVIDIA GeForce RTX 3080 : Processeur AMD FX 6300 6 cœurs 12 threads 3,50 GHz PB 5.73 PB 6.00 LTS (x64)
Un homme doit être poli, mais il doit aussi être libre !
Avatar de l’utilisateur
Zorro
Messages : 2185
Inscription : mar. 31/mai/2016 9:06

Re: Les opérateurs logiques ca peut servir!

Message par Zorro »

certes , mais si on peut aider de temps en temps de ce coté, c'est pas mal non plus
(et il y a deja eu des précédents...notamment avec Dayvid )
Image
Image
Site: http://michel.dobro.free.fr/
Devise :"dis moi ce dont tu as besoin, je t'expliquerai comment t'en passer"
Avatar de l’utilisateur
microdevweb
Messages : 1798
Inscription : mer. 29/juin/2011 14:11
Localisation : Belgique

Re: Les opérateurs logiques ca peut servir!

Message par microdevweb »

Et bien moi Zorro, j'ai repris l'école pour 3 ans pour l'obtention d'un baccalauréat en informatique et système orienté industrie.

Et même si en temps qu'autodidacte j'ai beaucoup appris, on ne cesse d'apprendre.
Windows 10 64 bits PB: 5.70 ; 5.72 LST
Work at Centre Spatial de Liège
Avatar de l’utilisateur
Zorro
Messages : 2185
Inscription : mar. 31/mai/2016 9:06

Re: Les opérateurs logiques ca peut servir!

Message par Zorro »

oui, bon courage a toi ,
c'est pas évident de se relancer dans les études, et ça demande de la volonté :)
Image
Image
Site: http://michel.dobro.free.fr/
Devise :"dis moi ce dont tu as besoin, je t'expliquerai comment t'en passer"
Mesa
Messages : 1093
Inscription : mer. 14/sept./2011 16:59

Re: Les opérateurs logiques ca peut servir!

Message par Mesa »

Pour info, il était possible d'utiliser la fonction EnumerationBinary:

Code : Tout sélectionner

EnumerationBinary
#Rook;=$00000001
#Knight;=$00000002
#Bishop;=$00000004
#King;=$00000008
#Queen;=$00000010
#Pawn;=$00000020
EndEnumeration
M.
Avatar de l’utilisateur
Ar-S
Messages : 9472
Inscription : dim. 09/oct./2005 16:51
Contact :

Re: Les opérateurs logiques ca peut servir!

Message par Ar-S »

J'avais loupé ce sujet, c'est intéressant merci.
~~~~Règles du forum ~~~~
⋅.˳˳.⋅ॱ˙˙ॱ⋅.˳Ar-S ˳.⋅ॱ˙˙ॱ⋅.˳˳.⋅
W11x64 PB 6.x
Section HORS SUJET : ICI
LDV MULTIMEDIA : Dépannage informatique & mes Logiciels PB
UPLOAD D'IMAGES : Uploader des images de vos logiciels
Répondre