PureBasic Forums - English

Code: Select all

Procedure.i IsConnectedToInternet()
  Connected = #False
  CompilerIf #PB_Compiler_Version < 600
    If (InitNetwork())
      *Buffer = ReceiveHTTPMemory("captive.apple.com", #PB_HTTP_NoRedirect)
    EndIf
  CompilerElse
    *Buffer = ReceiveHTTPMemory("captive.apple.com", #PB_HTTP_NoRedirect)
  CompilerEndIf
  If (*Buffer)
    Connected = Bool(FindString(PeekS(*Buffer, MemorySize(*Buffer), #PB_Ascii), "Success"))
    FreeMemory(*Buffer)
  EndIf
  ProcedureReturn Connected
EndProcedure

Debug IsConnectedToInternet()

Code: Select all

#FLAG_ICC_FORCE_CONNECTION = 1

If InternetCheckConnection_(@"http://www.google.com",#FLAG_ICC_FORCE_CONNECTION,0) = 1
   Debug "OK"
Else
   Debug "NO"
EndIf

Code: Select all

;- mk-soft May 17, 2021

; INTERNET_CONNECTION_CONFIGURED; 0x40
; Local system has a valid connection to the Internet, but it might or might not be currently connected.
; INTERNET_CONNECTION_LAN; 0x02
; Local system uses a local area network to connect to the Internet.

; INTERNET_CONNECTION_MODEM; 0x01
; Local system uses a modem to connect to the Internet.

; INTERNET_CONNECTION_MODEM_BUSY; 0x08
; No longer used.

; INTERNET_CONNECTION_OFFLINE; 0x20
; Local system is in offline mode.

; INTERNET_CONNECTION_PROXY; 0x04
; Local system uses a proxy server to connect to the Internet.

; INTERNET_RAS_INSTALLED; 0x10
; Local system has RAS installed.

lpdwFlags.l
r1 = InternetGetConnectedState_(@lpdwFlags, 0)
If r1
  Debug "Online"
Else
  Debug "Offline"
EndIf

Debug "Flags: 0x" + Hex(lpdwFlags)

Code: Select all

Procedure.i IsConnectedToInternet()
  
  Protected.i Connected, HTTPRequest
  
  HTTPTimeout(1000)
  HTTPRequest = HTTPRequest(#PB_HTTP_Get, "https://captive.apple.com", "", #PB_HTTP_HeadersOnly|#PB_HTTP_NoSSLCheck)
  If HTTPRequest
    Connected = #True
    FinishHTTP(HTTPRequest)
  EndIf
  ProcedureReturn Connected
EndProcedure

Debug IsConnectedToInternet()

Code: Select all

Procedure.i IsConnectedToInternet()
  
  Protected.i Connection
  
  Connection = OpenNetworkConnection("captive.apple.com", 443, #PB_Network_TCP, 500)
  If Connection
    CloseNetworkConnection(Connection)
  EndIf
  
  ProcedureReturn Connection
  
EndProcedure

If IsConnectedToInternet()
  Debug "Connected"
Else
  Debug "Not connected"
EndIf