PureBasic Forums - English

Oso wrote: Wed Feb 15, 2023 12:33 pmNevertheless, I'm curious about the concept of asynchronous callbacks. The below might suggest it would commence inside a thread, but thought I'd seek others' ideas on how you interpret this term.

mk-soft wrote: Wed Feb 15, 2023 3:31 pm An example asynchon callback under Linux is the libwebkit2gtk to get the HTML code. See WebKit_GetHtmlCode.

Oso wrote: Thu Feb 16, 2023 11:15 pm This is going to have to be something I come back to at some point. I'd love to run your GTK example but just wish that I had the time to set up Ubuntu and PB My Linux systems are all CentOS and Manjaro.

idle wrote: Fri Feb 17, 2023 8:20 pm call backs offer versatility they can be used synchronously or asynchronously. They provide a nice way to interleave events. For instance rather than processing and populating and returning a list or an array to a user you can use a callback function so the program only does one parse of the data. Say you're transforming data from a map into a list or array that's the time to consider a callback otherwise you would walk the map to populate the list of results and then the user would parse that list again. So it like N vs 2N plus the allow users to adapt the code.

A callback is a function passed as an argument to another function.

JavaScript Callbacks

Using a callback, you could call the calculator function (myCalculator) with a callback (myCallback), and let the calculator function run the callback after the calculation is finished — Example :

function myDisplayer(some) {
  document.getElementById("demo").innerHTML = some;
}

function myCalculator(num1, num2, myCallback) {
  let sum = num1 + num2;
  myCallback(sum);
}

myCalculator(5, 5, myDisplayer);

mk-soft wrote: Sat Feb 18, 2023 3:59 pm Example with callback parameter ... (synchron callback)

Code: Select all

;-TOP

#ProgramTitle = "Main Window"
#ProgramVersion = "v1.01.2"

Enumeration Windows
  #Main
EndEnumeration

Enumeration MenuBar
  #MainMenu
EndEnumeration

Enumeration MenuItems
  #MainMenuAbout
  #MainMenuExit
EndEnumeration

Enumeration Gadgets
  #MainList
  #MainButton1
  #MainButton2
EndEnumeration

Enumeration StatusBar
  #MainStatusBar
EndEnumeration

; ----

Prototype protoDisplayCB(Value)

Procedure myDisplayListCB(Value)
  AddGadgetItem(#MainList, -1, "Result = " + Value)
EndProcedure

Procedure myDisplayStatusCB(Value)
  StatusBarText(#MainStatusBar, 0, "Result = " + Value)
EndProcedure

Procedure myCalculater(Value1, Value2, *Callback.protoDisplayCB)
  Protected result
  
  result = Value1 * Value2
  *Callback(result)
EndProcedure

; ----

Procedure UpdateWindow()
  Protected dx, dy
  dx = WindowWidth(#Main)
  dy = WindowHeight(#Main) - StatusBarHeight(#MainStatusBar) - MenuHeight()
  ; Resize gadgets
  ResizeGadget(#MainList, 5, 5, dx - 10, dy - 45)
  ResizeGadget(#MainButton1, 10, dy - 35, 120, 30)
  ResizeGadget(#MainButton2, dx - 130, dy - 35, 120, 30)
EndProcedure

Procedure Main()
  Protected dx, dy, value
  
  #MainStyle = #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_MaximizeGadget | #PB_Window_MinimizeGadget
  
  If OpenWindow(#Main, #PB_Ignore, #PB_Ignore, 800, 600, #ProgramTitle , #MainStyle)
    ; Menu
    CreateMenu(#MainMenu, WindowID(#Main))
    MenuTitle("&File")
    CompilerIf #PB_Compiler_OS = #PB_OS_MacOS
      MenuItem(#PB_Menu_About, "")
    CompilerElse
      MenuItem(#MainMenuAbout, "About")
    CompilerEndIf
    ; Menu File Items
    
    CompilerIf Not #PB_Compiler_OS = #PB_OS_MacOS
      MenuBar()
      MenuItem(#MainMenuExit, "E&xit")
    CompilerEndIf
    
    ; StatusBar
    CreateStatusBar(#MainStatusBar, WindowID(#Main))
    AddStatusBarField(#PB_Ignore)
    
    ; Gadgets
    dx = WindowWidth(#Main)
    dy = WindowHeight(#Main) - StatusBarHeight(#MainStatusBar) - MenuHeight()
    ListViewGadget(#MainList, 5, 5, dx -10, dy - 45)
    ButtonGadget(#MainButton1, 10, dy - 35, 120, 30, "Update List")
    ButtonGadget(#MainButton2, dx - 130, dy - 35, 120, 30, "Update Status")
    
    ; Bind Events
    BindEvent(#PB_Event_SizeWindow, @UpdateWindow(), #Main)
    
    ; Event Loop
    Repeat
      Select WaitWindowEvent()
        Case #PB_Event_CloseWindow
          Select EventWindow()
            Case #Main
              Break
              
          EndSelect
          
        Case #PB_Event_Menu
          Select EventMenu()
            CompilerIf #PB_Compiler_OS = #PB_OS_MacOS   
              Case #PB_Menu_About
                PostEvent(#PB_Event_Menu, #Main, #MainMenuAbout)
                
              Case #PB_Menu_Preferences
                
              Case #PB_Menu_Quit
                PostEvent(#PB_Event_CloseWindow, #Main, #Null)
                
            CompilerEndIf
            
          Case #MainMenuAbout
            MessageRequester("About", #ProgramTitle + #LF$ + #ProgramVersion, #PB_MessageRequester_Info)
              
          Case #MainMenuExit
            PostEvent(#PB_Event_CloseWindow, #Main, #Null)
            
          EndSelect
          
        Case #PB_Event_Gadget
          Select EventGadget()
            Case #MainButton1
              value + 1
              myCalculater(value, 10, @myDisplayListCB())
              
            Case #MainButton2
              myCalculater(value, 10, @myDisplayStatusCB())
              
          EndSelect
          
      EndSelect
    ForEver
    
  EndIf
  
EndProcedure : Main()

idle wrote: Sun Feb 19, 2023 12:08 am

mk-soft wrote: Sat Feb 18, 2023 3:59 pm Example with callback parameter ... (synchron callback)

Good example

mk-soft wrote: Sat Feb 18, 2023 3:59 pm Example with callback parameter ... (synchron callback)

myCalculater(value, 10, @myDisplayListCB())

Procedure myCalculater(Value1, Value2, *Callback.protoDisplayCB)

*Callback(result)

Prototypes — Description

For advanced programmers. Prototype allows to declare a type which will map a function

EnableExplicit

Procedure OutputResult(displayresult.i)
  Debug displayresult.i
EndProcedure

Procedure Calculate(param1.i, param2.i)
  Define result.i = param1.i * param2.i
  OutputResult(result.i)
EndProcedure

Calculate(2, 4)

I assume the following would not be considered a callback, because the procedure to call is not passed as an argument...

The question I have is whether we need to use a Prototype? To be honest, I'd deliberately left out Prototypes from my PB learning up to now and focus on the essentials, noting the below...