PureBasic Forums - English

Code: Select all

; Define  - - -  LoadImage Dummy Procedure by Michael Vogel

	Procedure LoadImage_(id,name.s,x,y)

		Protected z

		#VoxMin=160
		#VoxMax=800
		#VoyMin=100
		#VoyMax=600

		If FileSize(name)>0
			ProcedureReturn LoadImage(id,name,x)

		Else
			If x*y=#Null
				x=#VoxMin+Random(#VoxMax-#VoxMin)
				y=#VoyMin+Random(#VoyMax-#VoyMin)
			EndIf
			z=CreateImage(id,x,y)

			If z
				If id=#PB_Any
					id=z
				EndIf
				StartDrawing(ImageOutput(id))
				DrawingMode(#PB_2DDrawing_Gradient)
				BackColor($FFFFFF)
				GradientColor(0.3,$404040|Random(#White))
				GradientColor(0.7,#White)
				GradientColor(0.7,$404040|Random(#White))
				FrontColor($FFFFFF)
				LinearGradient(0,0,x,y)
				Box(0,0,x,y,$FFFFFF)

				DrawingMode(#PB_2DDrawing_AlphaBlend)
				For i=0 To x>>3
					Circle(Random(x),Random(y),Random(y>>3),$60000000|Random(#White))
				Next i

				StopDrawing()
				ProcedureReturn id
			EndIf

			ProcedureReturn #Null
		EndIf

	EndProcedure
	Macro LoadImage(a,b,c=0,d=0)
		LoadImage_(a,b,c,d)
	EndMacro

; EndDefine


w=400
h=500

LoadFont(0,"Arial",-160,#PB_Font_HighQuality)

LoadImage(1,#PB_Compiler_Home + "Examples/Sources/Data/PureBasic.bmp",w*2,h*2)
StartDrawing(ImageOutput(1))
DrawingFont(FontID(0))
DrawingMode(#PB_2DDrawing_AlphaBlend)
DrawText(0,0,"Ax%ß6@",$FF000000,0)
DrawText(0,200,"Ax%ß6@",$FFFFFFFF,0)
StopDrawing()

CopyImage(1,2)

OpenWindow(0, 0, 0, w*2,h, "-", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)

ResizeImage(1,w,h,#PB_Image_Raw);    nearly identical to standard size
ImageGadget(1,	0,0,		w,h,	ImageID(1))

ResizeImage(2,w,h)
ImageGadget(2,	w,0,	w,h,	ImageID(2)); smooth content by using an enlarged image

Repeat
	Event = WaitWindowEvent()
Until Event = #PB_Event_CloseWindow

Code: Select all

#Factor=4; Quick and dirty adaption of the line width - only for demonstration
Macro CreateImage_AA(img,w,h,depth=24,color=0)
	CreateImage(img,w*#Factor,h*#Factor,depth,color)
EndMacro

Macro Circle_AA(x,y,radius,color=#PB_Default)
	For i=0 To #Factor>>1
		Circle(x*#Factor,y*#Factor,radius*#Factor+i,color)
	Next i
EndMacro

Macro LineXY_AA(x1,y1,x2,y2,color=#PB_Default)
	For i=0 To #Factor>>1
		LineXY(x1*#Factor+i,y1*#Factor,x2*#Factor+i,y2*#Factor,color)
	Next i
EndMacro

Macro Finish_AA(img)
	ResizeImage(img,ImageWidth(img)/#factor,ImageHeight(img)/#factor)
EndMacro

OpenWindow(0,0,0,680,280,"Anti-Alias Macros",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)

; Normal 2D circle with line.
CreateImage(1,320,240,32,#White)
StartDrawing(ImageOutput(1))
DrawingMode(#PB_2DDrawing_Outlined)
Circle(160,120,100,#Blue)
LineXY(0,0,320,240,#Red)
StopDrawing()

; Anti-aliased 2D circle with line.
CreateImage_AA(2,320,240,32,#White)
StartDrawing(ImageOutput(2))
DrawingMode(#PB_2DDrawing_Outlined)
Circle_AA(160,120,100,#Blue)
LineXY_AA(0,0,320,240,#Red)
StopDrawing()
Finish_AA(2) ; Required when AA drawing is done.

ImageGadget(1,10,10,320,240,ImageID(1))
ImageGadget(2,350,10,320,240,ImageID(2))

Repeat : Until WaitWindowEvent()=#PB_Event_CloseWindow