PureBasic Forums - English

Code: Select all

EnableExplicit


Procedure.i Circle2PtsRad(x1.i, y1.i, x2.i, y2.i, r.i, *middle.Point)
  
  Protected Result.i, d2.d, det.d, h.d
  
  
  d2 = (x1 - x2) * (x1 - x2) + (y1 - y2) * (y1 - y2)
  det = r * r / d2 - 0.25
  
  If det >= 0.0
    h = Sqr(det)
    *middle\x = (x1 + x2) * 0.5 + (y1 - y2) * h
    *middle\y = (y1 + y2) * 0.5 + (x2 - x1) * h
    Result = #True
  EndIf
  
  ProcedureReturn Result
  
EndProcedure


Define Middle.Point

#x1 = 80
#y1 = 30

#x2 = 130
#y2 = 30

#r = 80

If OpenWindow(0, 0, 0, 200, 200, "CircleCalc", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  If CreateImage(0, 200, 200) And StartDrawing(ImageOutput(0))
    
    If Circle2PtsRad(#x1, #y1, #x2, #y2, #r, @Middle)
      Debug Str(Middle\x) + " / " + Str(Middle\y)
      
      Circle(Middle\x, Middle\y, #r, #Blue)
      
      Plot(#x1, #y1, #Red)
      Plot(#x2, #y2, #Red)
      
    Else
      Debug "Not possible"
    EndIf
    
    StopDrawing() 
    ImageGadget(0, 0, 0, 200, 200, ImageID(0))
  EndIf
  
  Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf