PureBasic Forums - English

Code: Select all

; XL_Lite_Reader
; Read the First column of text of an Excel file
; (C)Marc56us - 2022/04/17
; In reply to: https://www.purebasic.fr/english/viewtopic.php?t=78990
; Only Excel >= 2007 (or compatible) 
; https://en.wikipedia.org/wiki/Microsoft_Excel#XML_Spreadsheet
; Adapt an use as you want. Enjoy :-)

EnableExplicit

Define XL_File$ = "c:\Tmp\Test.xlsx"

SetCurrentDirectory(GetPathPart(XL_File$))

If FileSize(XL_File$) < 1
  Debug "File " + XL_File$ + " Not Found"
  End
EndIf

If GetExtensionPart(XL_File$) <> "xlsx"
  Debug "Not an xlsx file. Use Office >= 2007"
  End
EndIf

Procedure Un_Zip(Zip$, File$)
  UseZipPacker()
  Global Tmp_File$
  If OpenPack(0, Zip$)
    While NextPackEntry(0)  
      Tmp_File$ = PackEntryName(0)
      If  Tmp_File$ = File$
        Tmp_File$ = GetFilePart(Tmp_File$)
        UncompressPackFile(0, Tmp_File$)
        ClosePack(0)
        ProcedureReturn
      EndIf
    Wend  
    ClosePack(0)
  Else
    Debug "Error in Zip"
  EndIf
EndProcedure

Procedure Get_Datas()
  Protected Txt$
  If Not ReadFile(0, Tmp_File$) : ProcedureReturn 2 : EndIf
  While Not Eof(0)
    Txt$ + ReadString(0, #PB_File_IgnoreEOL)
  Wend  
  CloseFile(0)
  Protected RegEx$ = ~"<t xml:space=\"preserve\">(.+?)</t>"
  If Not CreateRegularExpression(0, RegEx$)
    Debug "Regex Error" : ProcedureReturn 1
  EndIf 
  If ExamineRegularExpression(0, Txt$)
    While NextRegularExpressionMatch(0)
      Debug RegularExpressionGroup(0, 1)
    Wend 
  EndIf
EndProcedure

Un_Zip(XL_File$, "xl/sharedStrings.xml")
If Tmp_File$ : Get_Datas() : EndIf

End