PureBasic Forums - English

Code: Select all

Interface IMMDeviceEnumerator Extends IUnknown
  EnumAudioEndpoints()
  GetDefaultAudioEndpoint(Flow.l, role.l, IMMDevice.i)       
  GetDevice()        
  RegisterEndpointNotificationCallback() 
  UnregisterEndpointNotificationCallback()
EndInterface

Interface IAudioEndpointVolume Extends IUnknown
  RegisterControlChangeNotify()
  UnregisterControlChangeNotify()
  GetChannelCount()
  SetMasterVolumeLevel()
  SetMasterVolumeLevelScalar()
  GetMasterVolumeLevel()
  GetMasterVolumeLevelScalar()
  SetChannelVolumeLevel()
  SetChannelVolumeLevelScalar()
  GetChannelVolumeLevel()
  GetChannelVolumeLevelScalar()
  SetMute()
  GetMute()
  GetVolumeStepInfo()
  VolumeStepUp(*context)
  VolumeStepDown(*context)
  QueryHardwareSupport()
  GetVolumeRange()
EndInterface

Interface IMMDevice Extends IUnknown
  Activate(iid, dwClsCtx.l, *pActivationParams, *ppInterface)
  OpenPropertyStore() 
  GetId()
  GetState()
EndInterface  

Interface IAudioMeterInformation Extends IUnknown
  GetPeakValue(*pfPeak)
  GetMeteringChannelCount()
  GetChannelsPeakValues()
  QueryHardwareSupport()
EndInterface 

DataSection
  IAudioMeterInformation:
  Data.l $C02216F6
  Data.w $8C67,$4B5B
  Data.b $9D,$00,$D0,$08,$E7,$3E,$00,$64
  
  
  IAudioEndpointVolume:
  Data.l $5CDF2C82
  Data.w $841E,$4546
  Data.b $97,$22,$0C,$F7,$40,$78,$22,$9A
  
  MMDeviceEnumerator:
  Data.l $BCDE0395
  Data.w $E52F,$467C
  Data.b $8E,$3D,$C4,$57,$92,$91,$69,$2E
  
  IMMDeviceEnumerator:
  Data.l $A95664D2
  Data.w $9614
  Data.w $4F35
  Data.b $A7,$46,$DE,$8D,$B6,$36,$17,$E6
EndDataSection 

CoInitialize_(0);
deviceEnumerator.IMMDeviceEnumerator
defaultDevice.IMMDevice
audiomaterinformation.IAudioMeterInformation
endpointVolume.IAudioEndpointVolume
CoCreateInstance_(?MMDeviceEnumerator, 0, 1, ?IMMDeviceEnumerator, @deviceEnumerator);
deviceEnumerator\GetDefaultAudioEndpoint(0, 0, @defaultDevice)                       ;
deviceEnumerator\Release()
defaultDevice\Activate(?IAudioEndpointVolume, 1, 0, @endpointVolume);
defaultDevice\Activate(?IAudioMeterInformation, 1, 0, @audiomaterinformation);
defaultDevice\Release()                                                      ;

Peak.f
;Pointer To a float variable into which the method writes the peak sample value For the audio stream. The peak value is a number in the normalized range from 0.0 To 1.0.
While 1
  audiomaterinformation\GetPeakValue(@Peak)
  If Peak <= 0.5
    endpointVolume\VolumeStepUp(0)
  Else
    endpointVolume\VolumeStepDown(0)
  EndIf
  Delay(10)
Wend

audiomaterinformation\Release()
endpointVolume\Release();
CoUninitialize_();