PureBasic Forums - English

Code: Select all

EnableExplicit

Procedure.s RandomString (numChars.i, allowedCharacters$="ABCabc123")
   ; -- works in ASCII mode and Unicode mode
   Protected *sourceBase, *source.Character, *dest.Character
   Protected lastAllowed.i=Len(allowedCharacters$)-1
   Protected ret$ = Space(numChars)
   
   *sourceBase = @allowedCharacters$
   *dest = @ret$
   While *dest\c <> 0
      *source = *sourceBase + Random(lastAllowed) * SizeOf(Character)
      *dest\c = *source\c      
      *dest + SizeOf(Character)
   Wend   
   
   ProcedureReturn ret$
EndProcedure


Debug RandomString(10)

Code: Select all

For i = 1 To 10
	s$ + Chr(Random(126,32))
Next
Debug s$

Code: Select all

i = 0
Repeat
	t$ = Chr(Random(126,32))
	a = Asc(t$)
	If a <90 Or a > 96
		s$ + t$
		i+1
	EndIf
Until i = 10
Debug s$

Code: Select all

Procedure.s GenData(maxlen)
	Protected rn, string.s, number
	RandomSeed(Random(100000, 1))
	While number<maxlen
		rn =Random(122, 48)
		Select rn
			Case 48 To 57, 65 To 90, 97 To 122
				string+Chr(rn)
				number+1
		EndSelect
	Wend
ProcedureReturn string
EndProcedure

For i=1 To 10
	Debug GenData(10)
Next

Code: Select all

Procedure.s KeyGen(KeyLen)
  Define OldNum = Random(3)
  Define Use, x
  Define LongKey$, PassKey$

  For X = 1 To 1000
    Repeat
      Use = Random(3)                  ; numeric 0-3
    Until  Use <> OldNum
    OldNum = Use

    Select Use
    Case 0
      LongKey$ + Str(Random(9))        ; numbers       0 to 9
    Case 1
      LongKey$ + Chr(Random(25) + 65)  ; uppercase     A to Z
    Case 2
      LongKey$ + Chr(Random(25) + 97)  ; lowercase     a to z
    Case 3
      LongKey$ + Mid("#$%&+/<=>?@\~", Random(12), 1)  ; special chars
    EndSelect
  Next

  For X = 1 To KeyLen
    PassKey$ + Mid(LongKey$, Random(999) + 1, 1)
  Next

  ProcedureReturn PassKey$
EndProcedure

For i = 1 To 10
  Debug KeyGen(10)
Next i

Code: Select all

Procedure.s RandomString (numChars.i, allowedCharacters$="ABCabc123")
  ; -- works in ASCII mode and Unicode mode
  Static NewMap unique.b()
  Protected *sourceBase, *source.Character, *dest.Character
  Protected lastAllowed.i=Len(allowedCharacters$)-1
  Protected ret$ = Space(numChars)
  
  *sourceBase = @allowedCharacters$
  *dest = @ret$
  While *dest\c <> 0
    *source = *sourceBase + Random(lastAllowed) * SizeOf(Character)
    *dest\c = *source\c      
    *dest + SizeOf(Character)
  Wend   
  ; -- check that generated string is unique
  If FindMapElement(unique(),ret$)
    ; -- if not, then regenerate it
    ret$=RandomString (numChars,allowedCharacters$)
  Else
    ; -- otherwise, add the generated string to the existing 'list'    
    AddMapElement(unique(),ret$)
  EndIf
  
  ProcedureReturn ret$
EndProcedure