PureBasic Forums - English

Posted: **Fri Jul 26, 2019 9:17 am**

Attempting to get a 32 checksum from a buffer

After setting up the buffer I use 'Debug "Checksum = " + Str(PeekL(*SongBuffer + 22))'

The value returned is -1015688195

If I change to 'Debug "Checksum = " + Hex(PeekL(*SongBuffer + 22))'

The value returned is FFFFFFFFC375D3FD

The actual value should be C375D3FD

Other values are returned ok, am I missing something?

You will need an .ogg file to test.

The code I am using is here:-

Code: Select all

Structure Head
  Capture.s
  Version.a
  Type.a
  GranPos.d
  Serial.l
  Sequence.l
  Checksum.l
  PageSegments.a
EndStructure


Global OggHeader.Head

FileToSearch.s = OpenFileRequester("Please choose file to load", "", "All Files (*.*)|*.*", 0)

    If ReadFile(0, FileToSearch)
      length = Lof(0)
      *SongBuffer = AllocateMemory(length)
      If *SongBuffer
        bytes = ReadData(0, *SongBuffer, length)
      EndIf
      CloseFile(0)
    EndIf
  
    
    Debug "Capture Pattern = " + PeekS(*SongBuffer,4,#PB_UTF8)
    Debug "Version = " + Str(PeekA(*SongBuffer + 4))
    Debug "Type = " + Str(PeekA(*SongBuffer + 5))
    Debug "Granule Position = " + Str(PeekD(*SongBuffer + 6))
    Debug "Serial = " + Hex(PeekL(*SongBuffer + 14))
    Debug "Sequence = " + Hex(PeekL(*SongBuffer + 18))
    Debug "Checksum = " + Str(PeekL(*SongBuffer + 22))
    Debug "Number Of Segments = " + Str(PeekA(*SongBuffer + 26))

I know it will be something I am not seeing.

CD

Posted: **Fri Jul 26, 2019 9:22 am**

Code: Select all

Debug Hex(-1015688195, #PB_Long)

c ya,
nco2k

Posted: **Fri Jul 26, 2019 9:32 am**

Lovely

Thanks very much

CD

Posted: **Fri Jul 26, 2019 5:13 pm**

Besides the code i posted in the other thread: viewtopic.php?p=539643#p539643

Here is a very simple & fast way to get the ogg page offsets.

Code: Select all

EnableExplicit

Global NewList OggOffsets.i()

Procedure.i GetOggOffsets(File.s,List Offset.i())
  Protected handle.i
  Protected *buffer
  Protected buffer_size.i
  Protected *offset.Long
  Protected result.i
  Protected error.i
  If File
    handle = ReadFile(#PB_Any,File.s)
    If IsFile(handle)
      buffer_size = Lof(handle)
      If buffer_size > 4
        *buffer = AllocateMemory(buffer_size)
        If ReadData(handle,*buffer,buffer_size) = buffer_size
          For *offset = *buffer To (*buffer + buffer_size - 5)
            If *offset\l = 1399285583
              If AddElement(Offset())
                Offset() = *offset - *buffer
              Else
                error = #True
                Break
              EndIf
            EndIf
          Next
          result = Bool(error = #False)
        EndIf
        FreeMemory(*buffer)
      EndIf 
      CloseFile(handle)
    EndIf 
  EndIf 
  ProcedureReturn result
EndProcedure

If GetOggOffsets("yuna.ogg",OggOffsets())
  ForEach OggOffsets()
    Debug OggOffsets()
  Next
EndIf  
  
End

Posted: **Fri Jul 26, 2019 5:32 pm**

Hi Mijikai

Replied on this thread posting.php?mode=reply&f=13&t=73238 as more appropiate.

This is just about my confusion over PeekL()

Hope you do not mind?

Getting close now to writing ogg comments but better on the above thread.

King Regards

CD

PureBasic Forums - English

PeekL Seems to give wrong answer?

PeekL Seems to give wrong answer?

Re: PeekL Seems to give wrong answer?

Re: PeekL Seems to give wrong answer?

Re: PeekL Seems to give wrong answer?

Re: PeekL Seems to give wrong answer?