PureBasic Forums - English

Code: Select all

;-TOP by mk-soft, v1.01.1, 18.12.2021

#fileTemp = "/sys/class/thermal/thermal_zone0/temp"

Procedure.f get_cpu_temp()
  Protected r1.f, file, temp.s
  
  file = ReadFile(#PB_Any, #fileTemp)
  If file
    temp = ReadString(file, #PB_UTF8)
    CloseFile(file)
    r1 = 0.001 * Val(temp)
  Else
    r1 = 99.0
  EndIf
  ProcedureReturn r1
EndProcedure

For i = 1 To 5
  Debug get_cpu_temp()
  Delay(1000)
Next

Code: Select all

;get a unique id from the raspberry, 
;S.Rings 2021-12-28

Procedure.s get_machine_id()
  Protected  file, temp.s
  
  file = ReadFile(#PB_Any, "/etc/machine-id")
  If file
    temp = ReadString(file, #PB_UTF8)
    CloseFile(file)
  Else
  EndIf
  ProcedureReturn temp
EndProcedure

Debug get_machine_id()

Code: Select all

;get linux version  from the raspberry, 
;S.Rings 2021-12-28

Procedure.s get_linuxversion()
  Protected  file, temp.s
  
  file = ReadFile(#PB_Any, "/etc/os-release")
  If file
    temp = ReadString(file, #PB_UTF8)
    CloseFile(file)
  Else
  EndIf
  If Len(temp)>0 
    temp=Mid(temp,14,Len(temp)-14)
  EndIf
    
  ProcedureReturn temp
EndProcedure

Debug get_linuxversion()

Code: Select all

;sudo apt-get install portaudio19-dev

ImportC "-lportaudio" : EndImport 
!#include "/usr/include/portaudio.h"  

Structure paTestData
  left_phase.f;
  right_phase.f;
EndStructure

Global *stream;
Global err 
Global num_seconds= 4;
Global sample_rate = 44100;
Global *output
Global mData.PaTestData 

;** This routine will be called by the PortAudio engine when audio is needed.
;** It may called at interrupt level on some machines so don't do anything
;** that could mess up the system like calling malloc() Or free().
Procedure patestCallback(*inputBuffer,*outputBuffer,framesPerBuffer,*timeInfo,statusFlags,*userData.paTestData)
  
  *out.float = *outputBuffer;
  
  Protected i
  
  For i=0 To framesPerBuffer
    *out\f = *userData\left_phase;  /* left */
    *out+4
    *out\f = *userData\right_phase;  /* right */
    *out+4
    ;/* Generate simple sawtooth phaser that ranges between -1.0 And 1.0. */
    *userData\left_phase + 0.01
    ;/* When signal reaches top, drop back down. */
    If *userData\left_phase >= 1.0 
      *userData\left_phase - 1.0
    EndIf   
    ;higher pitch so we can distinguish left And right. */
    *userData\right_phase + 0.03
    If *userData\right_phase >= 1.0
      *userData\right_phase = -1.0;
    EndIf
    
  Next   
EndProcedure ;

Global paCallback = @patestCallback()     

Debug "PortAudio Test: output sawtooth wave."

!v_err = Pa_Initialize(); 
If err <> 0
  Goto error;
EndIf   

!v_err = Pa_OpenDefaultStream(&p_stream,0,2,paFloat32,v_sample_rate,16,v_pacallback,&v_mdata); 
If err <> 0 
  Goto error;
EndIf  

!v_err = Pa_StartStream(p_stream);
If err <> 0
  Goto error;
EndIf   

!Pa_Sleep(v_num_seconds*1000);
!v_err = Pa_StopStream(p_stream );
If err <> 0 
  Goto error;
EndIf   

!v_err = Pa_CloseStream(p_stream);
If err <> paNoError 
  Goto error;
EndIf   

!Pa_Terminate();
Debug "Test finished"
End  

error:
!Pa_Terminate();
Debug "An error occured while using the portaudio stream"
Debug "error number " + Str(err) 
!p_output = Pa_GetErrorText(v_err);
Debug PeekS(*out,-1,#PB_UTF8)