PureBasic Forums - English

Code: Select all

Debug FindString("text1$ text2$ text3$","t2$") ; Want 0 returned, not 11.

Code: Select all

EnableExplicit

Procedure FindString2(Source.s, SearchString.s)
	Protected pos = 1
	Protected length = Len(SearchString)
	Protected Result, charStart, charEnd
	Repeat
		pos = FindString(Source, SearchString, pos)
		If pos
			charStart = Asc(Mid(Source, pos - 1, 1))
			charEnd = Asc(Mid(Source, pos + length, 1))
; 			Debug Chr(charStart)
; 			Debug Chr(charEnd)
; 			Debug pos
; 			If Not ((charStart >= 65 And charStart <= 90) Or (charStart >= 97 And charStart <= 122) Or (charStart >= 48 And charStart <= 57 Or charStart = 36) Or (charEnd >= 65 And charEnd <= 90) Or (charEnd >= 97 And charEnd <= 122) Or (charEnd >= 48 And charEnd <= 57) Or charEnd = 36)
			If (Not ((charStart >= 65 And charStart <= 90) Or (charStart >= 97 And charStart <= 122) Or (charStart >= 48 And charStart <= 57 Or charStart = 36)) Or pos = 1) And Not ((charEnd >= 65 And charEnd <= 90) Or (charEnd >= 97 And charEnd <= 122) Or (charEnd >= 48 And charEnd <= 57) Or charEnd = 36)
				Result = pos
				Break
			EndIf
			pos + 1
		Else
			Break
		EndIf
	ForEver
	
    ProcedureReturn Result
EndProcedure

Debug FindString2("text1$ text2$ ext text3$","ext")
Debug FindString2("t2$ text1$ text2$ text3$ t2$","t2$")

Code: Select all

EnableExplicit

Procedure FindString2(Source.s, SearchString.s, separator.s = #TAB$ + " .,:<>()[]{}!")
	Protected pos = 1
	Protected length = Len(SearchString)
	Protected Result, charStart.s, charEnd.s
	Repeat
		pos = FindString(Source, SearchString, pos)
		If pos
			charStart = Mid(Source, pos - 1, 1)
			charEnd = Mid(Source, pos + length, 1)
; 			Debug charStart
; 			Debug charEnd
; 			Debug pos
; 			If FindString(separator, charStart) And FindString(separator, charEnd)
			If (pos = 1 Or FindString(separator, charStart)) And (FindString(separator, charEnd) Or charEnd = "")
				Result = pos
				Break
			EndIf
			pos + 1
		Else
			Break
		EndIf
	ForEver
	
    ProcedureReturn Result
EndProcedure

Debug FindString2("text1$ text2$ text3$","t2$")
Debug FindString2("text1$ text2$ text3$ t2$","t2$")

Code: Select all

EnableExplicit

Procedure FindString2(Source.s, SearchString.s)
	Protected pos = 1
	Protected length = Len(SearchString)
	Protected Result, charStart, charEnd
	Repeat
		pos = FindString(Source, SearchString, pos)
		If pos
			charStart = Asc(Mid(Source, pos - 1, 1))
			charEnd = Asc(Mid(Source, pos + length, 1))
			If pos = 1
				charStart = 1
			Else
				Select charStart
					Case 65 To 90, 97 To 122, 48 To 57, 36
						pos + 1
						Continue
				EndSelect
			EndIf
			Select charEnd
				Case 65 To 90, 97 To 122, 48 To 57, 36
					pos + 1
					Continue
			EndSelect
			Result = pos
			Break
		Else
			Break
		EndIf
	ForEver
	
	ProcedureReturn Result
EndProcedure

Debug FindString2("text1$ text2$ ext text3$","ext")
Debug FindString2("t2$ text1$ text2$ text3$ t2$","t2$")

Code: Select all

Debug FindString("text1$ text2$ text3$"," t2$") ; returns 0

Code: Select all

Procedure FindStringWhole(textString$, toFind$)

  Protected count = Len(toFind$)
  Protected count2 = count + 1
  Protected pos = 0
  
  If textString$ = toFind$ Or Left(textString$, count2) = toFind$ + " "
    pos = 1
  ElseIf Right(textString$, count2) = " " + toFind$
    pos = Len(textString$) - count+1
  Else
    pos = FindString(textString$, " " + toFind$ + " ")
    If pos > 0
      pos + 1
    EndIf
  EndIf
  
  ProcedureReturn pos
EndProcedure

Debug FindStringWhole("text1$ text2$ text3$","t2$")

Code: Select all

Debug FindStringWhole("Hello World!","World")

Code: Select all

Procedure FindWholeWord(Source.s, SearchString.s, Mode.i = 0)
	Protected regExFlags.i = #PB_RegularExpression_MultiLine
	If Mode = #PB_String_NoCase
		regExFlags | #PB_RegularExpression_NoCase
	EndIf
	
	Protected hRegEx.i = CreateRegularExpression(#PB_Any, "\b" + SearchString + "\b", regExFlags)
	If Not hRegEx
		ProcedureReturn -1
	EndIf
	
	If Not ExamineRegularExpression(hRegEx, Source)
		ProcedureReturn -2
	EndIf
	Protected position.i
	If NextRegularExpressionMatch(hRegEx)
		position = RegularExpressionMatchPosition(hRegEx)
	EndIf
	FreeRegularExpression(hRegEx)
	ProcedureReturn position
EndProcedure

Debug FindWholeWord("text1$ text2$ text3$", "t2$")
Debug FindWholeWord("Hello World!", "world", #PB_String_NoCase)