PureBasic Forums - English

Code: Select all

{
    /*
     * Sweet section
     */
    "fruit": "Watermelon", // Yes, watermelons is sweet!
    "dessert": /* Yummy! */ "Cheesecake",
    // And finally
    "drink": "Milkshake - /* strawberry */ or // chocolate!" // Mmm...
}

Code: Select all

EnableExplicit

Procedure.s StripJsonc(jsonc.s)
  #CHAR_ASTERISK = 42
  #CHAR_DQOUTES = 34
  #CHAR_SLASH = 47
  #CHAR_BACKSLASH = 92
  
  #SINGLE_COMMENT = 1
  #MULTI_COMMENT = 2
  
  Protected *buffer.Character, *begin, *current.Character, *next.Character, *tmp.Character, inComment, inString, json.s, count  

  *buffer.Character = AllocateMemory(StringByteLength(jsonc), #PB_Memory_NoClear)
  *begin = *buffer
  *current.Character = @jsonc
  *next.Character = *current + SizeOf(Character)
  inComment = #False
  inString = #False
  
  While *current\c
    If Not inComment And *current\c = #CHAR_DQOUTES
      count = 0
      *tmp = *current - SizeOf(Character)
      
      While *tmp\c = #CHAR_BACKSLASH
        count + 1
        *tmp - SizeOf(Character)
      Wend  
      
      If Not Bool(count % 2)
        inString = Bool(Not inString)  
      EndIf
    EndIf  
    
    If inString
      Goto copy
    EndIf
    
    If Not inComment And *current\c = #CHAR_SLASH And *next\c = #CHAR_SLASH
      inComment = #SINGLE_COMMENT
      *current + SizeOf(Character)
      Goto loop
    ElseIf inComment = #SINGLE_COMMENT And *current\c = #CR And *next\c = #LF
      inComment = #False
    ElseIf inComment = #SINGLE_COMMENT And *current\c = #LF
      inComment = #False
    ElseIf Not inComment And *current\c = #CHAR_SLASH And *next\c = #CHAR_ASTERISK
      inComment = #MULTI_COMMENT
      *current + SizeOf(Character)
      Goto loop
    ElseIf inComment = #MULTI_COMMENT And *current\c = #CHAR_ASTERISK And *next\c = #CHAR_SLASH
      inComment = #False
      *current + SizeOf(Character)
      Goto loop
    EndIf  
    
    If Not inComment  
      copy:
      *buffer\c = *current\c
      *buffer + SizeOf(Character)  
    EndIf
    
    loop:
    *current + SizeOf(Character)
    *next = *current + SizeOf(Character)
  Wend
  json = PeekS(*begin)
  FreeMemory(*begin)
  ProcedureReturn json
EndProcedure


DataSection
  DataStart:
  IncludeBinary "jsonc.txt"
  DataEnd:
EndDataSection


Define jsonc.s = PeekS(?DataStart,?DataEnd-?DataStart,#PB_UTF8)
Define json.s = StripJsonc(jsonc)
If Not ParseJSON(0, json)    
  Debug JSONErrorMessage()
  End 1
EndIf  

Debug ComposeJSON(0, #PB_JSON_PrettyPrint)
FreeJSON(0)