Page 1 of 1
Make the panel (taskbar) disappear during full screen
Posted: Tue Nov 12, 2024 1:59 am
by coco2
How do you make the panel disappear during fullscreen windowed mode?
Re: Make the panel (taskbar) disappear during full screen
Posted: Tue Nov 12, 2024 10:34 pm
by moulder61
Hi coco2,
I recently discovered StickyWindow(#Window, State). It forces a window to be on top of other windows.
I'm using a minimal XFCE desktop and my panel, tint2, is set to be below windows hierarchically. It's also set to have maximised windows not cover it. Fullscreen windows do though.
Obviously I have no idea what desktop/environment you are using, but either changing the panel settings or trying StickyWindow might be worth a try?
Another option would be to set your panel to hide intelligently. The downside to that would be that if you shared your software, the recipient would probably have to do the same on their machine.
Moulder.
Re: Make the panel (taskbar) disappear during full screen
Posted: Wed Nov 13, 2024 12:55 am
by mk-soft
GTK FullScreen ...
Code: Select all
;-TOP
Procedure UpdateWindow()
Protected dx, dy
dx = WindowWidth(0)
dy = WindowHeight(0) - StatusBarHeight(0) - MenuHeight()
; Resize Gadgets
EndProcedure
Procedure Main()
Protected dx, dy
#WinStyle = #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_MaximizeGadget | #PB_Window_MinimizeGadget
If OpenWindow(0, #PB_Ignore, #PB_Ignore, 600, 400, "Test Window", #WinStyle)
; MenuBar
CreateMenu(0, WindowID(0))
MenuTitle("&File")
MenuItem(99, "E&xit")
MenuTitle("&View")
MenuItem(1, "Fullscreen On")
MenuItem(2, "Fullscreen Off")
; StatusBar
CreateStatusBar(0, WindowID(0))
AddStatusBarField(#PB_Ignore)
; Gadgets
dx = WindowWidth(0)
dy = WindowHeight(0) - StatusBarHeight(0) - MenuHeight()
; Bind Events
BindEvent(#PB_Event_SizeWindow, @UpdateWindow(), 0)
; Main Loop
Repeat
Select WaitWindowEvent()
Case #PB_Event_CloseWindow
Select EventWindow()
Case 0
Break
EndSelect
Case #PB_Event_Menu
Select EventMenu()
Case 99
PostEvent(#PB_Event_CloseWindow, 0, 0)
Case 1
gtk_window_fullscreen_(WindowID(0))
Case 2
gtk_window_unfullscreen_(WindowID(0))
EndSelect
Case #PB_Event_Gadget
Select EventGadget()
EndSelect
EndSelect
ForEver
EndIf
EndProcedure : Main()
Re: Make the panel (taskbar) disappear during full screen
Posted: Wed Nov 13, 2024 8:48 am
by coco2
Thanks it works
Re: Make the panel (taskbar) disappear during full screen
Posted: Wed Nov 13, 2024 2:16 pm
by Mijikai
Thanks
