PureBasic

Forums PureBasic - Français
https://www.purebasic.fr/french/

Bug ou pas...avant d’embêter fred, j'ai besoins de vous....

https://www.purebasic.fr/french/viewtopic.php?t=17672

Page 1 sur 1

Bug ou pas...avant d’embêter fred, j'ai besoins de vous....

Publié : jeu. 02/mai/2019 5:13
par Stefou
Bonjour Tous le monde! 8)

J'espère que tout va bien pour vous et je vous remercie de me lire.

Voici un premier code qui marche correctement:
- si je clique sur la fenêtre 0, j'ai des événement sur la fenêtre 0
- si je clique sur la fenêtre 1, j'ai des événement sur la fenêtre 1

Code : Tout sélectionner

If OpenWindow(0, 0, 0, 300, 600, "fenetre 0", #PB_Window_SystemMenu )
  
  OpenWindow(1, 310, 0, 300, 600, "fenetre 1", #PB_Window_SystemMenu,WindowID(0) )

  Repeat 
    event= WaitWindowEvent() 
    
    If event<>0 And event<>13110 And event<>275 ;retire quelques évenement commun
      Debug "Evenement PRINC : |"+EventWindow()+" | "+event
    EndIf
  
  Until event= #PB_Event_CloseWindow
EndIf
Les problèmes arrivent lorsque l'on installe un timer :

Code : Tout sélectionner

If OpenWindow(0, 0, 0, 300, 600, "fenetre 0", #PB_Window_SystemMenu )
  
  OpenWindow(1, 310, 0, 300, 600, "fenetre 1", #PB_Window_SystemMenu,WindowID(0) )
  AddWindowTimer(0,1,100)
  Repeat 
    event= WaitWindowEvent() 
    
    If event<>0 And event<>13110 And event<>275 ;retire quelques évenement commun
      Debug "Evenement PRINC : |"+EventWindow()+" | "+event
    EndIf
    
  Until event= #PB_Event_CloseWindow
EndIf
On s’aperçoit qu'en cliquant dans la fenetre 1, des événement comme des 512,513,514 sont générés avec comme ID la fenêtre 0 ce qui m'a posé problème et ne me semble pas souhaitable...

Qu'en pensez vous?

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : jeu. 02/mai/2019 6:43
par Micoute
Bonjour Stefou,

moi, je verrais plutôt àa comme ça :

Code : Tout sélectionner

If OpenWindow(0, 0, 0, 300, 600, "fenetre 0", #PB_Window_SystemMenu )
  
  OpenWindow(1, 310, 0, 300, 600, "fenetre 1", #PB_Window_SystemMenu,WindowID(0) )
  AddWindowTimer(0,1,100)
  Repeat 
    event= WaitWindowEvent()
    
    Select event
      Case #PB_Event_Timer
        Select EventTimer()
          Case 0 ;Timer
            
            
            ;If event<>0 And event<>13110 And event<>275 ;retire quelques évenement commun
            Debug "Evenement PRINC : |"+EventWindow()+" | "+event
            ;EndIf
        EndSelect
    EndSelect
    
  Until event= #PB_Event_CloseWindow
EndIf

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : jeu. 02/mai/2019 7:39
par Marc56
Stefou a écrit : Les problèmes arrivent lorsque l'on installe un timer :
...
On s’aperçoit qu'en cliquant dans la fenetre 1, des événement comme des 512,513,514 sont générés avec comme ID la fenêtre 0 ce qui m'a posé problème et ne me semble pas souhaitable...
C'est logique: à chaque déclenchement du timer, c'est la fenêtre qui à ce timer qui devient la fenêtre émettrice pour EventWindow(). Peut importe que tu 'check' le timer ou pas dans la boucle, c'est alors la fenêtre 0 qui redevient la fenêtre "en cours".
Les événements 512, 513, 514 (déplacement souris) sont donc toujours retournés comme venant de la fenêtre 0.
Les autres ont bien la fenêtre source.

Si tu veux tester, mets par exemple un timer à 10 secondes et tu verra que EventWindow() changera au bout de 10 secondes

:wink:

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : jeu. 02/mai/2019 10:05
par Stefou
Merci à vous 2

Cela vous parait peut être logique mais pas à moi.

Lorsque je clique sur la fenêtre 1, je devrais avoir l’événement 513 lié à la 1 et non pas à la 0.

Je pensais que l’événement était lié à la fenêtre ou il a eu lieu et pas la fenêtre en cours!

Le timer ne devrait pas changer cela....????


....un autre avis.....

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : jeu. 02/mai/2019 12:54
par Micoute
à moins d'utiliser un canvas par fenêtre et tester les évènements de chaque canvas.

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : jeu. 02/mai/2019 13:29
par MLD
@Stefou
regarde ce code c'est A-Rs qui me l'a passé .Il vient de Lunasol.
En principe ceci devrait te parler.

Code : Tout sélectionner

EnableExplicit

Define CURSOR.q ; this is POINT structure by fact
Define hWnd

Define MyWindow1 = OpenWindow(#PB_Any, 0, 0, 250, 50, "1")
Define MyWindow2 = OpenWindow(#PB_Any, 250, 0, 250, 50, "2")

Repeat
   If WaitWindowEvent(1) = #PB_Event_CloseWindow
      Break
   EndIf
   
   GetCursorPos_(@CURSOR) ; get cursor pos
   hWnd = WindowFromPoint_(CURSOR) ; get window handle under specified cursor pos (excluding hidden/disabled windows)
   
   If hWnd = WindowID(MyWindow1)
      SetActiveWindow(MyWindow1)
   ElseIf hWnd = WindowID(MyWindow2)
      SetActiveWindow(MyWindow2)
   EndIf
   
  ; Delay(64)
ForEver

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : jeu. 02/mai/2019 16:10
par falsam
Tout comme te le dis Marc, le résultat que tu rencontres est normal. Pas de bug.

Dans ton code tu attaches un timer à la fenêtre 0.

EventWindow() ne retourne pas la fenêtre active.
EventWindow() retourne la fenêtre qui a déclenché un événement.

Regarde ton code modifié avec l'utilisation de GetActiveWindow()

Code : Tout sélectionner

If OpenWindow(0, 0, 0, 300, 600, "fenetre 0", #PB_Window_SystemMenu )
  
  OpenWindow(1, 310, 0, 300, 600, "fenetre 1", #PB_Window_SystemMenu,WindowID(0) )
  AddWindowTimer(0,1,100)
  Repeat 
    event= WaitWindowEvent() 
    
    If event<>0 And event<>13110 And event<>275 ;retire quelques évenement commun
      Debug "Evenement PRINC : |"+GetActiveWindow()+" | "+event
    EndIf
    
  Until event= #PB_Event_CloseWindow
EndIf
Je pense que c'est le résultat que attends

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : sam. 04/mai/2019 14:09
par microdevweb
GetActiveWindow() retourne par-contre la fenêtre qui a le focus

Code : Tout sélectionner

If OpenWindow(0, 0, 0, 300, 600, "fenetre 0", #PB_Window_SystemMenu )
  
  OpenWindow(1, 310, 0, 300, 600, "fenetre 1", #PB_Window_SystemMenu,WindowID(0) )
  AddWindowTimer(0,1,100)
  Repeat 
    event= WaitWindowEvent() 
    
    If event<>0 And event<>13110 And event<>275 ;retire quelques évenement commun
      Debug "Evenement PRINC : |"+EventWindow()+" | "+event
      Debug "Active window : "+Str(GetActiveWindow())
    EndIf
    
  Until event= #PB_Event_CloseWindow
EndIf

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : sam. 04/mai/2019 17:33
par falsam
C'est ce que j'ai repondu dans mon message précédent le tien .....

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : sam. 04/mai/2019 18:02
par Ollivier
falsam a écrit :C'est ce que j'ai repondu dans mon message précédent le tien .....
C'est ce que j'ai répondu dans mon message précédant le tiens.

C'est quand même plus fassile de voire laid fautes chez les hôtes !

Me cognant stoïquement le chambranle de la porte, récemment baptisée << EXIT >> par le père Mohamed Yomex-Tralucide, je vous salue mes soeurs et frères pour la vélocité de vos réponses, et l'exactitude à laquelle vous ne démordez...

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : dim. 05/mai/2019 20:49
par Ollivier
@Stefou

Avant, j'utilisais les nombres aussi. Jusqu'au jour où ceux-ci ont changé. Résultat : une perte de temps pas prévue.

Je te recommande les constantes natives, à moins que tu utilises des valeurs non pré-réglées. En tout cas, bon courage !

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : jeu. 09/mai/2019 4:27
par Stefou
Bonjour à tous

Je commence par m'excuser de ma réponse tardive que j'excuse tout d'abord par une charge de travail énorme en ce moment, et aussi par le fait que je ne suis pas convaincu par vos réponse.

Je vous remercie pour vos conseils de programmation très aimable, gentils, attentionnés...mais qui nous éloigne du problème car je ne cherche pas de solution.

Si j'avais a programmer un système d'exploitation, tous les événements intervenant sur une fenêtre serait liée à cette fenêtre.

Et c'est dans cet esprit que je programme actuellement.

MAIS je me suis aperçu qu'avec un Timer, quand je clic sur la fenêtre 1 il me renvoie un événement de clic sur la fenêtre 0!

S'il on doit débattre de quelque chose c'est de ça.

Je reprends donc vos argument pour me convaincre que c'est normal:

@Marc56
C'est logique: à chaque déclenchement du timer, c'est la fenêtre qui à ce timer qui devient la fenêtre émettrice pour EventWindow(). Peut importe que tu 'check' le timer ou pas dans la boucle, c'est alors la fenêtre 0 qui redevient la fenêtre "en cours".Les événements 512, 513, 514 (déplacement souris) sont donc toujours retournés comme venant de la fenêtre 0.
Je ne comprends pas la logique!
Windows devrait nous dire Timer sur la fenêtre 0 + Clic sur la fenêtre 1

@Falsam

Code : Tout sélectionner

EventWindow() ne retourne pas la fenêtre active.
EventWindow() retourne la fenêtre qui a déclenché un événement.
On est bien d'accord!!! Alors pourquoi il me dit clic sur la fenêtre 0 puisque je clic sur la 1!!!!

Merci d'avoir pris le temps de me lire et de rester dans le sujet.

Bonne journée à vous tous

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : jeu. 09/mai/2019 11:49
par microdevweb
Ne pas oublier aussi que si tu est sur la fenêtre 0 et que tu clique sur la fenêtre 1 la fenêtre 0 renvoi un événement de type "lost focus".

Le mieux encore est la gestion des événementq avec des "bind" perso cela fait très longtemps que ne gère plus les événements dans la main loop.

Code : Tout sélectionner

BindEvent(Event,@callback(),window)

Re: Bug ou pas...avant d’embêter fred, j'ai besoins de vous.

Publié : jeu. 09/mai/2019 13:39
par Zorro
Stefou a écrit : On est bien d'accord!!! Alors pourquoi il me dit clic sur la fenêtre 0 puisque je clic sur la 1!!!!
alors c'est pourtant indiqué dans la doc !!
je cite :
Renvoie le numéro de la fenêtre dans laquelle s'est produit le dernier évènement renvoyé
qui te dis, dans ton code que le dernier evenement renvoyé viens de ta fenetre 1 ??

en realité pleins d'event se passent tres tres rapidement ... lorsque tu quitte une fenetre, lorsque tu entres dans une autre etc...
en plus le timer... bref meme windows en ajoutes au passage ....

c'est a toi de choisir l'evenement que tu veux recuperer !

les events windows sont comme une cascade d'eau qui coule , a toi de récupérer les poissons qui te plaisent et qui tombent a la volée ...

ton code revu en plus propre (avec des cases) .. et qui utilise (comme Falsam te l'a expliqué) le bon evenement a recuperer

Code : Tout sélectionner

enumeration
		#Win_0
		#win_1
		#timer
Endenumeration

If OpenWindow(#win_0, 0, 0, 300, 600, "fenetre 0", #PB_Window_SystemMenu )
		
		OpenWindow(#win_1, 310, 0, 300, 600, "fenetre 1", #PB_Window_SystemMenu,WindowID(#win_0) )
		AddWindowTimer(#win_0,#timer,1000)
		Repeat
				event= WaitWindowEvent(2)
				select Event
						;   le Timer
						case #PB_Event_Timer
						If EventTimer() =#timer
								debug "Timer tick"
						EndIf    
						case #WM_LBUTTONDOWN
						debug "la fenetre qui a été cliquée est la numero :"+GetActiveWindow()
				EndSelect
				
		Until event= #PB_Event_CloseWindow
endif

de plus , tu utilises non pas 2 fenetres indépendantes , mais une fenetre qui est la fille de l'autre
c'est deja bien différent que 2 fenetres indépendante !! ;)


si tu veux avoir des events séparés , il te faut gerer ta boucle d'event de cette façon :

Code : Tout sélectionner


Enumeration 0 ; Id. Fenêtres
	#FENETRE1
	#FENETRE2
EndEnumeration
Enumeration 0 ; Id. Gadgets
	#FEN1_BOUTON
	#FEN1_FERMER
	#FEN2_FERMER
EndEnumeration

If OpenWindow(#FENETRE1, 0, 0, 640, 480, "Fenêtre 1", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)      
	If CreateGadgetList(WindowID(#FENETRE1))
		ButtonGadget(#FEN1_BOUTON, 5,  5, 100, 22, "Ouvrir Fenêtre 2")
		ButtonGadget(#FEN1_FERMER, 5, 45, 100, 22, "Quitter")
	EndIf      
	Repeat            
		Evenement.l = WaitWindowEvent()            
		Select EventWindow()                        
			;=====================================================
			;== EVENEMENTS DE LA FENETRE PRINCIPALE
			;=====================================================
			
			Case #FENETRE1                        
			Select Evenement                                    
				Case #PB_Event_Gadget                                    
				Select EventGadget()                                                
					Case #FEN1_BOUTON
					If OpenWindow(#FENETRE2, 0, 0, 320, 240, "Fenêtre 2", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)
						If CreateGadgetList(WindowID(#FENETRE2))
							ButtonGadget(#FEN2_FERMER, 5, 5, 100, 22, "Fermer")
						EndIf
					EndIf                                                
					Case #FEN1_FERMER
					Break                                                
				EndSelect
				
				Case #PB_Event_CloseWindow
				Break
				
			EndSelect
			
			;=====================================================
			;== EVENEMENTS DE LA FENETRE SECONDAIRE
			;=====================================================
			
			Case #FENETRE2                        
			Select Evenement                                    
				Case #PB_Event_Gadget                                    
				If EventGadget() = #FEN2_FERMER
					CloseWindow(#FENETRE2)
				EndIf                                    
				Case #PB_Event_CloseWindow                                    
				CloseWindow(#FENETRE2)                                    
			EndSelect                        
		EndSelect            
	ForEver      
EndIf


; EPB
et le prochain coup , utilise des Constantes, c'est mieux lisible que des 0 ou 1 ou 2 .....
Fuseau horaire sur UTC+01:00
Page 1 sur 1

Développé par phpBB® Forum Software © phpBB Limited

Traduction française officielle © Qiaeru