PureBasic Forums - English

http://www.purebasic.com
https://www.purebasic.fr/english/

SplitterGadget with PanelGadget Flickering problem [Resolved]

https://www.purebasic.fr/english/viewtopic.php?t=84390

Page 1 of 1

SplitterGadget with PanelGadget Flickering problem [Resolved]

Posted: Mon May 27, 2024 11:48 am
by tatanas
Hi,

I read a lot of posts about flickering gadgets when resizing window but nothing to fix Panel gadget as child of a splitter gadget.

Here is a sample :

Code: Select all

Enumeration Gadgets
	#Splitter
	#listicon
	#panel
	#str1
	#str2
	#str3
	#str4
EndEnumeration

Procedure BindSplitterV()
	Static SplitterPos
	Protected Position = GetGadgetState(EventGadget())
	If SplitterPos <> Position
		SplitterPos = Position
		;UpdateWindow_(GadgetID(#listicon))
		;UpdateWindow_(GadgetID(#panel))
	EndIf
EndProcedure


OpenWindow(0, 0, 0, 400, 400, "Splitter", #PB_Window_SystemMenu|#PB_Window_MinimizeGadget|#PB_Window_MaximizeGadget|#PB_Window_SizeGadget|#PB_Window_ScreenCentered)
ListIconGadget(#listicon, 5, 5, 150, 200, "col1", 100)
PanelGadget(#panel, 0, 0, 200, 200)
AddGadgetItem (#panel, -1, "Panel 1")
StringGadget(#str1, 5, 5, 100, 25, "string one")
StringGadget(#str2, 5, 35, 100, 25, "string two")
StringGadget(#str3, 5, 65, 100, 25, "string three")
StringGadget(#str4, 5, 95, 100, 25, "string four")
AddGadgetItem (#panel, -1, "Panel 2")
AddGadgetItem (#panel, -1, "Panel 3")
CloseGadgetList()

SplitterGadget(#Splitter, 5, 5, 390, 390, #listicon, #panel, #PB_Splitter_Vertical)
BindGadgetEvent(#Splitter, @BindSplitterV())

; SetWindowLongPtr_(GadgetID(#Splitter), #GWL_EXSTYLE, GetWindowLongPtr_(GadgetID(#Splitter), #GWL_EXSTYLE) | #WS_EX_COMPOSITED)
; SetWindowLongPtr_(GadgetID(#Splitter), #GWL_STYLE, GetWindowLongPtr_(GadgetID(#Splitter), #GWL_STYLE) | #WS_CLIPSIBLINGS | #WS_CLIPCHILDREN)

While WaitWindowEvent() <> #PB_Event_CloseWindow : Wend
As you can see, the listicon and the columns name of the Panel are flickering when we move the splitter.
Uncommenting
UpdateWindow_(GadgetID(#listicon))
fixes the Listicon.
Uncommenting
UpdateWindow_(GadgetID(#panel))
doesn't fix the Panel.

#WS_EX_COMPOSITED and #WS_CLIPSIBLINGS | WS_CLIPCHILDREN fix the Panel flickering but some drawing problem appears with the StringGadgets.

Is there a way to fix this ?

Thanks for your time.

Re: SplitterGadget with PanelGadget Flickering problem

Posted: Mon May 27, 2024 6:21 pm
by Justin
The new two SetWindowLongPtr_() versions get rid of the panel flickering, here, you will have to use

Code: Select all

SetWindowLongPtr_(GadgetItemID(#panel, 0), #GWL_STYLE, GetWindowLongPtr_(GadgetItemID(#panel, 0), #GWL_STYLE) | #WS_CLIPSIBLINGS | #WS_CLIPCHILDREN)
On enery panel item.
I don't see any listicon flickering here.

Code: Select all

Enumeration Gadgets
	#Splitter
	#listicon
	#panel
	#str1
	#str2
	#str3
	#str4
EndEnumeration

Procedure BindSplitterV()
	Static SplitterPos
	Protected Position = GetGadgetState(EventGadget())
	If SplitterPos <> Position
		SplitterPos = Position
		;UpdateWindow_(GadgetID(#listicon))
		;UpdateWindow_(GadgetID(#panel))
	EndIf
EndProcedure


OpenWindow(0, 0, 0, 400, 400, "Splitter", #PB_Window_SystemMenu|#PB_Window_MinimizeGadget|#PB_Window_MaximizeGadget|#PB_Window_SizeGadget|#PB_Window_ScreenCentered)
; SmartWindowRefresh(0, #True)
ListIconGadget(#listicon, 5, 5, 150, 200, "col1", 100)
PanelGadget(#panel, 0, 0, 200, 200)
AddGadgetItem (#panel, -1, "Panel 1")
StringGadget(#str1, 5, 5, 100, 25, "string one")
StringGadget(#str2, 5, 35, 100, 25, "string two")
StringGadget(#str3, 5, 65, 100, 25, "string three")
StringGadget(#str4, 5, 95, 100, 25, "string four")
AddGadgetItem (#panel, -1, "Panel 2")
AddGadgetItem (#panel, -1, "Panel 3")
CloseGadgetList()

SplitterGadget(#Splitter, 5, 5, 390, 390, #listicon, #panel, #PB_Splitter_Vertical)
BindGadgetEvent(#Splitter, @BindSplitterV())

SetWindowLongPtr_(GadgetID(#panel), #GWL_EXSTYLE, GetWindowLongPtr_(GadgetID(#Splitter), #GWL_EXSTYLE) | #WS_EX_COMPOSITED)
SetWindowLongPtr_(GadgetItemID(#panel, 0), #GWL_STYLE, GetWindowLongPtr_(GadgetItemID(#panel, 0), #GWL_STYLE) | #WS_CLIPSIBLINGS | #WS_CLIPCHILDREN)

While WaitWindowEvent() <> #PB_Event_CloseWindow : Wend

Re: SplitterGadget with PanelGadget Flickering problem

Posted: Wed May 29, 2024 7:30 am
by tatanas
Thank you very much. It's working.

Meanwhile, I read some explanations about the Panel Gadget which uses a static control. So I try this code and it's working fine too :

Code: Select all

SetWindowLongPtr_(GadgetID(#panel), #GWL_EXSTYLE, GetWindowLongPtr_(GadgetID(#panel), #GWL_EXSTYLE) | #WS_EX_COMPOSITED)
hStatic = FindWindowEx_(GadgetID(#panel), 0, "Static", 0)
SetWindowLong_(hStatic, #GWL_STYLE, GetWindowLong_(hStatic, #GWL_STYLE) | #WS_CLIPCHILDREN)

Re: SplitterGadget with PanelGadget Flickering problem [Resolved]

Posted: Wed May 29, 2024 8:25 am
by Justin
That will work too, but they introduced GadgetItemID(#panel, panelItem) for that, i think it's a better option, maybe they will change the static for another control, GadgetItemID() will always work.

Re: SplitterGadget with PanelGadget Flickering problem

Posted: Wed May 29, 2024 12:05 pm
by boddhi
Salut,
tatanas wrote: SetWindowLong_(hStatic, #GWL_STYLE, GetWindowLong_(hStatic, #GWL_STYLE) | #WS_CLIPCHILDREN)[/code]
If you want to ensure compatibility between x32 and x64 systems, always opt for

Code: Select all

SetWindowLongPtr_()
instead of

Code: Select all

SetWindowLong_()
:wink:

Re: SplitterGadget with PanelGadget Flickering problem

Posted: Wed May 29, 2024 4:56 pm
by ChrisR
Justin wrote: Mon May 27, 2024 6:21 pm The new two SetWindowLongPtr_() versions get rid of the panel flickering, here, you will have to use

Code: Select all

SetWindowLongPtr_(GadgetID(#panel), #GWL_EXSTYLE, GetWindowLongPtr_(GadgetID(#Splitter), #GWL_EXSTYLE) | #WS_EX_COMPOSITED)
SetWindowLongPtr_(GadgetItemID(#panel, 0), #GWL_STYLE, GetWindowLongPtr_(GadgetItemID(#panel, 0), #GWL_STYLE) | #WS_CLIPSIBLINGS | #WS_CLIPCHILDREN)
On enery panel item.
Thanks, good to know for all GadgetItemID, it works well and without flickering with the double buffer :)

Re: SplitterGadget with PanelGadget Flickering problem [Resolved]

Posted: Mon Jun 03, 2024 2:59 pm
by tatanas
I didn't notice at first glance but the CPU usage is huge (25% = 1 core) as soon as #WS_EX_COMPOSITED is used !
I can't use this anti flickering fix because of that :cry:

Re: SplitterGadget with PanelGadget Flickering problem [Resolved]

Posted: Mon Jun 03, 2024 10:25 pm
by Justin
You can apply the style only when the splitter is moved or the main window is resized:

Code: Select all

EnableExplicit

Enumeration Gadgets
	#Splitter
	#listicon
	#panel
	#str1
	#str2
	#str3
	#str4
EndEnumeration

Global.i g_oldTabProc

Procedure BindSplitterV()
	Static SplitterPos
	Protected Position = GetGadgetState(EventGadget())
	Debug Event()
	If SplitterPos <> Position
		SplitterPos = Position
		;UpdateWindow_(GadgetID(#listicon))
		;UpdateWindow_(GadgetID(#panel))
	EndIf
EndProcedure

Procedure.i tabProc(hwnd.i, msg.l, wparam.i, lparam.i)
	Select msg
		Case #WM_LBUTTONDOWN
			SetWindowLong_(GadgetID(#panel), #GWL_EXSTYLE, GetWindowLong_(GadgetID(#panel), #GWL_EXSTYLE) | #WS_EX_COMPOSITED)
		
		Case #WM_LBUTTONUP
			SetWindowLong_(GadgetID(#panel), #GWL_EXSTYLE, GetWindowLong_(GadgetID(#panel), #GWL_EXSTYLE) & ~#WS_EX_COMPOSITED)
	EndSelect
	
	ProcedureReturn CallWindowProc_(g_oldTabProc, hwnd, msg, wparam, lparam)
EndProcedure

Procedure mainWndProc(hwnd.i, msg.i, wparam.i, lparam.i)
	Select msg
		Case #WM_ENTERSIZEMOVE
			SetWindowLong_(GadgetID(#panel), #GWL_EXSTYLE, GetWindowLong_(GadgetID(#panel), #GWL_EXSTYLE) | #WS_EX_COMPOSITED)
	
		Case #WM_EXITSIZEMOVE
			SetWindowLong_(GadgetID(#panel), #GWL_EXSTYLE, GetWindowLong_(GadgetID(#panel), #GWL_EXSTYLE) & ~#WS_EX_COMPOSITED)
	EndSelect
	
	ProcedureReturn #PB_ProcessPureBasicEvents 
EndProcedure

Procedure wndOnSize()
	ResizeGadget(#Splitter, 0, 0, WindowWidth(0), WindowHeight(0))
EndProcedure

OpenWindow(0, 0, 0, 400, 400, "Splitter", #PB_Window_SystemMenu|#PB_Window_MinimizeGadget|#PB_Window_MaximizeGadget|#PB_Window_SizeGadget|#PB_Window_ScreenCentered)
SetWindowCallback(@mainWndProc(), 0)
BindEvent(#PB_Event_SizeWindow, @wndOnSize())
; SmartWindowRefresh(0, #True)
ListIconGadget(#listicon, 5, 5, 150, 200, "col1", 100)
PanelGadget(#panel, 0, 0, 200, 200)
AddGadgetItem (#panel, -1, "Panel 1")
StringGadget(#str1, 5, 5, 100, 25, "string one")
StringGadget(#str2, 5, 35, 100, 25, "string two")
StringGadget(#str3, 5, 65, 100, 25, "string three")
StringGadget(#str4, 5, 95, 100, 25, "string four")
AddGadgetItem (#panel, -1, "Panel 2")
AddGadgetItem (#panel, -1, "Panel 3")
CloseGadgetList()

SplitterGadget(#Splitter, 5, 5, 390, 390, #listicon, #panel, #PB_Splitter_Vertical)
; BindGadgetEvent(#Splitter, @BindSplitterV())

g_oldTabProc = SetWindowLongPtr_(GadgetID(#Splitter), #GWLP_WNDPROC, @tabProc())
SetWindowLong_(GadgetItemID(#panel, 0), #GWL_STYLE, GetWindowLong_(GadgetItemID(#panel, 0), #GWL_STYLE) | #WS_CLIPSIBLINGS | #WS_CLIPCHILDREN)

While WaitWindowEvent() <> #PB_Event_CloseWindow : Wend

Re: SplitterGadget with PanelGadget Flickering problem [Resolved]

Posted: Tue Jun 04, 2024 6:54 am
by tatanas
Nice trick. Thank you.
It's removing the cpu usage but the StringGadget got black background as soon as we move or resize the gui.

Do we know why the cpu usage is so high when #WS_EX_COMPOSITED is used ? Is it a bug ?

Re: SplitterGadget with PanelGadget Flickering problem [Resolved]

Posted: Tue Jun 04, 2024 11:29 pm
by ChrisR
Thanks for pointing out the CPU usage, around 20% here with Justin's 1st code, too bad it worked fine with just 2 SetWindowLongPtr.
The 2nd code works well here, without the string black background, it's disturbing not to have the same result.
Is there a way of degrading display performance to be able to better test for all configs?

Re: SplitterGadget with PanelGadget Flickering problem [Resolved]

Posted: Wed Jun 05, 2024 7:16 am
by tatanas
It seems the String black background problem is not present in PB 6.10 (It is in 6.04. I will verify again this evening).
Is this flickering problem because of the way Purebasic is handling the Splitter or the Panel ?

Re: SplitterGadget with PanelGadget Flickering problem [Resolved]

Posted: Wed Jun 05, 2024 12:34 pm
by Axolotl
Just my 2 cents.
I would not blame PureBasic for the flickering.
This flickering problem is also discussed in many other forums.
Mainly it was written about the same window styles and clearing the background (WM_ERASEBKGND) according to the WNDCLASS.
IMO it is the stack of controls like parent window -> child window -> child window and so on. (as you know: all controls (gadgets) are treated as windows)
The mechanism of the system cannot recognize the chain of dependencies and DoubleBuffer (WS_EX_COMPOSITED) requires more memory copies, which leads to higher CPU utilization.
My recommendation for myself: keep going and try to do better.
All times are UTC+01:00
Page 1 of 1

Powered by phpBB® Forum Software © phpBB Limited