PureBasic Forums - English

Code: Select all

; test_server.pb

EnableExplicit

Procedure ProcessRequest(connectNumber.i)

    Protected result.l
    Protected length.i
    Protected *memoryLocation
    Protected memLength.i    = 32767
    Protected lastRecv.i     = Date()
    Protected doNotExit.i    = #True
    Protected socketHandle.i = ConnectionID(connectNumber)

    PrintN("Client " + Str(connectNumber) + " connected")

    *memoryLocation = AllocateMemory(memLength)

; loop until we have received data, or our timeout has been exceeded

    While doNotExit
        result = ioctlsocket_(socketHandle, #FIONREAD, @length)
        If result = 0 And length > 0
            Debug "result = " + Str(result) + ", length received Data = " + Str(length)
            result = ReceiveNetworkData(connectNumber.i, *memoryLocation, memLength.i)
            Select result
            Case 1 To 32767
                PrintN("Client " + Str(connectNumber) + " received " + PeekS(*memoryLocation, result))
            Case 0
            Default
                PrintN("Client " + Str(connectNumber) + " received socket error:" + Str(result) + ", " + Str(WSAGetLastError_()))
                doNotExit = #False
            EndSelect

            If Date() - lastRecv > 5
                doNotExit = #False
            EndIf
        ElseIf result = 0 And length = 0
            Delay(100)
        Else
            PrintN("Client " + Str(connectNumber) + " received socket error:" + Str(result) + ", " + Str(WSAGetLastError_()))
            doNotExit = #False
        EndIf
    Wend

    FreeMemory(*memoryLocation)

EndProcedure

Define NSEvent.i
Define keyPressed.s
Define portNumber.i
Define portString.s
Define thisClient.i
Define serverNumber.i
Define socketHandle.i

OpenConsole("Network Server Tester, Build:" + #PB_Editor_BuildCount)

PrintN("")
Print("Enter the server port number you wish to spawn: ")
portString = Input()
If portString = ""
    CloseConsole()
    End
EndIf

portNumber = Val(portString)
If portNumber < 1 Or portNumber > 65535
    PrintN("Invalid port number entered: " + portString)
    Input()
    CloseConsole()
    End
EndIf

serverNumber = CreateNetworkServer(#PB_Any, portNumber)
If serverNumber < 1
    PrintN("Unable to spawn a server to port " + Str(portNumber))
    Input()
    End
EndIf

PrintN("Started Network Server on port " + Str(portNumber))

Repeat
    NSEvent = NetworkServerEvent()  ; if we receive data, it will be indicated here

    Select NSEvent
    Case #PB_NetworkEvent_Connect   ; a socket has connected
    Case #PB_NetworkEvent_Data      ; raw data has been received
        thisClient   = EventClient()  ; get the event client identifier
        socketHandle = ConnectionID(thisClient)
        PrintN("Received client connection from: " + IPString(GetClientIP(thisClient)))
        ProcessRequest(thisClient)  ; procedure to process incoming data
        Break
    Case #PB_NetworkEvent_Disconnect; a socket disconnected
    Default                         ; no server event occurred
        Delay(100)                  ; sleep so we don't hammer the processor
    EndSelect

    keyPressed = Inkey()
ForEver

PrintN("Exiting loop, will close the socket")
closesocket_(socketHandle)
PrintN("Returned from closing the socket, will attempt to close the server")
CloseNetworkServer(serverNumber)
PrintN("Returned from closing the server, will now end the progam")
CloseConsole()
Input()

End
; IDE Options = PureBasic 6.02 LTS (Windows - x64)
; ExecutableFormat = Console
; CursorPosition = 40
; FirstLine = 30
; Executable = test_server.exe
; DisableDebugger
; HideErrorLog
; CurrentDirectory = D:\dev\PureBasic\temp\
; CompileSourceDirectory
; EnableCompileCount = 1
; EnableBuildCount = 1
; EnableExeConstant

Code: Select all

; test_client.pb

EnableExplicit

Define length.i
Define result.i
Define errNumber.i
Define lenSendText.i
Define serverName.s
Define stringText.s
Define portNumber.i
Define portString.s
Define connectNumber.i
Define socketHandle.i
Define memLength.i = 10000
Define *memoryLocation = AllocateMemory(memLength + 1)

OpenConsole("Network Client Tester, Build:" + #PB_Editor_BuildCount)

PrintN("")
Print("Enter the IP Address or name of the server, or press <enter> for local host: ")
serverName = Input()
If  serverName = ""
    serverName = "localhost"
EndIf

Print("Enter the port number to connect to: ")
portString = Input()
If portString = ""
    CloseConsole()
    End
EndIf

portNumber = Val(portString)
If portNumber < 1 Or portNumber > 65535
    PrintN("Invalid port number entered: " + portString)
    Input()
    CloseConsole()
    End
EndIf

PrintN("Attempting to connect to Network Server at " + serverName + " on port " + Str(portNumber))

connectNumber = OpenNetworkConnection(serverName, portNumber)

If connectNumber < 1
    errNumber = WSAGetLastError_()
    PrintN("Unable to connect to localhost, port " + Str(portNumber))
    PrintN("Winsock error = " + Str(errNumber))
Else
    socketHandle = ConnectionID(connectNumber)

    Repeat
        result = ioctlsocket_(socketHandle, #FIONREAD, @length)
        Debug "result = " + Str(result) + ", length received Data = " + Str(length)
        If result = 0 And length > 0
            result = ReceiveNetworkData(connectNumber, *memoryLocation, memLength)
            If result > 0
                PrintN("Received: " + PeekS(*memoryLocation, result))
            ElseIf result < 0
                PrintN("Received error " + Str(result) + ", " + WSAGetLastError_())
                Break
            EndIf
        ElseIf result <> 0
            PrintN("Received error " + Str(result) + ", " + WSAGetLastError_())
            Break
        EndIf

        stringText  = Input()
        lenSendText = StringByteLength(stringText)
        If lenSendText
            stringText  + #CRLF$
            lenSendText + 2
            result = SendNetworkData(connectNumber, @stringText, lenSendText)
            If result <> lenSendText
                PrintN("Received error " + Str(result) + ", " + WSAGetLastError_())
                Break
            EndIf
        EndIf
        Debug "lenSendText = " + Str(lenSendText)
    ForEver

    CloseNetworkConnection(connectNumber)

    PrintN("Network sending complete, Press <enter> to exit")
EndIf

Input()

CloseConsole()

End
; IDE Options = PureBasic 6.02 LTS (Windows - x64)
; ExecutableFormat = Console
; CursorPosition = 69
; FirstLine = 18
; Executable = test_client.exe
; DisableDebugger
; HideErrorLog
; CurrentDirectory = \
; CompileSourceDirectory
; EnableCompileCount = 1
; EnableBuildCount = 1
; EnableExeConstant