PureBasic Forums - English

http://www.purebasic.com
https://www.purebasic.fr/english/

IsLatin, IsDigital, IsHex, IsFloat

https://www.purebasic.fr/english/viewtopic.php?t=79007

Page 1 of 1

IsLatin, IsDigital, IsHex, IsFloat

Posted: Mon Apr 18, 2022 10:55 am
by AZJIO
Instead of using a regular expression (\d, \w) that adds 150 KB to the size of the executable, you can use compact code.

Code: Select all

EnableExplicit

Procedure IsLatin(*text)
	Protected flag = #True, *c.Character = *text
	
	If *c = 0 Or *c\c = 0
		ProcedureReturn 0
	EndIf
	
	While *c\c
		If Not ((*c\c >= '0' And *c\c <= '9') Or (*c\c >= 'a' And *c\c <= 'z') Or (*c\c >= 'A' And *c\c <= 'Z') Or *c\c = '_')
			flag = #False
			Break
		EndIf
		*c + SizeOf(Character)
	Wend
	
	ProcedureReturn flag
EndProcedure

Debug IsLatin(@"123")
Debug IsLatin(@"12 3")
Debug IsLatin(@"qwerty")
Debug IsLatin(@"")
Debug IsLatin(@"  ")
Debug "==="


Procedure IsDigital(*text)
	Protected flag = #True, *c.Character = *text
	
	If *c = 0 Or *c\c = 0
		ProcedureReturn 0
	EndIf
	
	While *c\c
		If *c\c < '0' Or *c\c > '9'
			flag = #False
			Break
		EndIf
		*c + SizeOf(Character)
	Wend
	
	ProcedureReturn flag
EndProcedure

Debug IsDigital(@"123")
Debug IsDigital(@"12 3")
Debug IsDigital(@"")
Debug "==="


Procedure IsHex(*text)
	Protected flag = #True, *c.Character = *text
	
	If *c = 0 Or *c\c = 0
		ProcedureReturn 0
	EndIf
	
	While *c\c
		If Not ((*c\c >= '0' And *c\c <= '9') Or (*c\c >= 'a' And *c\c <= 'f') Or (*c\c >= 'A' And *c\c <= 'F'))
			flag = #False
			Break
		EndIf
		*c + SizeOf(Character)
	Wend
	
	ProcedureReturn flag
EndProcedure

Debug IsHex(@"123")
Debug IsHex(@"FF34FF")
Debug IsHex(@"")
Debug IsHex(@"  ")
Debug "==="


Procedure IsFloat(*text)
	Protected flag = #True, *c.Character = *text, sep = 0, increment = 1
	
	If *c = 0 Or *c\c = 0
		ProcedureReturn 0
	EndIf
	
	While *c\c
		If *c\c >= '0' And *c\c <= '9'
; 			Debug "-> 0-9"
			sep = increment
		ElseIf sep And *c\c = '.'
; 			Debug "-> ."
			If sep <= 0
; 				Debug "-> Out2"
				flag = #False
				Break
			EndIf
			sep = 0
			increment = -1
		Else
; 			Debug "-> Out"
			flag = #False
			Break
		EndIf
		*c + SizeOf(Character)
	Wend
	
	If sep <> -1
; 		Debug "-> Out3"
		flag = #False
	EndIf
	
	ProcedureReturn flag
EndProcedure

Debug IsFloat(@"1.2")
Debug IsFloat(@"1..2")
Debug IsFloat(@"1.2.3")
Debug IsFloat(@"1")
Debug IsFloat(@"1.")
Debug IsFloat(@".1")
Debug IsFloat(@"qwerty")
Debug IsFloat(@".")
Debug IsFloat(@"")

Re: IsLatin, IsDigital

Posted: Tue Apr 19, 2022 1:45 am
by idle
It's better to pass by reference so you don't copy the string

Code: Select all

Procedure IsLatin(*text)
	Protected flag = 1, *c.Character = *text
	
	While *c\c
		If Not ((*c\c >= '0' And *c\c <= '9') Or (*c\c >= 'a' And *c\c <= 'z') Or (*c\c >= 'A' And *c\c <= 'Z') Or *c\c = '_')
			flag = 0
			Break
		EndIf
		*c + SizeOf(Character)
	Wend
	
	ProcedureReturn flag
EndProcedure

Debug IsLatin(@"123")
Debug IsLatin(@"12 3")
Debug IsLatin(@"dfg")
Debug IsLatin(@"  ")


Procedure IsDigital(*text)
	Protected flag = 1, *c.Character = @text
	
	While *c\c
		If *c\c < '0' Or *c\c > '9'
			flag = 0
			Break
		EndIf
		*c + SizeOf(Character)
	Wend
	
	ProcedureReturn flag
EndProcedure

Debug IsDigital(@"123")
Debug IsDigital(@"12 3")

Re: IsLatin, IsDigital

Posted: Tue Apr 19, 2022 7:38 am
by juergenkulow
Sorry but there are 1475 Latin Charaters in Unicode. and
more 37 times 10 digits

Re: IsLatin, IsDigital

Posted: Tue Apr 19, 2022 9:13 am
by Rinzwind
juergenkulow wrote: Tue Apr 19, 2022 7:38 am Sorry but there are 1475 Latin Charaters in Unicode. and
more 37 times 10 digits
Well, can't handle everything. But yeah, accents are also not handled: é ë ê

Re: IsLatin, IsDigital

Posted: Tue Apr 19, 2022 2:29 pm
by AZJIO
Added to make empty string be 0

Code: Select all

If *c\c = 0
	ProcedureReturn 0
EndIf
Repeat-Until

Code: Select all

EnableExplicit

Procedure IsLatin(*text)
	Protected flag = #True, *c.Character = *text
	
	If *c = 0 Or *c\c = 0
		ProcedureReturn 0
	EndIf
	
	Repeat
		If Not ((*c\c >= '0' And *c\c <= '9') Or (*c\c >= 'a' And *c\c <= 'z') Or (*c\c >= 'A' And *c\c <= 'Z') Or *c\c = '_')
			flag = #False
			Break
		EndIf
		*c + SizeOf(Character)	
	Until Not *c\c
	
	ProcedureReturn flag
EndProcedure

Debug IsLatin(@"123")
Debug IsLatin(@"12 3")
Debug IsLatin(@"qwerty")
Debug IsLatin(@"")
Debug IsLatin(@"  ")
Debug "==="



Procedure IsDigital(*text)
	Protected flag = #True, *c.Character = *text
	
	If *c = 0 Or *c\c = 0
		ProcedureReturn 0
	EndIf
	
	Repeat
		If *c\c < '0' Or *c\c > '9'
			flag = #False
			Break
		EndIf
		*c + SizeOf(Character)	
	Until Not *c\c
	
	ProcedureReturn flag
EndProcedure

Debug IsDigital(@"123")
Debug IsDigital(@"12 3")
Debug IsDigital(@"")
Debug "==="


Procedure IsHex(*text)
	Protected flag = #True, *c.Character = *text
	
	If *c = 0 Or *c\c = 0
		ProcedureReturn 0
	EndIf
	
	Repeat
		If Not ((*c\c >= '0' And *c\c <= '9') Or (*c\c >= 'a' And *c\c <= 'f') Or (*c\c >= 'A' And *c\c <= 'F'))
			flag = #False
			Break
		EndIf
		*c + SizeOf(Character)	
	Until Not *c\c
	
	ProcedureReturn flag
EndProcedure

Debug IsHex(@"123")
Debug IsHex(@"FF34FF")
Debug IsHex(@"")
Debug IsHex(@"  ")
Debug "==="

Procedure IsFloat(*text)
	Protected flag = #True, *c.Character = *text, sep = 0, increment = 1
	
	If *c = 0 Or *c\c = 0
		ProcedureReturn 0
	EndIf
	
	Repeat
		If *c\c >= '0' And *c\c <= '9'
; 			Debug "-> 0-9"
			sep = increment
		ElseIf sep And *c\c = '.'
; 			Debug "-> ."
			If sep <= 0
; 				Debug "-> Out2"
				flag = #False
				Break
			EndIf
			sep = 0
			increment = -1
		Else
; 			Debug "-> Out"
			flag = #False
			Break
		EndIf
		*c + SizeOf(Character)	
	Until Not *c\c
	
	If sep <> -1
; 		Debug "-> Out3"
		flag = #False
	EndIf
	
	ProcedureReturn flag
EndProcedure

Debug IsFloat(@"1.2")
Debug IsFloat(@"1..2")
Debug IsFloat(@"1.2.3")
Debug IsFloat(@"1")
Debug IsFloat(@"1.")
Debug IsFloat(@".1")
Debug IsFloat(@"qwerty")
Debug IsFloat(@".")
Debug IsFloat(@"")

Re: IsLatin, IsDigital

Posted: Tue Apr 19, 2022 3:22 pm
by mk-soft
Its better

Code: Select all

	If *c = 0 Or *c\c = 0
		ProcedureReturn 0
	EndIf
because a string can be Nothing (NIL)

Re: IsLatin, IsDigital

Posted: Tue Apr 19, 2022 3:41 pm
by AZJIO

Code: Select all

EnableExplicit

Procedure IsFloat(*text)
	Protected flag = #True, *c.Character = *text, sep = 0, increment = 1
	
	If *c = 0 Or *c\c = 0
		ProcedureReturn 0
	EndIf
	
	Repeat
		If *c\c >= '0' And *c\c <= '9'
; 			Debug "-> 0-9"
			sep = increment
		ElseIf sep And *c\c = '.'
; 			Debug "-> ."
			If sep <= 0
; 				Debug "-> Out2"
				flag = #False
				Break
			EndIf
			sep = 0
			increment = -1
		Else
; 			Debug "-> Out"
			flag = #False
			Break
		EndIf
		*c + SizeOf(Character)	
	Until Not *c\c
	
	If sep <> -1
; 		Debug "-> Out3"
		flag = #False
	EndIf
	
	ProcedureReturn flag
EndProcedure

Debug IsFloat(@"1.2")
Debug IsFloat(@"1..2")
Debug IsFloat(@"1.2.3")
Debug IsFloat(@"1")
Debug IsFloat(@"1.")
Debug IsFloat(@".1")
Debug IsFloat(@"qwerty")
Debug IsFloat(@".")
Debug IsFloat(@"")
All times are UTC+01:00
Page 1 of 1

Powered by phpBB® Forum Software © phpBB Limited