PureBasic Forums - English

Code: Select all

;Putins broken clock, any key to activate, esc to end 
;fair use claimed for the intro to the Final Countdown by Europe 
EnableExplicit 

InitSprite()
InitKeyboard() 
InitMouse() 
InitSound() 
UseOGGSoundDecoder()

Global font
Global event,ct,sc,bput=0
Global width, height 
Global snd,spath.s 

Procedure DisplayMessageCenter(window,msg.s,color=255,scale.f=1.00)
  
  Protected spriteNumber,tempImage,fontsTextWidth,fontsTextHeight,cx,cy
  
  tempImage = CreateImage(#PB_Any,1,1)    ;if you need to get the size of a font in pixels         
  
  If tempImage
    If StartDrawing(ImageOutput(tempImage)) ;draw to the temp image 
      DrawingFont(FontID(font))             ;with the selected font  
      fontsTextWidth = TextWidth(msg)       ;get the width and height in pixles     
      fontsTextHeight = TextHeight(msg)  
      StopDrawing()  
      spriteNumber = CreateSprite(#PB_Any,fontsTextWidth,fontsTextHeight) ;create the sprite of required size 
      If spriteNumber 
        If StartDrawing(SpriteOutput(spriteNumber))   ;now you can draw the text to the sprite 
          DrawingFont(FontID(font)) 
          DrawText(0,0,msg,color)
          StopDrawing()
          TransparentSpriteColor(spriteNumber,0)
          cx= (WindowWidth(window) - (fontsTextWidth*scale)) / 2   
          cy = (WindowHeight(window)- (fontsTextHeight*scale)) / 2        
          ZoomSprite(spriteNumber,fontsTextWidth*scale,fontsTextHeight*scale)  
          DisplayTransparentSprite(spriteNumber,cx,cy)
        EndIf   
        FreeSprite(spriteNumber)
      EndIf  
    EndIf  
    FreeImage(tempImage)      
  EndIf 
  
EndProcedure 

spath = GetTemporaryDirectory() + "countdown.ogg" 
If FileSize(spath) > 0 
  LoadSound(0,spath) 
ElseIf ReceiveHTTPFile("https://dnscope.io/idlefiles/countdown.ogg",spath) 
  LoadSound(0,spath) 
EndIf   
  
ExamineDesktops() 
width = DesktopWidth(0)
height = DesktopHeight(0) 

font = LoadFont(#PB_Any,"arial",height/8,#PB_Font_HighQuality)

OpenWindow(0,0,0,width,height,"Putin de merde clock",#PB_Window_ScreenCentered | #PB_Window_BorderLess) 
OpenWindowedScreen(WindowID(0),0,0,width,height) 

Repeat 
  Repeat 
    event=WindowEvent()
    If event=#PB_Event_CloseWindow
      End
    EndIf
  Until event=0
  
  ExamineKeyboard() 
  ExamineMouse() 
    
  If bput > 0   
    ClearScreen((ct%64)*2)
    DisplayMessageCenter(0,FormatDate("%hh:%ii:%ss", Date()-ct),RGB(0,192,0),0.025*sc)
    ct+1  
  Else 
    ClearScreen(0)
    DisplayMessageCenter(0,FormatDate("%hh:%ii:%ss", Date()),RGB(0,192,0))
    ct=0
  EndIf 
   
  sc+1 
  sc%60
  FlipBuffers()
  
  If KeyboardInkey()
    bput ! 1
    If bput 
      If IsSound(0) 
        PlaySound(0) 
      EndIf 
    ElseIf IsSound(0)   
      StopSound(0) 
    EndIf   
    
  EndIf  
  
Until KeyboardPushed(#PB_Key_Escape)     

Code: Select all

InitSprite()
InitKeyboard()
InitMouse()

OpenWindow(1,200,100,500,500,"Test",#PB_Window_SystemMenu)
;
OpenWindowedScreen(WindowID(1), 0, 0, 500, 500)

Repeat
  Repeat
    event = WindowEvent()
    If event = #PB_Event_CloseWindow
      End
    EndIf
  Until event = 0
  
  ClearScreen(RGB(0, 0, 0)) ;for black or RGB(255, 0, 0) for red
  
  FlipBuffers()
  
ForEver