PureBasic Forums - English

The debbuger also tells me my images don't exist when they do. I believe I have the path corrent in the program

For this we need some code. With macOS, the path is a little different than with windows./quote]

Thank you, I think the IDE replacement helped. I changed the history setting too
I don't have anything inside the Repeat Until loop yet.

[img]https://mega.nz/file/I5dmgR5A#5UMWKqg45 ... -kCRfI/img]

Code: Select all

Procedure PlayerNumberSelection()
    
  If OpenWindow(0, 0, 0, 1440, 810, "")
    ImgFile = LoadImage(#PB_Any,"/Volumes/untitled 1/PureBasic Projects/ Ultimate Football Manager/Media/football1.png")
    Window = OpenWindow(#PB_Any, x, y, 1440, 810, "", #PB_Window_BorderLess)
    ImageGadget(#PB_Any, 0, 0, 1440, 810, ImageID(ImgFile))
    
   Repeat
      Event = WaitWindowEvent()
      
      
    Until Event = #PB_Event_CloseWindow 
      
  EndIf
   
 EndProcedure/code]

mk-soft wrote: Sat Jan 01, 2022 12:24 pm Check your path with

Code: Select all

path.s = OpenFileRequester("", "", "", 0)
Debug path

I will give the requester code a try

Do you want to start a folder name with a blank character?

mk-soft wrote: Sun Jan 02, 2022 1:33 pm As you can see, in macOS an application is a folder with a fixed structure. (MyApp.app)
This means that additional files belong in this folder.
These must be copied in after compiling and before starting.
To do this, I wrote an IDE tool, which I then added twice in the PB IDE in tools.

IDE-Tool MyAppdata

As with Windows and Linux, user settings are not stored in the program folder. They belong in fixed folders.

Code: Select all

;-TOP

; Comment: Path Helper v1.03 by mk-soft

; Change names
#CompanyName = "mk-soft"
#ApplicationName = "MyApplication"

CompilerIf #PB_Compiler_OS
  
  Macro CocoaString(NSString)
    PeekS(NSString, -1, #PB_UTF8)
  EndMacro
  
CompilerEndIf

Procedure.s GetProgramPath()
  CompilerIf #PB_Compiler_OS = #PB_OS_MacOS
    Static bundlePath.s
    Protected bundlePathPtr
    
    If Not Bool(bundlePath)
      bundlePathPtr = CocoaMessage(0,CocoaMessage(0,CocoaMessage(0,0,"NSBundle mainBundle"),"bundlePath"),"UTF8String")
      If bundlePathPtr
        bundlePath = CocoaString(bundlePathPtr) + "/"
      EndIf
    EndIf
    ProcedureReturn bundlePath
  CompilerElse
    ProcedureReturn GetPathPart(ProgramFilename())  
  CompilerEndIf
EndProcedure

; ----

Procedure.s GetResourcePath()
  CompilerIf #PB_Compiler_OS = #PB_OS_MacOS
    Static resourcePath.s
    Protected resourcePathPtr
    
    If Not Bool(resourcePath)
      resourcePathPtr = CocoaMessage(0,CocoaMessage(0,CocoaMessage(0,0,"NSBundle mainBundle"),"resourcePath"),"UTF8String")
      If resourcePathPtr
        resourcePath = CocoaString(resourcePathPtr) + "/"
      EndIf
    EndIf
    ProcedureReturn resourcePath
  CompilerElse
    ProcedureReturn GetProgramPath() + "Resources" + #PS$
  CompilerEndIf
EndProcedure

; ----

Procedure.s GetLibraryPath()
  Protected librayPath.s
  CompilerIf #PB_Compiler_OS = #PB_OS_MacOS
    librayPath = GetProgramPath() + "Contents/Library/"
  CompilerElse
    librayPath = GetProgramPath() + "Library" + #PS$
  CompilerEndIf
  ProcedureReturn librayPath
EndProcedure

; ----

Procedure.s GetProgramDataPath()
  Protected basePath.s, subPath.s, dataPath.s
  
  CompilerIf #PB_Compiler_OS = #PB_OS_Linux
    basePath = GetHomeDirectory()
    subPath = basePath + "." + #CompanyName + #PS$
  CompilerElse
    basePath = GetUserDirectory(#PB_Directory_ProgramData)
    subPath = basePath + #CompanyName + #PS$
  CompilerEndIf
  dataPath = subPath + #ApplicationName + #PS$
  If FileSize(dataPath) <> -2
    If FileSize(subPath) <> -2
      CreateDirectory(subPath)
    EndIf
    If FileSize(dataPath) <> -2
      CreateDirectory(dataPath)
    EndIf
  EndIf
  ProcedureReturn dataPath
EndProcedure

; ----

Procedure.s GetAllUserDataPath()
  Protected basePath.s, subPath.s, dataPath.s
  
  basePath = GetUserDirectory(#PB_Directory_AllUserData)
  subPath = basePath + #CompanyName + #PS$
  dataPath = subPath + #ApplicationName + #PS$
  If FileSize(dataPath) <> -2
    If FileSize(subPath) <> -2
      CreateDirectory(subPath)
    EndIf
    If FileSize(dataPath) <> -2
      CreateDirectory(dataPath)
    EndIf
  EndIf
  ProcedureReturn dataPath
EndProcedure

; ****

CompilerIf #PB_Compiler_IsMainFile
  Debug "Program Path: " + GetProgramPath()
  Debug "Program Resources Path: " + GetResourcePath()
  Debug "Program Libraries Path: " + GetLibraryPath()
  Debug "Program Data Path: " + GetProgramDataPath()
  Debug "Program Alluser Data Path: " + GetAllUserDataPath()
CompilerEndIf