PureBasic Forums - English

Code: Select all

If Decision = "Strings should also count as one."
	ThisIsAVeryLongVariableNameAndShouldBeCountAsOneToken = 4
Else
	ThisIsAVeryLongVariableNameAndShouldBeCountAsOneToken = 9
EndIf

Code: Select all

If D = "Short" : T = 4 : Else : T = 9 : EndIf

Code: Select all

EnableExplicit

Declare.s RegexReplace2(RgEx, *Result.string, Replace0$, Once = 0)
Define FilePath$, FilePath2$
Define Text.string

FilePath$ = OpenFileRequester("Open file", GetCurrentDirectory(), "PureBasic (*.pb)|*.pb", 0)
If Asc(FilePath$) And FileSize(FilePath$) > 0
	FilePath2$ = Left(FilePath$, Len(FilePath$) - 3) + " (no comments).pb"
Else
    End
EndIf

#File = 0
ReadFile(#File, FilePath$)
Text\s = ReadString(#File, #PB_UTF8 | #PB_File_IgnoreEOL) + #CRLF$
CloseFile(#File)

#q$ = Chr(34)
If FindString(Text\s, "~" + #q$)
	MessageRequester("",
	                 "Code contains strings with escaped quotes: ~" + #q$ + "..." + #q$ + #CRLF$ +
	                 "A copy of the file is being created, check the correctness of these lines in it.")
EndIf

#RegExp = 0
If CreateRegularExpression(#RegExp , ~"(?m)^((?:[^''\";]*([''\"]).*?\\2)*[^;]*)\\h*;.*$" )
	RegexReplace2(#RegExp, @Text, "\1")
	FreeRegularExpression(#RegExp)
	If CreateRegularExpression(#RegExp , "(\r\n|\r|\n){2,}" )
		 RegexReplace2(#RegExp, @Text, "\1")
		FreeRegularExpression(#RegExp)
	EndIf
	If CreateRegularExpression(#RegExp , "(?<!\r)\n" )
		Text\s = ReplaceRegularExpression(#RegExp, Text\s, #CRLF$)
		FreeRegularExpression(#RegExp)
	EndIf
	If CreateFile(#File, FilePath2$)
		WriteStringFormat(#File, #PB_UTF8)
		WriteString(#File, Text\s, #PB_UTF8)
		CloseFile(#File)
	EndIf
EndIf

; https://www.purebasic.fr/english/viewtopic.php?p=575871#p575871
Procedure.s RegexReplace2(RgEx, *Result.string, Replace0$, Once = 0)
	Protected i, CountGr, Pos, Offset = 1
	Protected Result$, Replace$
	Protected NewList item.s()
	Protected LenT, *Point
	CountGr = CountRegularExpressionGroups(RgEx)
	If CountGr > 9
		CountGr = 9
	EndIf
	If ExamineRegularExpression(RgEx, *Result\s)
		While NextRegularExpressionMatch(RgEx)
			Pos = RegularExpressionMatchPosition(RgEx)
			Replace$ = ReplaceString(Replace0$,"\0", RegularExpressionMatchString(RgEx))
			For i = 1 To CountGr
				Replace$ = ReplaceString(Replace$, "\"+Str(i), RegularExpressionGroup(RgEx, i))
			Next
			If AddElement(item())
				item() = Mid(*Result\s, Offset, Pos - Offset) + Replace$
			EndIf
			Offset = Pos + RegularExpressionMatchLength(RgEx)
			If Once
				Break
			EndIf
		Wend
		If AddElement(item())
			item() = Mid(*Result\s, Offset)
		EndIf
		LenT = 0
		ForEach item()
			LenT + Len(item())
		Next
		*Result\s = Space(LenT)
		*Point = @*Result\s
		ForEach item()
			CopyMemoryString(item(), @*Point)
		Next
		FreeList(item())
	EndIf
EndProcedure