PureBasic Forums - English

Code: Select all

Macro CreateImage_AA(img,w,h,depth=24,color=0)
  CreateImage(img,w*2,h*2,depth,color)
EndMacro

Macro Circle_AA(x,y,radius,color=#PB_Default)
  Circle(x*2,y*2,radius*2,color)
EndMacro

Macro LineXY_AA(x1,y1,x2,y2,color=#PB_Default)
  LineXY(x1*2,y1*2,x2*2,y2*2,color)
EndMacro

Macro Finish_AA(img)
  ResizeImage(img,ImageWidth(img)/2,ImageHeight(img)/2)
EndMacro

OpenWindow(0,0,0,680,280,"Anti-Alias Macros",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)

; Normal 2D circle with line.
CreateImage(1,320,240,32,#White)
StartDrawing(ImageOutput(1))
  DrawingMode(#PB_2DDrawing_Outlined)
  Circle(160,120,100,#Blue)
  LineXY(0,0,320,240,#Red)
StopDrawing()

; Anti-aliased 2D circle with line.
CreateImage_AA(2,320,240,32,#White)
StartDrawing(ImageOutput(2))
  DrawingMode(#PB_2DDrawing_Outlined)
  Circle_AA(160,120,100,#Blue)
  LineXY_AA(0,0,320,240,#Red)
StopDrawing()
Finish_AA(2) ; Required when AA drawing is done.

ImageGadget(1,10,10,320,240,ImageID(1))
ImageGadget(2,350,10,320,240,ImageID(2))

Repeat : Until WaitWindowEvent()=#PB_Event_CloseWindow

Code: Select all

;
; ------------------------------------------------------------
;
;   PureBasic - Antialiased line Drawing example file
;
;    (c) 2005 - Background code by Fantaisie Software
;        2015 - LineAA by djes
;
; ------------------------------------------------------------
;

Procedure LineAA(x0.i, y0.i, x1.i, y1.i, color.i)
  ; /* draw an anti-aliased line on background */
  ; adapted by djes upon Alois Zingl's work - http://members.chello.at/~easyfilter/bresenham.html
  Define.i dx = Abs(x1 - x0), sx : If x0 < x1 : sx = 1 : Else : sx = -1 : EndIf
  Define.i dy = Abs(y1 - y0), sy : If y0 < y1 : sy = 1 : Else : sy = -1 : EndIf
  Define.i x2, e2, err = dx - dy; /* error value e_xy */
  Define.i ed : If dx + dy = 0 : ed = 0 : Else : ed = Sqr(dx*dx + dy*dy) : EndIf
  Define.i r = Red(color), g = Green(color), b=Blue(color), a=Alpha(color), c
  Define.i blend
  While #True ; pixel loop
    blend = 255*Abs(err - dx+dy)/ed : c = Point(x0,y0)
    Plot(x0, y0, RGBA((blend*Red(c) + (255-blend)*r) / 255, (blend*Green(c) + (255-blend)*g) / 255, (blend*Blue(c) + (255-blend)*b) / 255, (blend*Alpha(c) + (255-blend)*a) / 255))
    e2 = err : x2 = x0;
    If (2*e2 >= -dx)  ;{ /* x Step */
      If (x0 = x1) : Break : EndIf
      If (e2+dy < ed) 
        blend = 255*(e2+dy)/ed : c = Point(x0,y0+sy)
        Plot(x0, y0+sy, RGBA((blend*Red(c) + (255-blend)*r) / 255, (blend*Green(c) + (255-blend)*g) / 255, (blend*Blue(c) + (255-blend)*b) / 255, (blend*Alpha(c) + (255-blend)*a) / 255))
      EndIf
      err - dy : x0 + sx;
    EndIf
    If (2*e2 <= dy) ;{ /* y Step */
      If (y0 = y1) : Break : EndIf
      If (dx-e2 < ed)
        blend = 255*(dx-e2)/ed : c = Point(x2+sx,y0)
        Plot(x2+sx,y0, RGBA((blend*Red(c) + (255-blend)*r) / 255, (blend*Green(c) + (255-blend)*g) / 255, (blend*Blue(c) + (255-blend)*b) / 255, (blend*Alpha(c) + (255-blend)*a) / 255))
      EndIf
      err + dx : y0 + sy
    EndIf
  Wend
EndProcedure

If OpenWindow(0, 100, 200, 300, 200, "AA Line Drawing Test")
  
  ; Create an offscreen image, with a green circle in it.
  ; It will be displayed later
  ;
  If CreateImage(0, 300, 200, 32)
    If StartDrawing(ImageOutput(0))
      Circle(100,100,50, RGB(0,0,255))  ; a nice blue circle...
      
      Box(150,20,20,20, RGB(0,255,0))  ; and a green box
      
      FrontColor(RGB(255,0,0)) ; Finally, red lines..
      For k=0 To 20
        LineAA(10,10+k*8,150, 0, RGBA(255,255,0,0))
        LineXY(290,10+k*8,150, 0)
      Next
      
      DrawingMode(#PB_2DDrawing_Transparent)
      BackColor(RGB(0,155,155)) ; Change the text back and front colour
      FrontColor(RGB(255,255,255)) 
      DrawText(10,50,"Hello, this is a test")
      
      StopDrawing()
    EndIf
  EndIf
  
  ; Create a gadget to display our nice image
  ;  
  ImageGadget(0, 0, 0, 0, 0, ImageID(0))
  
  ;
  ; This is the 'event loop'. All the user actions are processed here.
  ; It's very easy to understand: when an action occurs, the Event
  ; isn't 0 and we just have to see what have happened...
  ;
  
  Repeat
    Event = WaitWindowEvent() 
  Until Event = #PB_Event_CloseWindow  ; If the user has pressed on the window close button
  
EndIf

End   ; All the opened windows are closed automatically by PureBasic