PureBasic Forums - English

Code: Select all

Procedure CreatePduSendRequest(*pSession.SNMP_MGR_SESSION, *pValue.smiVALUE)
	
	; check For the validity of the Structure
	If *pSession = #Null
		ProcedureReturn #False
	EndIf
	
	; set the pdu type
	Select gVars\operation
		Case "GET"
			*pSession\nPduType = #SNMP_PDU_GET
			
		Case "GET_NEXT"
			*pSession\nPduType = #SNMP_PDU_GETNEXT
			
		Case "WALK"
			*pSession\nPduType = #SNMP_PDU_GETNEXT
			
		Case "SET"
			*pSession\nPduType = #SNMP_PDU_SET
			
		Case "SUB_TREE"
			*pSession\nPduType = #SNMP_PDU_GETNEXT
			
		Case "GET_BULK"
			*pSession\nPduType = #SNMP_PDU_GETBULK
			
	EndSelect
	
	; first time around, walk: always use the first oid
	If (gVars\nRequestId = 1) And (gVars\operation = "WALK" Or gVars\operation = "SUB_TREE") ; Or ( gVars\operation = #GET_BULK ) ) )
		
		If SnmpStrToOid(gVars\pszOid[0], @gVars\oid) = #SNMPAPI_FAILURE
			
			If SnmpMgrStrToOid(gVars\pszOid[0], @gVars\oid) = #False
				Debug "snmputil: Failed in SnmpStrToOid( ) or SnmpMgrStrToOid( ) function"
				ProcedureReturn #False
			EndIf
		Else
			; copy the var bind
			gVars\startOid = gVars\oid
		EndIf
	EndIf
	
	; create the appropriate Varbind lists depending on the operation.
	If gVars\operation = "WALK" Or gVars\operation = "SUB_TREE"
		
		If CreateVbl(*pSession, @gVars\oid, #Null) = #False
			ProcedureReturn #False
		EndIf
		
	ElseIf gVars\operation = "GET_NEXT" Or gVars\operation = "GET"

		If SnmpStrToOid(gVars\pszOid[gVars\nRequestId - 1], gVars\oid) = #SNMPAPI_FAILURE
			Debug "SnmpStrToOid failed : " + SnmpGetLastError(#Null) ; 9 = Invalid OID parameter, The string parameter is invalid

			If SnmpMgrStrToOid(gVars\pszOid[gVars\nRequestId - 1], gVars\oid) = #False
				Debug "SnmpMgrStrToOid failed"
				ProcedureReturn #False
			EndIf

		EndIf  
		
		If CreateVbl(*pSession, @gVars\oid, #Null ) = #False
			ProcedureReturn #False
		EndIf
		
	ElseIf gVars\operation = "SET"
		*pSession\hVbl = SnmpCreateVbl(*pSession\hSnmpSession, @gVars\oid, *pValue)
		
	ElseIf gVars\operation = "GET_BULK"
		; CreateVbl first then add OIDs To the Vbl
		*pSession\hVbl = SnmpCreateVbl(*pSession\hSnmpSession,  ; handle To the WinSNMP session 
		                               #Null,						  ; pointer To the variable name 
		                               #Null)						  ; pointer To the value To associate With the variable        
		
		If *pSession\hVbl = #SNMPAPI_FAILURE
			ProcedureReturn #False
		EndIf
		
		For i = 0 To gVars\oidCount - 1
			
			; the very last gVars.oid in the loop will be freed later
			If i > 0
				SnmpFreeDescriptor(#SNMP_SYNTAX_OID, @gVars\oid)
			EndIf
			
			If SnmpStrToOid(gVars\pszOid[i], @gVars\oid) = #SNMPAPI_FAILURE
				If SnmpMgrStrToOid(gVars\pszOid[i], @gVars\oid) = #False
					Debug "snmputil: Failed in SnmpStrToOid( ) or SnmpMgrStrToOid( ) function"
					ProcedureReturn #False
				EndIf
			EndIf
			
			; append vb To Vbl
			If SnmpSetVb(*pSession\hVbl, 0, @gVars\oid, #Null) = #SNMPAPI_FAILURE
				Debug "snmputil: Failed in SnmpSetVb( ) function"
				ProcedureReturn #False
			EndIf
			
		Next
		
	EndIf
	
	gVars\nRequestId = gVars\nRequestId + 1
	*pSession\nRequestId = gVars\nRequestId
	
	If gVars\operation = "GET_BULK"
		error_status = gVars\non_repeaters
		error_index = gVars\max_repetitions
	Else	
		error_status = #Null
		error_index = #Null
	EndIf
	
	; create a pdu using the parameters in pSession Structure
	*pSession\hPdu = SnmpCreatePdu(*pSession\hSnmpSession, *pSession\nPduType, *pSession\nRequestId, error_status, error_index, *pSession\hVbl)
	
	If *pSession\hPdu = #SNMPAPI_FAILURE
		Debug "snmputil: Failed in creating PDU"
		ProcedureReturn #False
	EndIf
	
	; send the message To the agent
	*pSession\nError = SnmpSendMsg(*pSession\hSnmpSession, *pSession\hManagerEntity, *pSession\hAgentEntity, *pSession\hViewContext, *pSession\hPdu)
	
	If gVars\operation <> "SUB_TREE"
		SnmpFreeDescriptor(#SNMP_SYNTAX_OID, @gVars\oid)
	EndIf
	
	
	; check error status And Return
	If *pSession\nError = #SNMPAPI_FAILURE  
		*pSession\nError = SnmpGetLastError(*pSession\hSnmpSession)
		Debug "snmputil: Failed in send message, Last Error " + *pSession\nError
		FreeVblandPdu(*pSession)
		ProcedureReturn #False
	Else
		FreeVblandPdu(*pSession)
		ProcedureReturn ProcessAgentResponse(*pSession)
	EndIf
	
EndProcedure