PureBasic Forums - English

Code: Select all

;/////////////////////////////////////////////////////////////////////////////////
;***COMate***  COM automation through iDispatch.
;*===========
;*
;*Search and replace in a Word document - by srod.
;/////////////////////////////////////////////////////////////////////////////////

IncludePath "..\"
XIncludeFile "COMatePLUS.pbi"

Define WordApplication.COMateObject 

#wdReplaceAll  = 2
  
inputDoc$ = "c:\testIN.doc"
outputDoc$ = "c:\testOUT.doc"

search$ = "is"
replace$ = "IS"


WordApplication = COMate_CreateObject("Word.Application") 
    
If WordApplication 
  If WordApplication\Invoke("Documents\Open('" + inputDoc$ + "')") = #S_OK 
    WordApplication\Invoke("Selection\GoTo(1)")
    WordApplication\SetProperty("Selection\Find\MatchWholeWord = #True")
    WordApplication\SetProperty("Selection\Find\Forward = #True")
    WordApplication\SetProperty("Selection\Find\Text = '" + search$ + "'")
    WordApplication\Invoke("Selection\Find\Execute(#Opt, #Opt, #Opt, #Opt, #Opt, #Opt, #Opt, #Opt, #Opt, '" + replace$ + "', " + Str(#wdReplaceAll) + ")")
    WordApplication\Invoke("ActiveDocument\SaveAs('" + outputDoc$ + "')")
    WordApplication\Invoke("Quit(0)") 
  Else 
    MessageRequester("COMate -search and replace text in word document!", "Couldn't load the document!")
  EndIf 
  WordApplication\Release() 
Else 
  MessageRequester("COMate -search and replace text in word document!", "Couldn't create the application object!")
EndIf
;

Code: Select all

IS this a good paragraph?
Comate plus IS good.
Sometimes I think it IS not a good example for all good people of earth. Other times it IS a good example , but this being a simple paragraph, I cannot think of another sentence with IS.
Also IS this a paragraph, yes it IS.

Code: Select all

EnableExplicit

; See https://learn.microsoft.com/en-us/office/vba/api/office.msoshapetype
#msoTextBox = 17 

; See https://learn.microsoft.com/en-us/office/vba/api/word.wdreplace
#wdReplaceAll = 2
#wdReplaceNone = 0
#wdReplaceOne = 1

IncludeFile "COMatePlus.pbi"

Define.COMateObject appWord, docThis, objShape, objTextRange
Define.COMateEnumObject colShapes
Define.I ShapeType
Define.S strCommand, strFind, strReplace

strFind = "ReplaceThis"
strReplace ="WithThis"

; Obtain an application object.
appWord = COMate_CreateObject("Word.Application")

If appWord = 0
  Debug "Failed to create application object."
  Debug COMate_GetLastErrorDescription()
  End
EndIf

appWord\SetProperty("Application\Visible=#True")
Debug "Visible:" + COMate_GetLastErrorDescription()

; Open the document.
strCommand = "Documents\Open('c:\testIN.doc')"
docThis = appWord\GetObjectProperty(strCommand)
If docThis = 0
  Debug "Failed to open the document."
  Debug COMate_GetLastErrorDescription()
  End
EndIf

; Get the shapes collection.
colShapes = docThis\CreateEnumeration("Shapes")
If colShapes = 0
  Debug "Failed to get the shapes collection."
  Debug COMate_GetLastErrorDescription()
  End
EndIf

; Start iteration.
objShape = colShapes\GetNextObject()
While objShape
  ShapeType = objShape\GetIntegerProperty("Type")
  Debug "Type: " +COMate_GetLastErrorDescription()
  
  If ShapeType = #msoTextBox
    
    ; Find and replace.
    ; See https://learn.microsoft.com/en-us/office/vba/api/word.find.execute
    objTextRange = objShape\GetObjectProperty("TextFrame\TextRange")
    Debug "TextFrame\TextRange: " + COMate_GetLastErrorDescription()
    strCommand = "Find\Execute('" + strFind + "', #Opt, #Opt, #Opt, #Opt, #Opt, #Opt, #Opt, #Opt, " + 
                 "'" + strReplace + "', " + StrU(#wdReplaceAll) + ", #Opt, #Opt, #Opt, #Opt)"
    objTextRange\Invoke(strCommand)
    Debug "Find\Execute : " + COMate_GetLastErrorDescription()
    
  EndIf
  
  ; Next iteration.
  objTextRange\Release()
  objShape\Release()
  objShape = colShapes\GetNextObject()
Wend

; Tidy up
colShapes\Release()
docThis\Release()
appWord\Release()

Code: Select all

appWord\SetProperty("Application\ScreenUpdating=#False")

Code: Select all

appWord\SetProperty("Application\ScreenUpdating=#True")

Code: Select all

appWord\SetProperty("Application\Visible=#False")